SL/AR.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Accounts Receivable module backend routines
  33 #
  34 #======================================================================
  35
  36 package AR;
  37
  38 use Data::Dumper;
  39 use SL::DATEV qw(:CONSTANTS);
  40 use SL::DBUtils;
  41 use SL::DB::Draft;
  42 use SL::IO;
  43 use SL::MoreCommon;
  44 use SL::DB::Default;
  45 use SL::TransNumber;
  46 use SL::Util qw(trim);
  47 use SL::DB;
  48
  49 use strict;
  50
  51 sub post_transaction {
  52   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  53   $main::lxdebug->enter_sub();
  54
  55   my $rc = SL::DB->client->with_transaction(\&_post_transaction, $self, $myconfig, $form, $provided_dbh, $payments_only);
  56
  57   $::lxdebug->leave_sub;
  58   return $rc;
  59 }
  60
  61 sub _post_transaction {
  62   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  63
  64   my ($query, $sth, $null, $taxrate, $amount, $tax);
  65   my $exchangerate = 0;
  66   my $i;
  67
  68   my @values;
  69
  70   my $dbh = $provided_dbh || SL::DB->client->dbh;
  71   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
  72
  73   # set exchangerate
  74   $form->{exchangerate} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
  75       ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy') ||
  76         $form->parse_amount($myconfig, $form->{exchangerate}) );
  77
  78   # get the charts selected
  79   $form->{AR_amounts}{"amount_$_"} = $form->{"AR_amount_chart_id_$_"} for (1 .. $form->{rowcount});
  80
  81   $form->{tax}       = 0; # is this still needed?
  82
  83   # main calculation of rowcount loop inside Form method, amount_$i and tax_$i get formatted
  84   $form->{taxincluded} = 0 unless $form->{taxincluded};
  85   ($form->{netamount},$form->{total_tax},$form->{amount}) = $form->calculate_arap('sell', $form->{taxincluded}, $form->{exchangerate});
  86
  87   # adjust paidaccounts if there is no date in the last row
  88   # this does not apply to stornos, where the paid field is set manually
  89   unless ($form->{storno}) {
  90     $form->{paidaccounts}-- unless $form->{"datepaid_$form->{paidaccounts}"};
  91     $form->{paid} = 0;
  92
  93     # add payments
  94     for $i (1 .. $form->{paidaccounts}) {
  95       $form->{"paid_$i"} = $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}), 2);
  96       $form->{paid}     += $form->{"paid_$i"};
  97       $form->{datepaid}  = $form->{"datepaid_$i"};
  98     }
  99
 100   }
 101   $form->{paid}   = $form->round_amount($form->{paid} * ($form->{exchangerate} || 1), 2);
 102
 103   $form->get_employee($dbh) unless $form->{employee_id};
 104
 105   # if we have an id delete old records else make one
 106   if (!$payments_only) {
 107     if ($form->{id}) {
 108       # delete detail records
 109       $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 110       do_query($form, $dbh, $query, $form->{id});
 111
 112     } else {
 113       $query = qq|SELECT nextval('glid')|;
 114       ($form->{id}) = selectrow_query($form, $dbh, $query);
 115       $query = qq|INSERT INTO ar (id, invnumber, employee_id, currency_id, taxzone_id) VALUES (?, 'dummy', ?, (SELECT id FROM currencies WHERE name=?), (SELECT taxzone_id FROM customer WHERE id = ?))|;
 116       do_query($form, $dbh, $query, $form->{id}, $form->{employee_id}, $form->{currency}, $form->{customer_id});
 117       if (!$form->{invnumber}) {
 118         my $trans_number   = SL::TransNumber->new(type => 'invoice', dbh => $dbh, number => $form->{partnumber}, id => $form->{id});
 119         $form->{invnumber} = $trans_number->create_unique;
 120       }
 121     }
 122   }
 123
 124   # amount for AR account
 125   $form->{receivables} = $form->round_amount($form->{amount}, 2) * -1;
 126
 127   # update exchangerate
 128   $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate}, $form->{exchangerate}, 0)
 129     if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy');
 130
 131   if (!$payments_only) {
 132     $query =
 133       qq|UPDATE ar set
 134            invnumber = ?, ordnumber = ?, transdate = ?, customer_id = ?,
 135            taxincluded = ?, amount = ?, duedate = ?, paid = ?,
 136            currency_id = (SELECT id FROM currencies WHERE name = ?),
 137            netamount = ?, notes = ?, department_id = ?,
 138            employee_id = ?, storno = ?, storno_id = ?, globalproject_id = ?,
 139            direct_debit = ?
 140          WHERE id = ?|;
 141     my @values = ($form->{invnumber}, $form->{ordnumber}, conv_date($form->{transdate}), conv_i($form->{customer_id}), $form->{taxincluded} ? 't' : 'f', $form->{amount},
 142                   conv_date($form->{duedate}), $form->{paid},
 143                   $form->{currency},
 144                   $form->{netamount}, $form->{notes}, conv_i($form->{department_id}),
 145                   conv_i($form->{employee_id}), $form->{storno} ? 't' : 'f', $form->{storno_id},
 146                   conv_i($form->{globalproject_id}), $form->{direct_debit} ? 't' : 'f', conv_i($form->{id}));
 147     do_query($form, $dbh, $query, @values);
 148
 149     # add individual transactions for AR, amount and taxes
 150     for $i (1 .. $form->{rowcount}) {
 151       if ($form->{"amount_$i"} != 0) {
 152         my $project_id = conv_i($form->{"project_id_$i"});
 153
 154         # insert detail records in acc_trans
 155         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 156                      VALUES (?, ?, ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.id = ?))|;
 157         @values = (conv_i($form->{id}), $form->{AR_amounts}{"amount_$i"}, conv_i($form->{"amount_$i"}), conv_date($form->{transdate}), $project_id,
 158                    conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"amount_$i"});
 159         do_query($form, $dbh, $query, @values);
 160
 161         if ($form->{"tax_$i"} != 0) {
 162           # insert detail records in acc_trans
 163           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 164                        VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 165           @values = (conv_i($form->{id}), $form->{AR_amounts}{"tax_$i"}, conv_i($form->{"tax_$i"}), conv_date($form->{transdate}), $project_id,
 166                      conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"tax_$i"});
 167           do_query($form, $dbh, $query, @values);
 168         }
 169       }
 170     }
 171
 172     # add recievables
 173     $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, taxkey, tax_id, chart_link)
 174                  VALUES (?, ?, ?, ?, (SELECT taxkey_id FROM chart WHERE id = ?),
 175                  (SELECT tax_id
 176                   FROM taxkeys
 177                   WHERE chart_id = ?
 178                   AND startdate <= ?
 179                   ORDER BY startdate DESC LIMIT 1),
 180                  (SELECT c.link FROM chart c WHERE c.id = ?))|;
 181     @values = (conv_i($form->{id}), $form->{AR_chart_id}, conv_i($form->{receivables}), conv_date($form->{transdate}),
 182                 $form->{AR_chart_id}, $form->{AR_chart_id}, conv_date($form->{transdate}), $form->{AR_chart_id});
 183     do_query($form, $dbh, $query, @values);
 184
 185   } else {
 186     # Record paid amount.
 187     $query = qq|UPDATE ar SET paid = ?, datepaid = ? WHERE id = ?|;
 188     do_query($form, $dbh, $query,  $form->{paid}, $form->{paid} ? conv_date($form->{datepaid}) : undef, conv_i($form->{id}));
 189   }
 190
 191   $form->new_lastmtime('ar');
 192
 193   # add paid transactions
 194   for my $i (1 .. $form->{paidaccounts}) {
 195
 196     if ($form->{"acc_trans_id_$i"} && $payments_only && (SL::DB::Default->get->payments_changeable == 0)) {
 197       next;
 198     }
 199
 200     if ($form->{"paid_$i"} != 0) {
 201       my $project_id = conv_i($form->{"paid_project_id_$i"});
 202
 203       $form->{"AR_paid_$i"} =~ s/\"//g;
 204       ($form->{AR}{"paid_$i"}) = split(/--/, $form->{"AR_paid_$i"});
 205       $form->{"datepaid_$i"} = $form->{transdate}
 206         unless ($form->{"datepaid_$i"});
 207
 208       $form->{"exchangerate_$i"} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
 209         ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy') ||
 210           $form->parse_amount($myconfig, $form->{"exchangerate_$i"}) );
 211
 212       # if there is no amount and invtotal is zero there is no exchangerate
 213       $form->{exchangerate} = $form->{"exchangerate_$i"}
 214         if ($form->{amount} == 0 && $form->{netamount} == 0);
 215
 216       # receivables amount
 217       $amount = $form->round_amount($form->{"paid_$i"} * $form->{exchangerate}, 2);
 218
 219       if ($amount != 0) {
 220         # add receivable
 221         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 222                      VALUES (?, ?, ?, ?, ?, (SELECT taxkey_id FROM chart WHERE id = ?),
 223                      (SELECT tax_id
 224                       FROM taxkeys
 225                       WHERE chart_id = ?
 226                       AND startdate <= ?
 227                       ORDER BY startdate DESC LIMIT 1),
 228                      (SELECT c.link FROM chart c WHERE c.id = ?))|;
 229         @values = (conv_i($form->{id}), $form->{AR_chart_id}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR_chart_id}, $form->{AR_chart_id}, conv_date($form->{"datepaid_$i"}), $form->{AR_chart_id});
 230
 231         do_query($form, $dbh, $query, @values);
 232       }
 233
 234       if ($form->{"paid_$i"} != 0) {
 235         # add payment
 236         my $project_id = conv_i($form->{"paid_project_id_$i"});
 237         my $gldate = (conv_date($form->{"gldate_$i"}))? conv_date($form->{"gldate_$i"}) : conv_date($form->current_date($myconfig));
 238         $amount = $form->{"paid_$i"} * -1;
 239         $query  = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, source, memo, project_id, taxkey, tax_id, chart_link)
 240                      VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, ?, ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 241                      (SELECT tax_id
 242                       FROM taxkeys
 243                       WHERE chart_id= (SELECT id
 244                                        FROM chart
 245                                        WHERE accno = ?)
 246                       AND startdate <= ?
 247                       ORDER BY startdate DESC LIMIT 1),
 248                      (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 249         @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $gldate, $form->{"source_$i"}, $form->{"memo_$i"}, $project_id, $form->{AR}{"paid_$i"},
 250                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 251         do_query($form, $dbh, $query, @values);
 252
 253         # exchangerate difference for payment
 254         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{"exchangerate_$i"} - 1) * -1, 2);
 255
 256         if ($amount != 0) {
 257           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 258                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 259                        (SELECT tax_id
 260                         FROM taxkeys
 261                         WHERE chart_id= (SELECT id
 262                                          FROM chart
 263                                          WHERE accno = ?)
 264                         AND startdate <= ?
 265                         ORDER BY startdate DESC LIMIT 1),
 266                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 267           @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR}{"paid_$i"},
 268                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 269           do_query($form, $dbh, $query, @values);
 270         }
 271
 272         # exchangerate gain/loss
 273         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{exchangerate} - $form->{"exchangerate_$i"}) * -1, 2);
 274
 275         if ($amount != 0) {
 276           # fetch fxgain and fxloss chart info from defaults if charts aren't already filled in form
 277           if ( !$form->{fxgain_accno} && $::instance_conf->get_fxgain_accno_id ) {
 278             $form->{fxgain_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id)->accno;
 279           };
 280           if ( !$form->{fxloss_accno} && $::instance_conf->get_fxloss_accno_id ) {
 281             $form->{fxloss_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id)->accno;
 282           };
 283           die "fxloss_accno missing" if $amount < 0 and not $form->{fxloss_accno};
 284           die "fxgain_accno missing" if $amount > 0 and not $form->{fxgain_accno};
 285           my $accno = ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno};
 286           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 287                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 288                        (SELECT tax_id
 289                         FROM taxkeys
 290                         WHERE chart_id= (SELECT id
 291                                          FROM chart
 292                                          WHERE accno = ?)
 293                         AND startdate <= ?
 294                         ORDER BY startdate DESC LIMIT 1),
 295                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 296           @values = (conv_i($form->{id}), $accno, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $accno, $accno, conv_date($form->{"datepaid_$i"}), $accno);
 297           do_query($form, $dbh, $query, @values);
 298         }
 299       }
 300
 301       # update exchangerate record
 302       $form->update_exchangerate($dbh, $form->{currency}, $form->{"datepaid_$i"}, $form->{"exchangerate_$i"}, 0)
 303         if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 304     }
 305   }
 306
 307   IO->set_datepaid(table => 'ar', id => $form->{id}, dbh => $dbh);
 308
 309   if ($form->{draft_id}) {
 310     SL::DB::Manager::Draft->delete_all(where => [ id => delete($form->{draft_id}) ]);
 311   }
 312
 313   # safety check datev export
 314   if ($::instance_conf->get_datev_check_on_ar_transaction) {
 315     my $datev = SL::DATEV->new(
 316       dbh        => $dbh,
 317       trans_id   => $form->{id},
 318     );
 319
 320     $datev->generate_datev_data;
 321
 322     if ($datev->errors) {
 323       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 324     }
 325   }
 326
 327   return 1;
 328 }
 329
 330 sub _delete_payments {
 331   $main::lxdebug->enter_sub();
 332
 333   my ($self, $form, $dbh) = @_;
 334
 335   my @delete_acc_trans_ids;
 336
 337   # Delete old payment entries from acc_trans.
 338   my $query =
 339     qq|SELECT acc_trans_id
 340        FROM acc_trans
 341        WHERE (trans_id = ?) AND fx_transaction
 342
 343        UNION
 344
 345        SELECT at.acc_trans_id
 346        FROM acc_trans at
 347        LEFT JOIN chart c ON (at.chart_id = c.id)
 348        WHERE (trans_id = ?) AND (c.link LIKE '%AR_paid%')|;
 349   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}), conv_i($form->{id}));
 350
 351   $query =
 352     qq|SELECT at.acc_trans_id
 353        FROM acc_trans at
 354        LEFT JOIN chart c ON (at.chart_id = c.id)
 355        WHERE (trans_id = ?)
 356          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 357        ORDER BY at.acc_trans_id
 358        OFFSET 1|;
 359   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}));
 360
 361   if (@delete_acc_trans_ids) {
 362     $query = qq|DELETE FROM acc_trans WHERE acc_trans_id IN (| . join(", ", @delete_acc_trans_ids) . qq|)|;
 363     do_query($form, $dbh, $query);
 364   }
 365
 366   $main::lxdebug->leave_sub();
 367 }
 368
 369 sub post_payment {
 370   my ($self, $myconfig, $form, $locale) = @_;
 371   $main::lxdebug->enter_sub();
 372
 373   my $rc = SL::DB->client->with_transaction(\&_post_payment, $self, $myconfig, $form, $locale);
 374
 375   $::lxdebug->leave_sub;
 376   return $rc;
 377 }
 378
 379 sub _post_payment {
 380   my ($self, $myconfig, $form, $locale) = @_;
 381
 382   my $dbh = SL::DB->client->dbh;
 383
 384   my (%payments, $old_form, $row, $item, $query, %keep_vars);
 385
 386   $old_form = save_form();
 387
 388   # Delete all entries in acc_trans from prior payments.
 389   if (SL::DB::Default->get->payments_changeable != 0) {
 390     $self->_delete_payments($form, $dbh);
 391   }
 392
 393   # Save the new payments the user made before cleaning up $form.
 394   my $payments_re = '^datepaid_\d+$|^gldate_\d+$|^acc_trans_id_\d+$|^memo_\d+$|^source_\d+$|^exchangerate_\d+$|^paid_\d+$|^paid_project_id_\d+$|^AR_paid_\d+$|^paidaccounts$';
 395   map { $payments{$_} = $form->{$_} } grep m/$payments_re/, keys %{ $form };
 396
 397   # Clean up $form so that old content won't tamper the results.
 398   %keep_vars = map { $_, 1 } qw(login password id);
 399   map { delete $form->{$_} unless $keep_vars{$_} } keys %{ $form };
 400
 401   # Retrieve the invoice from the database.
 402   $form->create_links('AR', $myconfig, 'customer', $dbh);
 403
 404   # Restore the payment options from the user input.
 405   map { $form->{$_} = $payments{$_} } keys %payments;
 406
 407   # Set up the content of $form in the way that AR::post_transaction() expects.
 408
 409   $self->setup_form($form, 1);
 410
 411   $form->{exchangerate}    = $form->format_amount($myconfig, $form->{exchangerate});
 412   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
 413
 414   # Get the AR chart ID (which is normally done by Form::create_links()).
 415   $query =
 416     qq|SELECT c.id
 417        FROM acc_trans at
 418        LEFT JOIN chart c ON (at.chart_id = c.id)
 419        WHERE (trans_id = ?)
 420          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 421        ORDER BY at.acc_trans_id
 422        LIMIT 1|;
 423
 424   ($form->{AR_chart_id}) = selectfirst_array_query($form, $dbh, $query, conv_i($form->{id}));
 425
 426   # Post the new payments.
 427   $self->post_transaction($myconfig, $form, $dbh, 1);
 428
 429   restore_form($old_form);
 430
 431   return 1;
 432 }
 433
 434 sub delete_transaction {
 435   $main::lxdebug->enter_sub();
 436
 437   my ($self, $myconfig, $form) = @_;
 438
 439   SL::DB->client->with_transaction(sub {
 440     # acc_trans entries are deleted by database triggers.
 441     my $query = qq|DELETE FROM ar WHERE id = ?|;
 442     do_query($form, SL::DB->client->dbh, $query, $form->{id});
 443     1;
 444   }) or do { die SL::DB->client->error };
 445
 446   $main::lxdebug->leave_sub();
 447
 448   return 1;
 449 }
 450
 451 sub ar_transactions {
 452   $main::lxdebug->enter_sub();
 453
 454   my ($self, $myconfig, $form) = @_;
 455
 456   # connect to database
 457   my $dbh = $form->get_standard_dbh($myconfig);
 458
 459   my @values;
 460
 461   my $query =
 462     qq|SELECT DISTINCT a.id, a.invnumber, a.ordnumber, a.cusordnumber, a.transdate, | .
 463     qq|  a.duedate, a.netamount, a.amount, a.paid, | .
 464     qq|  a.invoice, a.datepaid, a.notes, a.shipvia, | .
 465     qq|  a.shippingpoint, a.storno, a.storno_id, a.globalproject_id, | .
 466     qq|  a.marge_total, a.marge_percent, | .
 467     qq|  a.transaction_description, a.direct_debit, | .
 468     qq|  pr.projectnumber AS globalprojectnumber, | .
 469     qq|  c.name, c.customernumber, c.country, c.ustid, b.description as customertype, | .
 470     qq|  c.id as customer_id, | .
 471     qq|  e.name AS employee, | .
 472     qq|  e2.name AS salesman, | .
 473     qq|  dc.dunning_description, | .
 474     qq|  tz.description AS taxzone, | .
 475     qq|  pt.description AS payment_terms, | .
 476     qq|  d.description AS department, | .
 477     qq{  ( SELECT ch.accno || ' -- ' || ch.description
 478            FROM acc_trans at
 479            LEFT JOIN chart ch ON ch.id = at.chart_id
 480            WHERE ch.link ~ 'AR[[:>:]]'
 481             AND at.trans_id = a.id
 482             LIMIT 1
 483           ) AS charts } .
 484     qq|FROM ar a | .
 485     qq|JOIN customer c ON (a.customer_id = c.id) | .
 486     qq|LEFT JOIN contacts cp ON (a.cp_id = cp.cp_id) | .
 487     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 488     qq|LEFT JOIN employee e2 ON (a.salesman_id = e2.id) | .
 489     qq|LEFT JOIN dunning_config dc ON (a.dunning_config_id = dc.id) | .
 490     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id)| .
 491     qq|LEFT JOIN tax_zones tz ON (tz.id = a.taxzone_id)| .
 492     qq|LEFT JOIN payment_terms pt ON (pt.id = a.payment_id)| .
 493     qq|LEFT JOIN business b ON (b.id = c.business_id)| .
 494     qq|LEFT JOIN department d ON (d.id = a.department_id)|;
 495
 496   my $where = "1 = 1";
 497
 498   unless ( $::auth->assert('show_ar_transactions', 1) ) {
 499     $where .= " AND NOT invoice = 'f' ";  # remove ar transactions from Sales -> Reports -> Invoices
 500   };
 501
 502   if ($form->{customer}) {
 503     $where .= " AND c.name ILIKE ?";
 504     push(@values, like($form->{customer}));
 505   }
 506   if ($form->{"cp_name"}) {
 507     $where .= " AND (cp.cp_name ILIKE ? OR cp.cp_givenname ILIKE ?)";
 508     push(@values, (like($form->{"cp_name"}))x2);
 509   }
 510   if ($form->{business_id}) {
 511     my $business_id = $form->{business_id};
 512     $where .= " AND c.business_id = ?";
 513     push(@values, $business_id);
 514   }
 515   if ($form->{department_id}) {
 516     $where .= " AND a.department_id = ?";
 517     push(@values, $form->{department_id});
 518   }
 519   foreach my $column (qw(invnumber ordnumber cusordnumber notes transaction_description)) {
 520     if ($form->{$column}) {
 521       $where .= " AND a.$column ILIKE ?";
 522       push(@values, like($form->{$column}));
 523     }
 524   }
 525   if ($form->{"project_id"}) {
 526     $where .=
 527       qq|AND ((a.globalproject_id = ?) OR EXISTS | .
 528       qq|  (SELECT * FROM invoice i | .
 529       qq|   WHERE i.project_id = ? AND i.trans_id = a.id) | .
 530       qq| OR EXISTS | .
 531       qq|  (SELECT * FROM acc_trans at | .
 532       qq|   WHERE at.project_id = ? AND at.trans_id = a.id)| .
 533       qq|  )|;
 534     push(@values, $form->{project_id}, $form->{project_id}, $form->{project_id});
 535   }
 536
 537   if ($form->{transdatefrom}) {
 538     $where .= " AND a.transdate >= ?";
 539     push(@values, trim($form->{transdatefrom}));
 540   }
 541   if ($form->{transdateto}) {
 542     $where .= " AND a.transdate <= ?";
 543     push(@values, trim($form->{transdateto}));
 544   }
 545   if ($form->{duedatefrom}) {
 546     $where .= " AND a.duedate >= ?";
 547     push(@values, trim($form->{duedatefrom}));
 548   }
 549   if ($form->{duedateto}) {
 550     $where .= " AND a.duedate <= ?";
 551     push(@values, trim($form->{duedateto}));
 552   }
 553   if ($form->{open} || $form->{closed}) {
 554     unless ($form->{open} && $form->{closed}) {
 555       $where .= " AND a.amount <> a.paid" if ($form->{open});
 556       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 557     }
 558   }
 559
 560   if (!$main::auth->assert('sales_all_edit', 1)) {
 561     # only show own invoices
 562     $where .= " AND a.employee_id = (select id from employee where login= ?)";
 563     push (@values, $::myconfig{login});
 564   } else {
 565     if ($form->{employee_id}) {
 566       $where .= " AND a.employee_id = ?";
 567       push @values, conv_i($form->{employee_id});
 568     }
 569     if ($form->{salesman_id}) {
 570       $where .= " AND a.salesman_id = ?";
 571       push @values, conv_i($form->{salesman_id});
 572     }
 573   };
 574
 575   if ($form->{parts_partnumber}) {
 576     $where .= <<SQL;
 577       AND EXISTS (
 578         SELECT invoice.trans_id
 579         FROM invoice
 580         LEFT JOIN parts ON (invoice.parts_id = parts.id)
 581         WHERE (invoice.trans_id = a.id)
 582           AND (parts.partnumber ILIKE ?)
 583         LIMIT 1
 584       )
 585 SQL
 586     push @values, like($form->{parts_partnumber});
 587   }
 588
 589   if ($form->{parts_description}) {
 590     $where .= <<SQL;
 591       AND EXISTS (
 592         SELECT invoice.trans_id
 593         FROM invoice
 594         WHERE (invoice.trans_id = a.id)
 595           AND (invoice.description ILIKE ?)
 596         LIMIT 1
 597       )
 598 SQL
 599     push @values, like($form->{parts_description});
 600   }
 601
 602   my ($cvar_where, @cvar_values) = CVar->build_filter_query('module'         => 'CT',
 603                                                             'trans_id_field' => 'c.id',
 604                                                             'filter'         => $form,
 605                                                            );
 606   if ($cvar_where) {
 607     $where .= qq| AND ($cvar_where)|;
 608     push @values, @cvar_values;
 609   }
 610
 611   my @a = qw(transdate invnumber name);
 612   push @a, "employee" if $form->{l_employee};
 613   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 614   my $sortorder = join(', ', map { "$_ $sortdir" } @a);
 615
 616   if (grep({ $_ eq $form->{sort} } qw(id transdate duedate invnumber ordnumber cusordnumber name datepaid employee shippingpoint shipvia transaction_description))) {
 617     $sortorder = $form->{sort} . " $sortdir";
 618   }
 619
 620   $query .= " WHERE $where ORDER BY $sortorder";
 621
 622   my @result = selectall_hashref_query($form, $dbh, $query, @values);
 623
 624   $form->{AR} = [ @result ];
 625
 626   $main::lxdebug->leave_sub();
 627 }
 628
 629 sub get_transdate {
 630   $main::lxdebug->enter_sub();
 631
 632   my ($self, $myconfig, $form) = @_;
 633
 634   # connect to database
 635   my $dbh = SL::DB->client->dbh;
 636
 637   my $query =
 638     "SELECT COALESCE(" .
 639     "  (SELECT transdate FROM ar WHERE id = " .
 640     "    (SELECT MAX(id) FROM ar) LIMIT 1), " .
 641     "  current_date)";
 642   ($form->{transdate}) = $dbh->selectrow_array($query);
 643
 644   $main::lxdebug->leave_sub();
 645 }
 646
 647 sub setup_form {
 648   $main::lxdebug->enter_sub();
 649
 650   my ($self, $form, $for_post_payments) = @_;
 651
 652   my ($exchangerate, $akey, $j, $k, $index, $taxamount, $totaltax, $taxrate, $diff, $totalwithholding, $withholdingrate,
 653       $totalamount, $tax);
 654
 655   # forex
 656   $form->{forex} = $form->{exchangerate};
 657   $exchangerate  = $form->{exchangerate} ? $form->{exchangerate} : 1;
 658
 659   # expected keys: AR, AR_paid, AR_tax, AR_amount
 660   foreach my $key (keys %{ $form->{AR_links} }) {
 661     $j = 0;
 662     $k = 0;
 663
 664     # if there is a value we have an old entry
 665     next unless $form->{acc_trans}{$key};
 666
 667     # do not use old entries for payments. They come from the form
 668     # even if they are not changeable (then they are in hiddens)
 669     next if $for_post_payments && $key eq "AR_paid";
 670
 671     for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 672       if ($key eq "AR_paid") {
 673         $j++;
 674         $form->{"AR_paid_$j"} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 675
 676         $form->{"acc_trans_id_$j"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 677         # reverse paid
 678         $form->{"paid_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 679         $form->{"datepaid_$j"}        = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 680         $form->{"gldate_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 681         $form->{"source_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{source};
 682         $form->{"memo_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 683         $form->{"forex_$j"}           = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 684         $form->{"exchangerate_$i"}    = $form->{"forex_$j"};
 685         $form->{"paid_project_id_$j"} = $form->{acc_trans}{$key}->[$i - 1]->{project_id};
 686         $form->{paidaccounts}++;
 687
 688       } else { # e.g. AR_amount, AR, AR_tax
 689
 690         $akey = $key;
 691         $akey =~ s/AR_//; # e.g. tax, amount, AR, used to store form key tax_$i, amount_$i, ...
 692
 693         if ($key eq "AR_tax" || $key eq "AP_tax") { # AR_tax
 694           $form->{"${key}_$form->{acc_trans}{$key}->[$i-1]->{accno}"}  = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 695           # determine the rounded tax amounts for each account, e.g. tax_1776
 696           $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 697
 698           # check e.g. $form->{1776_rate}, does this make sense for AR_tax charts? Is this ever valid? If it was, totaltax would be calculated twice
 699           if ($form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"} > 0) {
 700             $totaltax += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 701             $taxrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 702
 703           } else {
 704             $totalwithholding += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 705             $withholdingrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 706           }
 707
 708           $index                 = $form->{acc_trans}{$key}->[$i - 1]->{index};
 709           $form->{"tax_$index"}  = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2); # convert the tax_$i amounts
 710           # currently totaltax is the sum of rounded tax amounts, is this correct?
 711           $totaltax             += $form->{"tax_$index"};
 712
 713         } else { # e.g. AR_amount, AR
 714           $k++;
 715           $form->{"${akey}_$k"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 716
 717           if ($akey eq 'amount') {
 718             $form->{rowcount}++;
 719             $totalamount += $form->{"${akey}_$i"};
 720
 721             $form->{"oldprojectnumber_$k"} = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 722             $form->{"projectnumber_$k"}    = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 723             $form->{taxrate}               = $form->{acc_trans}{$key}->[$i - 1]->{rate};
 724             $form->{"project_id_$k"}       = $form->{acc_trans}{$key}->[$i-1]->{project_id};
 725
 726             $form->{"${key}_chart_id_$k"} = $form->{acc_trans}{$key}->[$i-1]->{chart_id};
 727             $form->{"taxchart_$k"} = $form->{acc_trans}{$key}->[$i-1]->{id}    . "--" . $form->{acc_trans}{$key}->[$i-1]->{rate};
 728           }
 729         }
 730       }
 731     }
 732   }
 733
 734   $form->{paidaccounts} = 1            if not defined $form->{paidaccounts};
 735
 736   if ($form->{taxincluded} && $form->{taxrate} && $totalamount) {
 737
 738     # add tax to amounts and invtotal
 739     for my $i (1 .. $form->{rowcount}) {
 740       $taxamount            = ($totaltax + $totalwithholding) * $form->{"amount_$i"} / $totalamount;
 741       $tax                  = $form->round_amount($taxamount, 2);
 742       $diff                += ($taxamount - $tax);
 743       $form->{"amount_$i"} += $form->{"tax_$i"};
 744     }
 745     $form->{amount_1} += $form->round_amount($diff, 2);
 746   }
 747
 748   $taxamount   = $form->round_amount($taxamount, 2);
 749   $form->{tax} = $taxamount;
 750
 751   $form->{invtotal} = $totalamount + $totaltax;
 752
 753   $main::lxdebug->leave_sub();
 754 }
 755
 756 sub storno {
 757   my ($self, $form, $myconfig, $id) = @_;
 758   $main::lxdebug->enter_sub();
 759
 760   my $rc = SL::DB->client->with_transaction(\&_storno, $self, $form, $myconfig, $id);
 761
 762   $::lxdebug->leave_sub;
 763   return $rc;
 764 }
 765
 766
 767 sub _storno {
 768   my ($self, $form, $myconfig, $id) = @_;
 769
 770   my ($query, $new_id, $storno_row, $acc_trans_rows);
 771   my $dbh = SL::DB->client->dbh;
 772
 773   $query = qq|SELECT nextval('glid')|;
 774   ($new_id) = selectrow_query($form, $dbh, $query);
 775
 776   $query = qq|SELECT * FROM ar WHERE id = ?|;
 777   $storno_row = selectfirst_hashref_query($form, $dbh, $query, $id);
 778
 779   $storno_row->{id}         = $new_id;
 780   $storno_row->{storno_id}  = $id;
 781   $storno_row->{storno}     = 't';
 782   $storno_row->{invnumber}  = 'Storno-' . $storno_row->{invnumber};
 783   $storno_row->{amount}    *= -1;
 784   $storno_row->{netamount} *= -1;
 785   $storno_row->{paid}       = $storno_row->{amount};
 786
 787   delete @$storno_row{qw(itime mtime)};
 788
 789   $query = sprintf 'INSERT INTO ar (%s) VALUES (%s)', join(', ', keys %$storno_row), join(', ', map '?', values %$storno_row);
 790   do_query($form, $dbh, $query, (values %$storno_row));
 791
 792   $query = qq|UPDATE ar SET paid = amount + paid, storno = 't' WHERE id = ?|;
 793   do_query($form, $dbh, $query, $id);
 794
 795   $form->new_lastmtime('ar') if $id == $form->{id};
 796
 797   # now copy acc_trans entries
 798   $query = qq|SELECT a.*, c.link FROM acc_trans a LEFT JOIN chart c ON a.chart_id = c.id WHERE a.trans_id = ? ORDER BY a.acc_trans_id|;
 799   my $rowref = selectall_hashref_query($form, $dbh, $query, $id);
 800
 801   # kill all entries containing payments, which are the last 2n rows, of which the last has link =~ /paid/
 802   while ($rowref->[-1]{link} =~ /paid/) {
 803     splice(@$rowref, -2);
 804   }
 805
 806   for my $row (@$rowref) {
 807     delete @$row{qw(itime mtime link acc_trans_id)};
 808     $query = sprintf 'INSERT INTO acc_trans (%s) VALUES (%s)', join(', ', keys %$row), join(', ', map '?', values %$row);
 809     $row->{trans_id}   = $new_id;
 810     $row->{amount}    *= -1;
 811     do_query($form, $dbh, $query, (values %$row));
 812   }
 813
 814   map { IO->set_datepaid(table => 'ar', id => $_, dbh => $dbh) } ($id, $new_id);
 815
 816   return 1;
 817 }
 818
 819
 820 1;