SL/AR.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Accounts Receivable module backend routines
  33 #
  34 #======================================================================
  35
  36 package AR;
  37
  38 use Data::Dumper;
  39 use SL::DATEV qw(:CONSTANTS);
  40 use SL::DBUtils;
  41 use SL::IO;
  42 use SL::MoreCommon;
  43 use SL::DB::Default;
  44 use SL::TransNumber;
  45 use SL::Util qw(trim);
  46 use SL::DB;
  47
  48 use strict;
  49
  50 sub post_transaction {
  51   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  52   $main::lxdebug->enter_sub();
  53
  54   my $rc = SL::DB->client->with_transaction(\&_post_transaction, $self, $myconfig, $form, $provided_dbh, $payments_only);
  55
  56   $::lxdebug->leave_sub;
  57   return $rc;
  58 }
  59
  60 sub _post_transaction {
  61   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  62
  63   my ($query, $sth, $null, $taxrate, $amount, $tax);
  64   my $exchangerate = 0;
  65   my $i;
  66
  67   my @values;
  68
  69   my $dbh = $provided_dbh || SL::DB->client->dbh;
  70   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
  71
  72   # set exchangerate
  73   $form->{exchangerate} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
  74       ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy') ||
  75         $form->parse_amount($myconfig, $form->{exchangerate}) );
  76
  77   # get the charts selected
  78   map { ($form->{AR_amounts}{"amount_$_"}) = split /--/, $form->{"AR_amount_$_"} } 1 .. $form->{rowcount};
  79
  80   $form->{AR_amounts}{receivables} = $form->{ARselected};
  81   $form->{AR}{receivables}         = $form->{ARselected};
  82
  83   $form->{tax}       = 0; # is this still needed?
  84
  85   # main calculation of rowcount loop inside Form method, amount_$i and tax_$i get formatted
  86   $form->{taxincluded} = 0 unless $form->{taxincluded};
  87   ($form->{netamount},$form->{total_tax},$form->{amount}) = $form->calculate_arap('sell', $form->{taxincluded}, $form->{exchangerate});
  88
  89   # adjust paidaccounts if there is no date in the last row
  90   # this does not apply to stornos, where the paid field is set manually
  91   unless ($form->{storno}) {
  92     $form->{paidaccounts}-- unless $form->{"datepaid_$form->{paidaccounts}"};
  93     $form->{paid} = 0;
  94
  95     # add payments
  96     for $i (1 .. $form->{paidaccounts}) {
  97       $form->{"paid_$i"} = $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}), 2);
  98       $form->{paid}     += $form->{"paid_$i"};
  99       $form->{datepaid}  = $form->{"datepaid_$i"};
 100     }
 101
 102   }
 103   $form->{paid}   = $form->round_amount($form->{paid} * ($form->{exchangerate} || 1), 2);
 104
 105   ($null, $form->{employee_id}) = split /--/, $form->{employee};
 106
 107   $form->get_employee($dbh) unless $form->{employee_id};
 108
 109   # if we have an id delete old records else make one
 110   if (!$payments_only) {
 111     if ($form->{id}) {
 112       # delete detail records
 113       $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 114       do_query($form, $dbh, $query, $form->{id});
 115
 116     } else {
 117       $query = qq|SELECT nextval('glid')|;
 118       ($form->{id}) = selectrow_query($form, $dbh, $query);
 119       $query = qq|INSERT INTO ar (id, invnumber, employee_id, currency_id, taxzone_id) VALUES (?, 'dummy', ?, (SELECT id FROM currencies WHERE name=?), (SELECT taxzone_id FROM customer WHERE id = ?))|;
 120       do_query($form, $dbh, $query, $form->{id}, $form->{employee_id}, $form->{currency}, $form->{customer_id});
 121       if (!$form->{invnumber}) {
 122         my $trans_number   = SL::TransNumber->new(type => 'invoice', dbh => $dbh, number => $form->{partnumber}, id => $form->{id});
 123         $form->{invnumber} = $trans_number->create_unique;
 124       }
 125     }
 126   }
 127
 128   # update department
 129   ($null, $form->{department_id}) = split(/--/, $form->{department});
 130
 131   # amount for AR account
 132   $form->{receivables} = $form->round_amount($form->{amount}, 2) * -1;
 133
 134   # update exchangerate
 135   $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate}, $form->{exchangerate}, 0)
 136     if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy');
 137
 138   if (!$payments_only) {
 139     $query =
 140       qq|UPDATE ar set
 141            invnumber = ?, ordnumber = ?, transdate = ?, customer_id = ?,
 142            taxincluded = ?, amount = ?, duedate = ?, paid = ?,
 143            currency_id = (SELECT id FROM currencies WHERE name = ?),
 144            netamount = ?, notes = ?, department_id = ?,
 145            employee_id = ?, storno = ?, storno_id = ?, globalproject_id = ?,
 146            direct_debit = ?
 147          WHERE id = ?|;
 148     my @values = ($form->{invnumber}, $form->{ordnumber}, conv_date($form->{transdate}), conv_i($form->{customer_id}), $form->{taxincluded} ? 't' : 'f', $form->{amount},
 149                   conv_date($form->{duedate}), $form->{paid},
 150                   $form->{currency},
 151                   $form->{netamount}, $form->{notes}, conv_i($form->{department_id}),
 152                   conv_i($form->{employee_id}), $form->{storno} ? 't' : 'f', $form->{storno_id},
 153                   conv_i($form->{globalproject_id}), $form->{direct_debit} ? 't' : 'f', conv_i($form->{id}));
 154     do_query($form, $dbh, $query, @values);
 155
 156     # add individual transactions for AR, amount and taxes
 157     for $i (1 .. $form->{rowcount}) {
 158       if ($form->{"amount_$i"} != 0) {
 159         my $project_id = conv_i($form->{"project_id_$i"});
 160
 161         # insert detail records in acc_trans
 162         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 163                      VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 164         @values = (conv_i($form->{id}), $form->{AR_amounts}{"amount_$i"}, conv_i($form->{"amount_$i"}), conv_date($form->{transdate}), $project_id,
 165                    conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"amount_$i"});
 166         do_query($form, $dbh, $query, @values);
 167
 168         if ($form->{"tax_$i"} != 0) {
 169           # insert detail records in acc_trans
 170           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 171                        VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 172           @values = (conv_i($form->{id}), $form->{AR_amounts}{"tax_$i"}, conv_i($form->{"tax_$i"}), conv_date($form->{transdate}), $project_id,
 173                      conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"tax_$i"});
 174           do_query($form, $dbh, $query, @values);
 175         }
 176       }
 177     }
 178
 179     # add recievables
 180     $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, taxkey, tax_id, chart_link)
 181                  VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 182                  (SELECT tax_id
 183                   FROM taxkeys
 184                   WHERE chart_id= (SELECT id
 185                                    FROM chart
 186                                    WHERE accno = ?)
 187                   AND startdate <= ?
 188                   ORDER BY startdate DESC LIMIT 1),
 189                  (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 190     @values = (conv_i($form->{id}), $form->{AR_amounts}{receivables}, conv_i($form->{receivables}), conv_date($form->{transdate}),
 191                 $form->{AR_amounts}{receivables}, $form->{AR_amounts}{receivables}, conv_date($form->{transdate}), $form->{AR_amounts}{receivables});
 192     do_query($form, $dbh, $query, @values);
 193
 194   } else {
 195     # Record paid amount.
 196     $query = qq|UPDATE ar SET paid = ?, datepaid = ? WHERE id = ?|;
 197     do_query($form, $dbh, $query,  $form->{paid}, $form->{paid} ? conv_date($form->{datepaid}) : undef, conv_i($form->{id}));
 198   }
 199
 200   $form->new_lastmtime('ar');
 201
 202   # add paid transactions
 203   for my $i (1 .. $form->{paidaccounts}) {
 204
 205     if ($form->{"acc_trans_id_$i"} && $payments_only && (SL::DB::Default->get->payments_changeable == 0)) {
 206       next;
 207     }
 208
 209     if ($form->{"paid_$i"} != 0) {
 210       my $project_id = conv_i($form->{"paid_project_id_$i"});
 211
 212       $form->{"AR_paid_$i"} =~ s/\"//g;
 213       ($form->{AR}{"paid_$i"}) = split(/--/, $form->{"AR_paid_$i"});
 214       $form->{"datepaid_$i"} = $form->{transdate}
 215         unless ($form->{"datepaid_$i"});
 216
 217       $form->{"exchangerate_$i"} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
 218         ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy') ||
 219           $form->parse_amount($myconfig, $form->{"exchangerate_$i"}) );
 220
 221       # if there is no amount and invtotal is zero there is no exchangerate
 222       $form->{exchangerate} = $form->{"exchangerate_$i"}
 223         if ($form->{amount} == 0 && $form->{netamount} == 0);
 224
 225       # receivables amount
 226       $amount = $form->round_amount($form->{"paid_$i"} * $form->{exchangerate}, 2);
 227
 228       if ($amount != 0) {
 229         # add receivable
 230         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 231                      VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 232                      (SELECT tax_id
 233                       FROM taxkeys
 234                       WHERE chart_id= (SELECT id
 235                                        FROM chart
 236                                        WHERE accno = ?)
 237                       AND startdate <= ?
 238                       ORDER BY startdate DESC LIMIT 1),
 239                      (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 240         @values = (conv_i($form->{id}), $form->{AR}{receivables}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR}{receivables}, $form->{AR}{receivables}, conv_date($form->{"datepaid_$i"}),
 241         $form->{AR}{receivables});
 242
 243         do_query($form, $dbh, $query, @values);
 244       }
 245
 246       if ($form->{"paid_$i"} != 0) {
 247         # add payment
 248         my $project_id = conv_i($form->{"paid_project_id_$i"});
 249         my $gldate = (conv_date($form->{"gldate_$i"}))? conv_date($form->{"gldate_$i"}) : conv_date($form->current_date($myconfig));
 250         $amount = $form->{"paid_$i"} * -1;
 251         $query  = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, source, memo, project_id, taxkey, tax_id, chart_link)
 252                      VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, ?, ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 253                      (SELECT tax_id
 254                       FROM taxkeys
 255                       WHERE chart_id= (SELECT id
 256                                        FROM chart
 257                                        WHERE accno = ?)
 258                       AND startdate <= ?
 259                       ORDER BY startdate DESC LIMIT 1),
 260                      (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 261         @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $gldate, $form->{"source_$i"}, $form->{"memo_$i"}, $project_id, $form->{AR}{"paid_$i"},
 262                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 263         do_query($form, $dbh, $query, @values);
 264
 265         # exchangerate difference for payment
 266         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{"exchangerate_$i"} - 1) * -1, 2);
 267
 268         if ($amount != 0) {
 269           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 270                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 271                        (SELECT tax_id
 272                         FROM taxkeys
 273                         WHERE chart_id= (SELECT id
 274                                          FROM chart
 275                                          WHERE accno = ?)
 276                         AND startdate <= ?
 277                         ORDER BY startdate DESC LIMIT 1),
 278                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 279           @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR}{"paid_$i"},
 280                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 281           do_query($form, $dbh, $query, @values);
 282         }
 283
 284         # exchangerate gain/loss
 285         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{exchangerate} - $form->{"exchangerate_$i"}) * -1, 2);
 286
 287         if ($amount != 0) {
 288           # fetch fxgain and fxloss chart info from defaults if charts aren't already filled in form
 289           if ( !$form->{fxgain_accno} && $::instance_conf->get_fxgain_accno_id ) {
 290             $form->{fxgain_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id)->accno;
 291           };
 292           if ( !$form->{fxloss_accno} && $::instance_conf->get_fxloss_accno_id ) {
 293             $form->{fxloss_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id)->accno;
 294           };
 295           die "fxloss_accno missing" if $amount < 0 and not $form->{fxloss_accno};
 296           die "fxgain_accno missing" if $amount > 0 and not $form->{fxgain_accno};
 297           my $accno = ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno};
 298           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 299                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 300                        (SELECT tax_id
 301                         FROM taxkeys
 302                         WHERE chart_id= (SELECT id
 303                                          FROM chart
 304                                          WHERE accno = ?)
 305                         AND startdate <= ?
 306                         ORDER BY startdate DESC LIMIT 1),
 307                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 308           @values = (conv_i($form->{id}), $accno, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $accno, $accno, conv_date($form->{"datepaid_$i"}), $accno);
 309           do_query($form, $dbh, $query, @values);
 310         }
 311       }
 312
 313       # update exchangerate record
 314       $form->update_exchangerate($dbh, $form->{currency}, $form->{"datepaid_$i"}, $form->{"exchangerate_$i"}, 0)
 315         if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 316     }
 317   }
 318
 319   IO->set_datepaid(table => 'ar', id => $form->{id}, dbh => $dbh);
 320
 321   # safety check datev export
 322   if ($::instance_conf->get_datev_check_on_ar_transaction) {
 323     my $transdate = $::form->{transdate} ? DateTime->from_lxoffice($::form->{transdate}) : undef;
 324     $transdate  ||= DateTime->today;
 325
 326     my $datev = SL::DATEV->new(
 327       exporttype => DATEV_ET_BUCHUNGEN,
 328       format     => DATEV_FORMAT_KNE,
 329       dbh        => $dbh,
 330       trans_id   => $form->{id},
 331     );
 332
 333     $datev->export;
 334
 335     if ($datev->errors) {
 336       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 337     }
 338   }
 339
 340   return 1;
 341 }
 342
 343 sub _delete_payments {
 344   $main::lxdebug->enter_sub();
 345
 346   my ($self, $form, $dbh) = @_;
 347
 348   my @delete_acc_trans_ids;
 349
 350   # Delete old payment entries from acc_trans.
 351   my $query =
 352     qq|SELECT acc_trans_id
 353        FROM acc_trans
 354        WHERE (trans_id = ?) AND fx_transaction
 355
 356        UNION
 357
 358        SELECT at.acc_trans_id
 359        FROM acc_trans at
 360        LEFT JOIN chart c ON (at.chart_id = c.id)
 361        WHERE (trans_id = ?) AND (c.link LIKE '%AR_paid%')|;
 362   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}), conv_i($form->{id}));
 363
 364   $query =
 365     qq|SELECT at.acc_trans_id
 366        FROM acc_trans at
 367        LEFT JOIN chart c ON (at.chart_id = c.id)
 368        WHERE (trans_id = ?)
 369          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 370        ORDER BY at.acc_trans_id
 371        OFFSET 1|;
 372   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}));
 373
 374   if (@delete_acc_trans_ids) {
 375     $query = qq|DELETE FROM acc_trans WHERE acc_trans_id IN (| . join(", ", @delete_acc_trans_ids) . qq|)|;
 376     do_query($form, $dbh, $query);
 377   }
 378
 379   $main::lxdebug->leave_sub();
 380 }
 381
 382 sub post_payment {
 383   my ($self, $myconfig, $form, $locale) = @_;
 384   $main::lxdebug->enter_sub();
 385
 386   my $rc = SL::DB->client->with_transaction(\&_post_payment, $self, $myconfig, $form, $locale);
 387
 388   $::lxdebug->leave_sub;
 389   return $rc;
 390 }
 391
 392 sub _post_payment {
 393   my ($self, $myconfig, $form, $locale) = @_;
 394
 395   my $dbh = SL::DB->client->dbh;
 396
 397   my (%payments, $old_form, $row, $item, $query, %keep_vars);
 398
 399   $old_form = save_form();
 400
 401   # Delete all entries in acc_trans from prior payments.
 402   if (SL::DB::Default->get->payments_changeable != 0) {
 403     $self->_delete_payments($form, $dbh);
 404   }
 405
 406   # Save the new payments the user made before cleaning up $form.
 407   my $payments_re = '^datepaid_\d+$|^gldate_\d+$|^acc_trans_id_\d+$|^memo_\d+$|^source_\d+$|^exchangerate_\d+$|^paid_\d+$|^paid_project_id_\d+$|^AR_paid_\d+$|^paidaccounts$';
 408   map { $payments{$_} = $form->{$_} } grep m/$payments_re/, keys %{ $form };
 409
 410   # Clean up $form so that old content won't tamper the results.
 411   %keep_vars = map { $_, 1 } qw(login password id);
 412   map { delete $form->{$_} unless $keep_vars{$_} } keys %{ $form };
 413
 414   # Retrieve the invoice from the database.
 415   $form->create_links('AR', $myconfig, 'customer', $dbh);
 416
 417   # Restore the payment options from the user input.
 418   map { $form->{$_} = $payments{$_} } keys %payments;
 419
 420   # Set up the content of $form in the way that AR::post_transaction() expects.
 421
 422   $self->setup_form($form, 1);
 423
 424   $form->{exchangerate}    = $form->format_amount($myconfig, $form->{exchangerate});
 425   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
 426
 427   # Get the AR accno (which is normally done by Form::create_links()).
 428   $query =
 429     qq|SELECT c.accno
 430        FROM acc_trans at
 431        LEFT JOIN chart c ON (at.chart_id = c.id)
 432        WHERE (trans_id = ?)
 433          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 434        ORDER BY at.acc_trans_id
 435        LIMIT 1|;
 436
 437   ($form->{ARselected}) = selectfirst_array_query($form, $dbh, $query, conv_i($form->{id}));
 438
 439   # Post the new payments.
 440   $self->post_transaction($myconfig, $form, $dbh, 1);
 441
 442   restore_form($old_form);
 443
 444   return 1;
 445 }
 446
 447 sub delete_transaction {
 448   $main::lxdebug->enter_sub();
 449
 450   my ($self, $myconfig, $form) = @_;
 451
 452   SL::DB->client->with_transaction(sub {
 453     # acc_trans entries are deleted by database triggers.
 454     my $query = qq|DELETE FROM ar WHERE id = ?|;
 455     do_query($form, SL::DB->client->dbh, $query, $form->{id});
 456     1;
 457   }) or do { die SL::DB->client->error };
 458
 459   $main::lxdebug->leave_sub();
 460
 461   return 1;
 462 }
 463
 464 sub ar_transactions {
 465   $main::lxdebug->enter_sub();
 466
 467   my ($self, $myconfig, $form) = @_;
 468
 469   # connect to database
 470   my $dbh = $form->get_standard_dbh($myconfig);
 471
 472   my @values;
 473
 474   my $query =
 475     qq|SELECT DISTINCT a.id, a.invnumber, a.ordnumber, a.cusordnumber, a.transdate, | .
 476     qq|  a.duedate, a.netamount, a.amount, a.paid, | .
 477     qq|  a.invoice, a.datepaid, a.notes, a.shipvia, | .
 478     qq|  a.shippingpoint, a.storno, a.storno_id, a.globalproject_id, | .
 479     qq|  a.marge_total, a.marge_percent, | .
 480     qq|  a.transaction_description, a.direct_debit, | .
 481     qq|  pr.projectnumber AS globalprojectnumber, | .
 482     qq|  c.name, c.customernumber, c.country, c.ustid, b.description as customertype, | .
 483     qq|  c.id as customer_id, | .
 484     qq|  e.name AS employee, | .
 485     qq|  e2.name AS salesman, | .
 486     qq|  dc.dunning_description, | .
 487     qq|  tz.description AS taxzone, | .
 488     qq|  pt.description AS payment_terms, | .
 489     qq|  d.description AS department, | .
 490     qq{  ( SELECT ch.accno || ' -- ' || ch.description
 491            FROM acc_trans at
 492            LEFT JOIN chart ch ON ch.id = at.chart_id
 493            WHERE ch.link ~ 'AR[[:>:]]'
 494             AND at.trans_id = a.id
 495             LIMIT 1
 496           ) AS charts } .
 497     qq|FROM ar a | .
 498     qq|JOIN customer c ON (a.customer_id = c.id) | .
 499     qq|LEFT JOIN contacts cp ON (a.cp_id = cp.cp_id) | .
 500     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 501     qq|LEFT JOIN employee e2 ON (a.salesman_id = e2.id) | .
 502     qq|LEFT JOIN dunning_config dc ON (a.dunning_config_id = dc.id) | .
 503     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id)| .
 504     qq|LEFT JOIN tax_zones tz ON (tz.id = a.taxzone_id)| .
 505     qq|LEFT JOIN payment_terms pt ON (pt.id = a.payment_id)| .
 506     qq|LEFT JOIN business b ON (b.id = c.business_id)| .
 507     qq|LEFT JOIN department d ON (d.id = a.department_id)|;
 508
 509   my $where = "1 = 1";
 510
 511   unless ( $::auth->assert('show_ar_transactions', 1) ) {
 512     $where .= " AND NOT invoice = 'f' ";  # remove ar transactions from Sales -> Reports -> Invoices
 513   };
 514
 515   if ($form->{customernumber}) {
 516     $where .= " AND c.customernumber = ?";
 517     push(@values, trim($form->{customernumber}));
 518   }
 519   if ($form->{customer_id}) {
 520     $where .= " AND a.customer_id = ?";
 521     push(@values, $form->{customer_id});
 522   } elsif ($form->{customer}) {
 523     $where .= " AND c.name ILIKE ?";
 524     push(@values, like($form->{customer}));
 525   }
 526   if ($form->{"cp_name"}) {
 527     $where .= " AND (cp.cp_name ILIKE ? OR cp.cp_givenname ILIKE ?)";
 528     push(@values, (like($form->{"cp_name"}))x2);
 529   }
 530   if ($form->{business_id}) {
 531     my $business_id = $form->{business_id};
 532     $where .= " AND c.business_id = ?";
 533     push(@values, $business_id);
 534   }
 535   if ($form->{department_id}) {
 536     my $department_id = $form->{department_id};
 537     $where .= " AND a.department_id = ?";
 538     push(@values, $department_id);
 539   }
 540   if ($form->{department}) {
 541     my $department = like($form->{department});
 542     $where .= " AND d.description ILIKE ?";
 543     push(@values, $department);
 544   }
 545   foreach my $column (qw(invnumber ordnumber cusordnumber notes transaction_description)) {
 546     if ($form->{$column}) {
 547       $where .= " AND a.$column ILIKE ?";
 548       push(@values, like($form->{$column}));
 549     }
 550   }
 551   if ($form->{"project_id"}) {
 552     $where .=
 553       qq|AND ((a.globalproject_id = ?) OR EXISTS | .
 554       qq|  (SELECT * FROM invoice i | .
 555       qq|   WHERE i.project_id = ? AND i.trans_id = a.id) | .
 556       qq| OR EXISTS | .
 557       qq|  (SELECT * FROM acc_trans at | .
 558       qq|   WHERE at.project_id = ? AND at.trans_id = a.id)| .
 559       qq|  )|;
 560     push(@values, $form->{project_id}, $form->{project_id}, $form->{project_id});
 561   }
 562
 563   if ($form->{transdatefrom}) {
 564     $where .= " AND a.transdate >= ?";
 565     push(@values, trim($form->{transdatefrom}));
 566   }
 567   if ($form->{transdateto}) {
 568     $where .= " AND a.transdate <= ?";
 569     push(@values, trim($form->{transdateto}));
 570   }
 571   if ($form->{duedatefrom}) {
 572     $where .= " AND a.duedate >= ?";
 573     push(@values, trim($form->{duedatefrom}));
 574   }
 575   if ($form->{duedateto}) {
 576     $where .= " AND a.duedate <= ?";
 577     push(@values, trim($form->{duedateto}));
 578   }
 579   if ($form->{open} || $form->{closed}) {
 580     unless ($form->{open} && $form->{closed}) {
 581       $where .= " AND a.amount <> a.paid" if ($form->{open});
 582       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 583     }
 584   }
 585
 586   if (!$main::auth->assert('sales_all_edit', 1)) {
 587     # only show own invoices
 588     $where .= " AND a.employee_id = (select id from employee where login= ?)";
 589     push (@values, $::myconfig{login});
 590   } else {
 591     if ($form->{employee_id}) {
 592       $where .= " AND a.employee_id = ?";
 593       push @values, conv_i($form->{employee_id});
 594     }
 595     if ($form->{salesman_id}) {
 596       $where .= " AND a.salesman_id = ?";
 597       push @values, conv_i($form->{salesman_id});
 598     }
 599   };
 600
 601   if ($form->{parts_partnumber}) {
 602     $where .= <<SQL;
 603       AND EXISTS (
 604         SELECT invoice.trans_id
 605         FROM invoice
 606         LEFT JOIN parts ON (invoice.parts_id = parts.id)
 607         WHERE (invoice.trans_id = a.id)
 608           AND (parts.partnumber ILIKE ?)
 609         LIMIT 1
 610       )
 611 SQL
 612     push @values, like($form->{parts_partnumber});
 613   }
 614
 615   if ($form->{parts_description}) {
 616     $where .= <<SQL;
 617       AND EXISTS (
 618         SELECT invoice.trans_id
 619         FROM invoice
 620         WHERE (invoice.trans_id = a.id)
 621           AND (invoice.description ILIKE ?)
 622         LIMIT 1
 623       )
 624 SQL
 625     push @values, like($form->{parts_description});
 626   }
 627
 628   my ($cvar_where, @cvar_values) = CVar->build_filter_query('module'         => 'CT',
 629                                                             'trans_id_field' => 'c.id',
 630                                                             'filter'         => $form,
 631                                                            );
 632   if ($cvar_where) {
 633     $where .= qq| AND ($cvar_where)|;
 634     push @values, @cvar_values;
 635   }
 636
 637   my @a = qw(transdate invnumber name);
 638   push @a, "employee" if $form->{l_employee};
 639   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 640   my $sortorder = join(', ', map { "$_ $sortdir" } @a);
 641
 642   if (grep({ $_ eq $form->{sort} } qw(id transdate duedate invnumber ordnumber cusordnumber name datepaid employee shippingpoint shipvia transaction_description))) {
 643     $sortorder = $form->{sort} . " $sortdir";
 644   }
 645
 646   $query .= " WHERE $where ORDER BY $sortorder";
 647
 648   my @result = selectall_hashref_query($form, $dbh, $query, @values);
 649
 650   $form->{AR} = [ @result ];
 651
 652   $main::lxdebug->leave_sub();
 653 }
 654
 655 sub get_transdate {
 656   $main::lxdebug->enter_sub();
 657
 658   my ($self, $myconfig, $form) = @_;
 659
 660   # connect to database
 661   my $dbh = SL::DB->client->dbh;
 662
 663   my $query =
 664     "SELECT COALESCE(" .
 665     "  (SELECT transdate FROM ar WHERE id = " .
 666     "    (SELECT MAX(id) FROM ar) LIMIT 1), " .
 667     "  current_date)";
 668   ($form->{transdate}) = $dbh->selectrow_array($query);
 669
 670   $main::lxdebug->leave_sub();
 671 }
 672
 673 sub setup_form {
 674   $main::lxdebug->enter_sub();
 675
 676   my ($self, $form, $for_post_payments) = @_;
 677
 678   my ($exchangerate, $akey, $j, $k, $index, $taxamount, $totaltax, $taxrate, $diff, $totalwithholding, $withholdingrate,
 679       $totalamount, $tax);
 680
 681   # forex
 682   $form->{forex} = $form->{exchangerate};
 683   $exchangerate  = $form->{exchangerate} ? $form->{exchangerate} : 1;
 684
 685   # expected keys: AR, AR_paid, AR_tax, AR_amount
 686   foreach my $key (keys %{ $form->{AR_links} }) {
 687     $j = 0;
 688     $k = 0;
 689
 690     # if there is a value we have an old entry
 691     next unless $form->{acc_trans}{$key};
 692
 693     # do not use old entries for payments. They come from the form
 694     # even if they are not changeable (then they are in hiddens)
 695     next if $for_post_payments && $key eq "AR_paid";
 696
 697     for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 698       if ($key eq "AR_paid") {
 699         $j++;
 700         $form->{"AR_paid_$j"} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 701
 702         $form->{"acc_trans_id_$j"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 703         # reverse paid
 704         $form->{"paid_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 705         $form->{"datepaid_$j"}        = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 706         $form->{"gldate_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 707         $form->{"source_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{source};
 708         $form->{"memo_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 709         $form->{"forex_$j"}           = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 710         $form->{"exchangerate_$i"}    = $form->{"forex_$j"};
 711         $form->{"paid_project_id_$j"} = $form->{acc_trans}{$key}->[$i - 1]->{project_id};
 712         $form->{paidaccounts}++;
 713
 714       } else { # e.g. AR_amount, AR, AR_tax
 715
 716         $akey = $key;
 717         $akey =~ s/AR_//; # e.g. tax, amount, AR, used to store form key tax_$i, amount_$i, ...
 718
 719         if ($key eq "AR_tax" || $key eq "AP_tax") { # AR_tax
 720           $form->{"${key}_$form->{acc_trans}{$key}->[$i-1]->{accno}"}  = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 721           # determine the rounded tax amounts for each account, e.g. tax_1776
 722           $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 723
 724           # check e.g. $form->{1776_rate}, does this make sense for AR_tax charts? Is this ever valid? If it was, totaltax would be calculated twice
 725           if ($form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"} > 0) {
 726             $totaltax += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 727             $taxrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 728
 729           } else {
 730             $totalwithholding += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 731             $withholdingrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 732           }
 733
 734           $index                 = $form->{acc_trans}{$key}->[$i - 1]->{index};
 735           $form->{"tax_$index"}  = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2); # convert the tax_$i amounts
 736           # currently totaltax is the sum of rounded tax amounts, is this correct?
 737           $totaltax             += $form->{"tax_$index"};
 738
 739         } else { # e.g. AR_amount, AR
 740           $k++;
 741           $form->{"${akey}_$k"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 742
 743           if ($akey eq 'amount') {
 744             $form->{rowcount}++;
 745             $totalamount += $form->{"${akey}_$i"};
 746
 747             $form->{"oldprojectnumber_$k"} = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 748             $form->{"projectnumber_$k"}    = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 749             $form->{taxrate}               = $form->{acc_trans}{$key}->[$i - 1]->{rate};
 750             $form->{"project_id_$k"}       = $form->{acc_trans}{$key}->[$i-1]->{project_id};
 751           }
 752
 753           $form->{"${key}_$i"} = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 754
 755           if ($akey eq "AR") {
 756             $form->{ARselected} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 757
 758           } elsif ($akey eq "amount") {
 759             $form->{"${key}_$k"}   = $form->{acc_trans}{$key}->[$i-1]->{accno} . "--" . $form->{acc_trans}{$key}->[$i-1]->{id};
 760             $form->{"taxchart_$k"} = $form->{acc_trans}{$key}->[$i-1]->{id}    . "--" . $form->{acc_trans}{$key}->[$i-1]->{rate};
 761           }
 762         }
 763       }
 764     }
 765   }
 766
 767   $form->{paidaccounts} = 1            if not defined $form->{paidaccounts};
 768
 769   if ($form->{taxincluded} && $form->{taxrate} && $totalamount) {
 770
 771     # add tax to amounts and invtotal
 772     for my $i (1 .. $form->{rowcount}) {
 773       $taxamount            = ($totaltax + $totalwithholding) * $form->{"amount_$i"} / $totalamount;
 774       $tax                  = $form->round_amount($taxamount, 2);
 775       $diff                += ($taxamount - $tax);
 776       $form->{"amount_$i"} += $form->{"tax_$i"};
 777     }
 778     $form->{amount_1} += $form->round_amount($diff, 2);
 779   }
 780
 781   $taxamount   = $form->round_amount($taxamount, 2);
 782   $form->{tax} = $taxamount;
 783
 784   $form->{invtotal} = $totalamount + $totaltax;
 785
 786   $main::lxdebug->leave_sub();
 787 }
 788
 789 sub storno {
 790   my ($self, $form, $myconfig, $id) = @_;
 791   $main::lxdebug->enter_sub();
 792
 793   my $rc = SL::DB->client->with_transaction(\&_storno, $self, $form, $myconfig, $id);
 794
 795   $::lxdebug->leave_sub;
 796   return $rc;
 797 }
 798
 799
 800 sub _storno {
 801   my ($self, $form, $myconfig, $id) = @_;
 802
 803   my ($query, $new_id, $storno_row, $acc_trans_rows);
 804   my $dbh = SL::DB->client->dbh;
 805
 806   $query = qq|SELECT nextval('glid')|;
 807   ($new_id) = selectrow_query($form, $dbh, $query);
 808
 809   $query = qq|SELECT * FROM ar WHERE id = ?|;
 810   $storno_row = selectfirst_hashref_query($form, $dbh, $query, $id);
 811
 812   $storno_row->{id}         = $new_id;
 813   $storno_row->{storno_id}  = $id;
 814   $storno_row->{storno}     = 't';
 815   $storno_row->{invnumber}  = 'Storno-' . $storno_row->{invnumber};
 816   $storno_row->{amount}    *= -1;
 817   $storno_row->{netamount} *= -1;
 818   $storno_row->{paid}       = $storno_row->{amount};
 819
 820   delete @$storno_row{qw(itime mtime)};
 821
 822   $query = sprintf 'INSERT INTO ar (%s) VALUES (%s)', join(', ', keys %$storno_row), join(', ', map '?', values %$storno_row);
 823   do_query($form, $dbh, $query, (values %$storno_row));
 824
 825   $query = qq|UPDATE ar SET paid = amount + paid, storno = 't' WHERE id = ?|;
 826   do_query($form, $dbh, $query, $id);
 827
 828   $form->new_lastmtime('ar') if $id == $form->{id};
 829
 830   # now copy acc_trans entries
 831   $query = qq|SELECT a.*, c.link FROM acc_trans a LEFT JOIN chart c ON a.chart_id = c.id WHERE a.trans_id = ? ORDER BY a.acc_trans_id|;
 832   my $rowref = selectall_hashref_query($form, $dbh, $query, $id);
 833
 834   # kill all entries containing payments, which are the last 2n rows, of which the last has link =~ /paid/
 835   while ($rowref->[-1]{link} =~ /paid/) {
 836     splice(@$rowref, -2);
 837   }
 838
 839   for my $row (@$rowref) {
 840     delete @$row{qw(itime mtime link acc_trans_id)};
 841     $query = sprintf 'INSERT INTO acc_trans (%s) VALUES (%s)', join(', ', keys %$row), join(', ', map '?', values %$row);
 842     $row->{trans_id}   = $new_id;
 843     $row->{amount}    *= -1;
 844     do_query($form, $dbh, $query, (values %$row));
 845   }
 846
 847   map { IO->set_datepaid(table => 'ar', id => $_, dbh => $dbh) } ($id, $new_id);
 848
 849   return 1;
 850 }
 851
 852
 853 1;