SL/AR.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 # Accounts Receivable module backend routines
  32 #
  33 #======================================================================
  34
  35 package AR;
  36
  37 use Data::Dumper;
  38 use SL::DATEV qw(:CONSTANTS);
  39 use SL::DBUtils;
  40 use SL::IO;
  41 use SL::MoreCommon;
  42 use SL::DB::Default;
  43
  44 use strict;
  45
  46 sub post_transaction {
  47   $main::lxdebug->enter_sub();
  48
  49   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  50
  51   my ($query, $sth, $null, $taxrate, $amount, $tax);
  52   my $exchangerate = 0;
  53   my $i;
  54
  55   my @values;
  56
  57   my $dbh = $provided_dbh ? $provided_dbh : $form->dbconnect_noauto($myconfig);
  58   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
  59
  60   # set exchangerate
  61   $form->{exchangerate} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
  62       ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy') ||
  63         $form->parse_amount($myconfig, $form->{exchangerate}) );
  64
  65   # get the charts selected
  66   map { ($form->{AR_amounts}{"amount_$_"}) = split /--/, $form->{"AR_amount_$_"} } 1 .. $form->{rowcount};
  67
  68   $form->{AR_amounts}{receivables} = $form->{ARselected};
  69   $form->{AR}{receivables}         = $form->{ARselected};
  70
  71   # parsing
  72   for $i (1 .. $form->{rowcount}) {
  73     $form->{"amount_$i"} = $form->round_amount($form->parse_amount($myconfig, $form->{"amount_$i"}) * $form->{exchangerate}, 2);
  74     $form->{amount}     += $form->{"amount_$i"};
  75     $form->{"tax_$i"}    = $form->parse_amount($myconfig, $form->{"tax_$i"});
  76   }
  77
  78   # this is for ar
  79   $form->{tax}       = 0;
  80   $form->{netamount} = 0;
  81   $form->{total_tax} = 0;
  82
  83   # taxincluded doesn't make sense if there is no amount
  84   $form->{taxincluded} = 0 unless $form->{amount};
  85
  86   for $i (1 .. $form->{rowcount}) {
  87     ($form->{"tax_id_$i"}) = split /--/, $form->{"taxchart_$i"};
  88
  89     $query = qq|SELECT c.accno, t.taxkey, t.rate FROM tax t LEFT JOIN chart c ON (c.id = t.chart_id) WHERE t.id = ? ORDER BY c.accno|;
  90     ($form->{AR_amounts}{"tax_$i"}, $form->{"taxkey_$i"}, $form->{"taxrate_$i"}) = selectrow_query($form, $dbh, $query, $form->{"tax_id_$i"});
  91
  92     if ($form->{taxincluded} *= 1) {
  93       $tax = $form->{"korrektur_$i"}
  94         ? $form->{"tax_$i"}
  95         : $form->{"amount_$i"} - ($form->{"amount_$i"} / ($form->{"taxrate_$i"} + 1)); # should be same as taxrate * amount / (taxrate + 1)
  96       $form->{"amount_$i"} = $form->round_amount($form->{"amount_$i"} - $tax, 2);
  97       $form->{"tax_$i"}    = $form->round_amount($tax, 2);
  98     } else {
  99       $form->{"tax_$i"}    = $form->{"amount_$i"} * $form->{"taxrate_$i"} unless $form->{"korrektur_$i"};
 100       $form->{"tax_$i"}    = $form->round_amount($form->{"tax_$i"} * $form->{exchangerate}, 2);
 101     }
 102     $form->{netamount}  += $form->{"amount_$i"};
 103     $form->{total_tax}  += $form->{"tax_$i"};
 104   }
 105
 106   # adjust paidaccounts if there is no date in the last row
 107   # this does not apply to stornos, where the paid field is set manually
 108   unless ($form->{storno}) {
 109     $form->{paidaccounts}-- unless $form->{"datepaid_$form->{paidaccounts}"};
 110     $form->{paid} = 0;
 111
 112     # add payments
 113     for $i (1 .. $form->{paidaccounts}) {
 114       $form->{"paid_$i"} = $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}), 2);
 115       $form->{paid}     += $form->{"paid_$i"};
 116       $form->{datepaid}  = $form->{"datepaid_$i"};
 117     }
 118
 119     $form->{amount} = $form->{netamount} + $form->{total_tax};
 120   }
 121   $form->{paid}   = $form->round_amount($form->{paid} * ($form->{exchangerate} || 1), 2);
 122
 123   ($null, $form->{employee_id}) = split /--/, $form->{employee};
 124
 125   $form->get_employee($dbh) unless $form->{employee_id};
 126
 127   # if we have an id delete old records else make one
 128   if (!$payments_only) {
 129     if ($form->{id}) {
 130       # delete detail records
 131       $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 132       do_query($form, $dbh, $query, $form->{id});
 133
 134     } else {
 135       $query = qq|SELECT nextval('glid')|;
 136       ($form->{id}) = selectrow_query($form, $dbh, $query);
 137       $query = qq|INSERT INTO ar (id, invnumber, employee_id, curr) VALUES (?, 'dummy', ?, (SELECT id FROM currencies WHERE curr=?))|;
 138       do_query($form, $dbh, $query, $form->{id}, $form->{employee_id}, $form->{currency});
 139       $form->{invnumber} = $form->update_defaults($myconfig, "invnumber", $dbh) unless $form->{invnumber};
 140     }
 141   }
 142
 143   # update department
 144   ($null, $form->{department_id}) = split(/--/, $form->{department});
 145
 146   # amount for AR account
 147   $form->{receivables} = $form->round_amount($form->{amount}, 2) * -1;
 148
 149   # update exchangerate
 150   $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate}, $form->{exchangerate}, 0)
 151     if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'buy');
 152
 153   if (!$payments_only) {
 154     $query =
 155       qq|UPDATE ar set
 156            invnumber = ?, ordnumber = ?, transdate = ?, customer_id = ?,
 157            taxincluded = ?, amount = ?, duedate = ?, paid = ?,
 158            netamount = ?, notes = ?, department_id = ?,
 159            employee_id = ?, storno = ?, storno_id = ?, globalproject_id = ?,
 160            direct_debit = ?
 161          WHERE id = ?|;
 162     my @values = ($form->{invnumber}, $form->{ordnumber}, conv_date($form->{transdate}), conv_i($form->{customer_id}), $form->{taxincluded} ? 't' : 'f', $form->{amount},
 163                   conv_date($form->{duedate}), $form->{paid}, $form->{netamount}, $form->{notes}, conv_i($form->{department_id}),
 164                   conv_i($form->{employee_id}), $form->{storno} ? 't' : 'f', $form->{storno_id},
 165                   conv_i($form->{globalproject_id}), $form->{direct_debit} ? 't' : 'f', conv_i($form->{id}));
 166     do_query($form, $dbh, $query, @values);
 167
 168     # add individual transactions for AR, amount and taxes
 169     for $i (1 .. $form->{rowcount}) {
 170       if ($form->{"amount_$i"} != 0) {
 171         my $project_id = conv_i($form->{"project_id_$i"});
 172
 173         # insert detail records in acc_trans
 174         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 175                      VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 176         @values = (conv_i($form->{id}), $form->{AR_amounts}{"amount_$i"}, conv_i($form->{"amount_$i"}), conv_date($form->{transdate}), $project_id,
 177                    conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"amount_$i"});
 178         do_query($form, $dbh, $query, @values);
 179
 180         if ($form->{"tax_$i"} != 0) {
 181           # insert detail records in acc_trans
 182           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 183                        VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?, (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 184           @values = (conv_i($form->{id}), $form->{AR_amounts}{"tax_$i"}, conv_i($form->{"tax_$i"}), conv_date($form->{transdate}), $project_id,
 185                      conv_i($form->{"taxkey_$i"}), conv_i($form->{"tax_id_$i"}), $form->{AR_amounts}{"tax_$i"});
 186           do_query($form, $dbh, $query, @values);
 187         }
 188       }
 189     }
 190
 191     # add recievables
 192     $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, taxkey, tax_id, chart_link)
 193                  VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 194                  (SELECT tax_id
 195                   FROM taxkeys
 196                   WHERE chart_id= (SELECT id
 197                                    FROM chart
 198                                    WHERE accno = ?)
 199                   AND startdate <= ?
 200                   ORDER BY startdate DESC LIMIT 1),
 201                  (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 202     @values = (conv_i($form->{id}), $form->{AR_amounts}{receivables}, conv_i($form->{receivables}), conv_date($form->{transdate}),
 203                 $form->{AR_amounts}{receivables}, $form->{AR_amounts}{receivables}, conv_date($form->{transdate}), $form->{AR_amounts}{receivables});
 204     do_query($form, $dbh, $query, @values);
 205
 206   } else {
 207     # Record paid amount.
 208     $query = qq|UPDATE ar SET paid = ?, datepaid = ? WHERE id = ?|;
 209     do_query($form, $dbh, $query,  $form->{paid}, $form->{paid} ? conv_date($form->{datepaid}) : undef, conv_i($form->{id}));
 210   }
 211
 212   # add paid transactions
 213   for my $i (1 .. $form->{paidaccounts}) {
 214
 215     if ($form->{"acc_trans_id_$i"} && $payments_only && (SL::DB::Default->get->payments_changeable == 0)) {
 216       next;
 217     }
 218
 219     if ($form->{"paid_$i"} != 0) {
 220       my $project_id = conv_i($form->{"paid_project_id_$i"});
 221
 222       $form->{"AR_paid_$i"} =~ s/\"//g;
 223       ($form->{AR}{"paid_$i"}) = split(/--/, $form->{"AR_paid_$i"});
 224       $form->{"datepaid_$i"} = $form->{transdate}
 225         unless ($form->{"datepaid_$i"});
 226
 227       $form->{"exchangerate_$i"} = ($form->{currency} eq $form->{defaultcurrency}) ? 1 :
 228         ( $form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy') ||
 229           $form->parse_amount($myconfig, $form->{"exchangerate_$i"}) );
 230
 231       # if there is no amount and invtotal is zero there is no exchangerate
 232       $form->{exchangerate} = $form->{"exchangerate_$i"}
 233         if ($form->{amount} == 0 && $form->{netamount} == 0);
 234
 235       # receivables amount
 236       $amount = $form->round_amount($form->{"paid_$i"} * $form->{exchangerate}, 2);
 237
 238       if ($amount != 0) {
 239         # add receivable
 240         $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)
 241                      VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 242                      (SELECT tax_id
 243                       FROM taxkeys
 244                       WHERE chart_id= (SELECT id
 245                                        FROM chart
 246                                        WHERE accno = ?)
 247                       AND startdate <= ?
 248                       ORDER BY startdate DESC LIMIT 1),
 249                      (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 250         @values = (conv_i($form->{id}), $form->{AR}{receivables}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR}{receivables}, $form->{AR}{receivables}, conv_date($form->{"datepaid_$i"}),
 251         $form->{AR}{receivables});
 252
 253         do_query($form, $dbh, $query, @values);
 254       }
 255
 256       if ($form->{"paid_$i"} != 0) {
 257         # add payment
 258         my $project_id = conv_i($form->{"paid_project_id_$i"});
 259         my $gldate = (conv_date($form->{"gldate_$i"}))? conv_date($form->{"gldate_$i"}) : conv_date($form->current_date($myconfig));
 260         $amount = $form->{"paid_$i"} * -1;
 261         $query  = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, source, memo, project_id, taxkey, tax_id, chart_link)
 262                      VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, ?, ?, ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 263                      (SELECT tax_id
 264                       FROM taxkeys
 265                       WHERE chart_id= (SELECT id
 266                                        FROM chart
 267                                        WHERE accno = ?)
 268                       AND startdate <= ?
 269                       ORDER BY startdate DESC LIMIT 1),
 270                      (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 271         @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $gldate, $form->{"source_$i"}, $form->{"memo_$i"}, $project_id, $form->{AR}{"paid_$i"},
 272                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 273         do_query($form, $dbh, $query, @values);
 274
 275         # exchangerate difference for payment
 276         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{"exchangerate_$i"} - 1) * -1, 2);
 277
 278         if ($amount != 0) {
 279           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 280                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 281                        (SELECT tax_id
 282                         FROM taxkeys
 283                         WHERE chart_id= (SELECT id
 284                                          FROM chart
 285                                          WHERE accno = ?)
 286                         AND startdate <= ?
 287                         ORDER BY startdate DESC LIMIT 1),
 288                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 289           @values = (conv_i($form->{id}), $form->{AR}{"paid_$i"}, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $form->{AR}{"paid_$i"},
 290                     $form->{AR}{"paid_$i"}, conv_date($form->{"datepaid_$i"}), $form->{AR}{"paid_$i"});
 291           do_query($form, $dbh, $query, @values);
 292         }
 293
 294         # exchangerate gain/loss
 295         $amount = $form->round_amount( $form->{"paid_$i"} * ($form->{exchangerate} - $form->{"exchangerate_$i"}) * -1, 2);
 296
 297         if ($amount != 0) {
 298           my $accno = ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno};
 299           $query = qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link)
 300                        VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, (SELECT taxkey_id FROM chart WHERE accno = ?),
 301                        (SELECT tax_id
 302                         FROM taxkeys
 303                         WHERE chart_id= (SELECT id
 304                                          FROM chart
 305                                          WHERE accno = ?)
 306                         AND startdate <= ?
 307                         ORDER BY startdate DESC LIMIT 1),
 308                        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 309           @values = (conv_i($form->{id}), $accno, $amount, conv_date($form->{"datepaid_$i"}), $project_id, $accno, $accno, conv_date($form->{"datepaid_$i"}), $accno);
 310           do_query($form, $dbh, $query, @values);
 311         }
 312       }
 313
 314       # update exchangerate record
 315       $form->update_exchangerate($dbh, $form->{currency}, $form->{"datepaid_$i"}, $form->{"exchangerate_$i"}, 0)
 316         if ($form->{currency} ne $form->{defaultcurrency}) && !$form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 317     }
 318   }
 319
 320   IO->set_datepaid(table => 'ar', id => $form->{id}, dbh => $dbh);
 321
 322   # safety check datev export
 323   if ($::instance_conf->get_datev_check_on_ar_transaction) {
 324     my $transdate = $::form->{transdate} ? DateTime->from_lxoffice($::form->{transdate}) : undef;
 325     $transdate  ||= DateTime->today;
 326
 327     my $datev = SL::DATEV->new(
 328       exporttype => DATEV_ET_BUCHUNGEN,
 329       format     => DATEV_FORMAT_KNE,
 330       dbh        => $dbh,
 331       from       => $transdate,
 332       to         => $transdate,
 333     );
 334
 335     $datev->export;
 336
 337     if ($datev->errors) {
 338       $dbh->rollback;
 339       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 340     }
 341   }
 342
 343   my $rc = 1;
 344   if (!$provided_dbh) {
 345     $rc = $dbh->commit();
 346     $dbh->disconnect();
 347   }
 348
 349   $main::lxdebug->leave_sub() and return $rc;
 350 }
 351
 352 sub _delete_payments {
 353   $main::lxdebug->enter_sub();
 354
 355   my ($self, $form, $dbh) = @_;
 356
 357   my @delete_acc_trans_ids;
 358
 359   # Delete old payment entries from acc_trans.
 360   my $query =
 361     qq|SELECT acc_trans_id
 362        FROM acc_trans
 363        WHERE (trans_id = ?) AND fx_transaction
 364
 365        UNION
 366
 367        SELECT at.acc_trans_id
 368        FROM acc_trans at
 369        LEFT JOIN chart c ON (at.chart_id = c.id)
 370        WHERE (trans_id = ?) AND (c.link LIKE '%AR_paid%')|;
 371   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}), conv_i($form->{id}));
 372
 373   $query =
 374     qq|SELECT at.acc_trans_id
 375        FROM acc_trans at
 376        LEFT JOIN chart c ON (at.chart_id = c.id)
 377        WHERE (trans_id = ?)
 378          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 379        ORDER BY at.acc_trans_id
 380        OFFSET 1|;
 381   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}));
 382
 383   if (@delete_acc_trans_ids) {
 384     $query = qq|DELETE FROM acc_trans WHERE acc_trans_id IN (| . join(", ", @delete_acc_trans_ids) . qq|)|;
 385     do_query($form, $dbh, $query);
 386   }
 387
 388   $main::lxdebug->leave_sub();
 389 }
 390
 391 sub post_payment {
 392   $main::lxdebug->enter_sub();
 393
 394   my ($self, $myconfig, $form, $locale) = @_;
 395
 396   # connect to database, turn off autocommit
 397   my $dbh = $form->dbconnect_noauto($myconfig);
 398
 399   my (%payments, $old_form, $row, $item, $query, %keep_vars);
 400
 401   $old_form = save_form();
 402
 403   # Delete all entries in acc_trans from prior payments.
 404   if (SL::DB::Default->get->payments_changeable != 0) {
 405     $self->_delete_payments($form, $dbh);
 406   }
 407
 408   # Save the new payments the user made before cleaning up $form.
 409   my $payments_re = '^datepaid_\d+$|^gldate_\d+$|^acc_trans_id_\d+$|^memo_\d+$|^source_\d+$|^exchangerate_\d+$|^paid_\d+$|^paid_project_id_\d+$|^AR_paid_\d+$|^paidaccounts$';
 410   map { $payments{$_} = $form->{$_} } grep m/$payments_re/, keys %{ $form };
 411
 412   # Clean up $form so that old content won't tamper the results.
 413   %keep_vars = map { $_, 1 } qw(login password id);
 414   map { delete $form->{$_} unless $keep_vars{$_} } keys %{ $form };
 415
 416   # Retrieve the invoice from the database.
 417   $form->create_links('AR', $myconfig, 'customer', $dbh);
 418
 419   # Restore the payment options from the user input.
 420   map { $form->{$_} = $payments{$_} } keys %payments;
 421
 422   # Set up the content of $form in the way that AR::post_transaction() expects.
 423
 424   $self->setup_form($form, 1);
 425
 426   $form->{exchangerate}    = $form->format_amount($myconfig, $form->{exchangerate});
 427   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
 428
 429   # Get the AR accno (which is normally done by Form::create_links()).
 430   $query =
 431     qq|SELECT c.accno
 432        FROM acc_trans at
 433        LEFT JOIN chart c ON (at.chart_id = c.id)
 434        WHERE (trans_id = ?)
 435          AND ((c.link = 'AR') OR (c.link LIKE '%:AR') OR (c.link LIKE 'AR:%'))
 436        ORDER BY at.acc_trans_id
 437        LIMIT 1|;
 438
 439   ($form->{ARselected}) = selectfirst_array_query($form, $dbh, $query, conv_i($form->{id}));
 440
 441   # Post the new payments.
 442   $self->post_transaction($myconfig, $form, $dbh, 1);
 443
 444   restore_form($old_form);
 445
 446   my $rc = $dbh->commit();
 447   $dbh->disconnect();
 448
 449   $main::lxdebug->leave_sub();
 450
 451   return $rc;
 452 }
 453
 454 sub delete_transaction {
 455   $main::lxdebug->enter_sub();
 456
 457   my ($self, $myconfig, $form) = @_;
 458
 459   # connect to database, turn AutoCommit off
 460   my $dbh = $form->dbconnect_noauto($myconfig);
 461
 462   # acc_trans entries are deleted by database triggers.
 463   my $query = qq|DELETE FROM ar WHERE id = ?|;
 464   do_query($form, $dbh, $query, $form->{id});
 465
 466   # commit
 467   my $rc = $dbh->commit;
 468   $dbh->disconnect;
 469
 470   $main::lxdebug->leave_sub();
 471
 472   return $rc;
 473 }
 474
 475 sub ar_transactions {
 476   $main::lxdebug->enter_sub();
 477
 478   my ($self, $myconfig, $form) = @_;
 479
 480   # connect to database
 481   my $dbh = $form->get_standard_dbh($myconfig);
 482
 483   my @values;
 484
 485   my $query =
 486     qq|SELECT DISTINCT a.id, a.invnumber, a.ordnumber, a.transdate, | .
 487     qq|  a.duedate, a.netamount, a.amount, a.paid, | .
 488     qq|  a.invoice, a.datepaid, a.terms, a.notes, a.shipvia, | .
 489     qq|  a.shippingpoint, a.storno, a.storno_id, a.globalproject_id, | .
 490     qq|  a.marge_total, a.marge_percent, | .
 491     qq|  a.transaction_description, | .
 492     qq|  pr.projectnumber AS globalprojectnumber, | .
 493     qq|  c.name, c.customernumber, c.country, c.ustid, b.description as customertype, | .
 494     qq|  c.id as customer_id, | .
 495     qq|  e.name AS employee, | .
 496     qq|  e2.name AS salesman, | .
 497     qq|  tz.description AS taxzone, | .
 498     qq|  pt.description AS payment_terms, | .
 499     qq{  ( SELECT ch.accno || ' -- ' || ch.description
 500            FROM acc_trans at
 501            LEFT JOIN chart ch ON ch.id = at.chart_id
 502            WHERE ch.link ~ 'AR[[:>:]]'
 503             AND at.trans_id = a.id
 504             LIMIT 1
 505           ) AS charts } .
 506     qq|FROM ar a | .
 507     qq|JOIN customer c ON (a.customer_id = c.id) | .
 508     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 509     qq|LEFT JOIN employee e2 ON (a.salesman_id = e2.id) | .
 510     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id)| .
 511     qq|LEFT JOIN tax_zones tz ON (tz.id = c.taxzone_id)| .
 512     qq|LEFT JOIN payment_terms pt ON (pt.id = c.payment_id)| .
 513     qq|LEFT JOIN business b ON (b.id = c.business_id)| .
 514     qq|LEFT JOIN department d ON (d.id = a.department_id)|;
 515
 516   my $where = "1 = 1";
 517   if ($form->{customernumber}) {
 518     $where .= " AND c.customernumber = ?";
 519     push(@values, $form->{customernumber});
 520   }
 521   if ($form->{customer_id}) {
 522     $where .= " AND a.customer_id = ?";
 523     push(@values, $form->{customer_id});
 524   } elsif ($form->{customer}) {
 525     $where .= " AND c.name ILIKE ?";
 526     push(@values, $form->like($form->{customer}));
 527   }
 528   if ($form->{business_id}) {
 529     my $business_id = $form->{business_id};
 530     $where .= " AND c.business_id = ?";
 531     push(@values, $business_id);
 532   }
 533   if ($form->{department_id}) {
 534     my $department_id = $form->{department_id};
 535     $where .= " AND a.department_id = ?";
 536     push(@values, $department_id);
 537   }
 538   if ($form->{department}) {
 539     my $department = "%" . $form->{department} . "%";
 540     $where .= " AND d.description ILIKE ?";
 541     push(@values, $department);
 542   }
 543   foreach my $column (qw(invnumber ordnumber notes transaction_description)) {
 544     if ($form->{$column}) {
 545       $where .= " AND a.$column ILIKE ?";
 546       push(@values, $form->like($form->{$column}));
 547     }
 548   }
 549   if ($form->{"project_id"}) {
 550     $where .=
 551       qq|AND ((a.globalproject_id = ?) OR EXISTS | .
 552       qq|  (SELECT * FROM invoice i | .
 553       qq|   WHERE i.project_id = ? AND i.trans_id = a.id) | .
 554       qq| OR EXISTS | .
 555       qq|  (SELECT * FROM acc_trans at | .
 556       qq|   WHERE at.project_id = ? AND at.trans_id = a.id)| .
 557       qq|  )|;
 558     push(@values, $form->{project_id}, $form->{project_id}, $form->{project_id});
 559   }
 560
 561   if ($form->{transdatefrom}) {
 562     $where .= " AND a.transdate >= ?";
 563     push(@values, $form->{transdatefrom});
 564   }
 565   if ($form->{transdateto}) {
 566     $where .= " AND a.transdate <= ?";
 567     push(@values, $form->{transdateto});
 568   }
 569   if ($form->{open} || $form->{closed}) {
 570     unless ($form->{open} && $form->{closed}) {
 571       $where .= " AND a.amount <> a.paid" if ($form->{open});
 572       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 573     }
 574   }
 575
 576   if (!$main::auth->assert('sales_all_edit', 1)) {
 577     # only show own invoices
 578     $where .= " AND a.employee_id = (select id from employee where login= ?)";
 579     push (@values, $form->{login});
 580   } else {
 581     if ($form->{employee_id}) {
 582       $where .= " AND a.employee_id = ?";
 583       push @values, conv_i($form->{employee_id});
 584     }
 585     if ($form->{salesman_id}) {
 586       $where .= " AND a.salesman_id = ?";
 587       push @values, conv_i($form->{salesman_id});
 588     }
 589   };
 590
 591   my @a = qw(transdate invnumber name);
 592   push @a, "employee" if $form->{l_employee};
 593   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 594   my $sortorder = join(', ', map { "$_ $sortdir" } @a);
 595
 596   if (grep({ $_ eq $form->{sort} } qw(id transdate duedate invnumber ordnumber name datepaid employee shippingpoint shipvia transaction_description))) {
 597     $sortorder = $form->{sort} . " $sortdir";
 598   }
 599
 600   $query .= " WHERE $where ORDER BY $sortorder";
 601
 602   my @result = selectall_hashref_query($form, $dbh, $query, @values);
 603
 604   $form->{AR} = [ @result ];
 605
 606   $main::lxdebug->leave_sub();
 607 }
 608
 609 sub get_transdate {
 610   $main::lxdebug->enter_sub();
 611
 612   my ($self, $myconfig, $form) = @_;
 613
 614   # connect to database
 615   my $dbh = $form->dbconnect($myconfig);
 616
 617   my $query =
 618     "SELECT COALESCE(" .
 619     "  (SELECT transdate FROM ar WHERE id = " .
 620     "    (SELECT MAX(id) FROM ar) LIMIT 1), " .
 621     "  current_date)";
 622   ($form->{transdate}) = $dbh->selectrow_array($query);
 623
 624   $dbh->disconnect;
 625
 626   $main::lxdebug->leave_sub();
 627 }
 628
 629 sub setup_form {
 630   $main::lxdebug->enter_sub();
 631
 632   my ($self, $form, $for_post_payments) = @_;
 633
 634   my ($exchangerate, $akey, $j, $k, $index, $taxamount, $totaltax, $taxrate, $diff, $totalwithholding, $withholdingrate,
 635       $totalamount, $taxincluded, $tax);
 636
 637   # forex
 638   $form->{forex} = $form->{exchangerate};
 639   $exchangerate  = $form->{exchangerate} ? $form->{exchangerate} : 1;
 640
 641   foreach my $key (keys %{ $form->{AR_links} }) {
 642     $j = 0;
 643     $k = 0;
 644
 645     # if there is a value we have an old entry
 646     next unless $form->{acc_trans}{$key};
 647
 648     # do not use old entries for payments. They come from the form
 649     # even if they are not changeable (then they are in hiddens)
 650     next if $for_post_payments && $key eq "AR_paid";
 651
 652     for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 653       if ($key eq "AR_paid") {
 654         $j++;
 655         $form->{"AR_paid_$j"} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 656
 657         $form->{"acc_trans_id_$j"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 658         # reverse paid
 659         $form->{"paid_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 660         $form->{"datepaid_$j"}        = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 661         $form->{"gldate_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 662         $form->{"source_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{source};
 663         $form->{"memo_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 664         $form->{"forex_$j"}           = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 665         $form->{"exchangerate_$i"}    = $form->{"forex_$j"};
 666         $form->{"paid_project_id_$j"} = $form->{acc_trans}{$key}->[$i - 1]->{project_id};
 667         $form->{paidaccounts}++;
 668
 669       } else {
 670
 671         $akey = $key;
 672         $akey =~ s/AR_//;
 673
 674         if ($key eq "AR_tax" || $key eq "AP_tax") {
 675           $form->{"${key}_$form->{acc_trans}{$key}->[$i-1]->{accno}"}  = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 676           $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 677
 678           if ($form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"} > 0) {
 679             $totaltax += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 680             $taxrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 681
 682           } else {
 683             $totalwithholding += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 684             $withholdingrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 685           }
 686
 687           $index                 = $form->{acc_trans}{$key}->[$i - 1]->{index};
 688           $form->{"tax_$index"}  = $form->{acc_trans}{$key}->[$i - 1]->{amount};
 689           $totaltax             += $form->{"tax_$index"};
 690
 691         } else {
 692           $k++;
 693           $form->{"${akey}_$k"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 694
 695           if ($akey eq 'amount') {
 696             $form->{rowcount}++;
 697             $totalamount += $form->{"${akey}_$i"};
 698
 699             $form->{"oldprojectnumber_$k"} = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 700             $form->{"projectnumber_$k"}    = $form->{acc_trans}{$key}->[$i-1]->{projectnumber};
 701             $form->{taxrate}               = $form->{acc_trans}{$key}->[$i - 1]->{rate};
 702             $form->{"project_id_$k"}       = $form->{acc_trans}{$key}->[$i-1]->{project_id};
 703           }
 704
 705           $form->{"${key}_$i"} = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 706
 707           if ($akey eq "AR") {
 708             $form->{ARselected} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 709
 710           } elsif ($akey eq "amount") {
 711             $form->{"${key}_$k"}   = $form->{acc_trans}{$key}->[$i-1]->{accno} . "--" . $form->{acc_trans}{$key}->[$i-1]->{id};
 712             $form->{"taxchart_$k"} = $form->{acc_trans}{$key}->[$i-1]->{id}    . "--" . $form->{acc_trans}{$key}->[$i-1]->{rate};
 713           }
 714         }
 715       }
 716     }
 717   }
 718
 719   $form->{taxincluded}  = $taxincluded if ($form->{id});
 720   $form->{paidaccounts} = 1            if not defined $form->{paidaccounts};
 721
 722   if ($form->{taxincluded} && $form->{taxrate} && $totalamount) {
 723
 724     # add tax to amounts and invtotal
 725     for my $i (1 .. $form->{rowcount}) {
 726       $taxamount            = ($totaltax + $totalwithholding) * $form->{"amount_$i"} / $totalamount;
 727       $tax                  = $form->round_amount($taxamount, 2);
 728       $diff                += ($taxamount - $tax);
 729       $form->{"amount_$i"} += $form->{"tax_$i"};
 730     }
 731     $form->{amount_1} += $form->round_amount($diff, 2);
 732   }
 733
 734   $taxamount   = $form->round_amount($taxamount, 2);
 735   $form->{tax} = $taxamount;
 736
 737   $form->{invtotal} = $totalamount + $totaltax;
 738
 739   $main::lxdebug->leave_sub();
 740 }
 741
 742 sub storno {
 743   $main::lxdebug->enter_sub();
 744
 745   my ($self, $form, $myconfig, $id) = @_;
 746
 747   my ($query, $new_id, $storno_row, $acc_trans_rows);
 748   my $dbh = $form->get_standard_dbh($myconfig);
 749
 750   $query = qq|SELECT nextval('glid')|;
 751   ($new_id) = selectrow_query($form, $dbh, $query);
 752
 753   $query = qq|SELECT * FROM ar WHERE id = ?|;
 754   $storno_row = selectfirst_hashref_query($form, $dbh, $query, $id);
 755
 756   $storno_row->{id}         = $new_id;
 757   $storno_row->{storno_id}  = $id;
 758   $storno_row->{storno}     = 't';
 759   $storno_row->{invnumber}  = 'Storno-' . $storno_row->{invnumber};
 760   $storno_row->{amount}    *= -1;
 761   $storno_row->{netamount} *= -1;
 762   $storno_row->{paid}       = $storno_row->{amount};
 763
 764   delete @$storno_row{qw(itime mtime)};
 765
 766   $query = sprintf 'INSERT INTO ar (%s) VALUES (%s)', join(', ', keys %$storno_row), join(', ', map '?', values %$storno_row);
 767   do_query($form, $dbh, $query, (values %$storno_row));
 768
 769   $query = qq|UPDATE ar SET paid = amount + paid, storno = 't' WHERE id = ?|;
 770   do_query($form, $dbh, $query, $id);
 771
 772   # now copy acc_trans entries
 773   $query = qq|SELECT a.*, c.link FROM acc_trans a LEFT JOIN chart c ON a.chart_id = c.id WHERE a.trans_id = ? ORDER BY a.acc_trans_id|;
 774   my $rowref = selectall_hashref_query($form, $dbh, $query, $id);
 775
 776   # kill all entries containing payments, which are the last 2n rows, of which the last has link =~ /paid/
 777   while ($rowref->[-1]{link} =~ /paid/) {
 778     splice(@$rowref, -2);
 779   }
 780
 781   for my $row (@$rowref) {
 782     delete @$row{qw(itime mtime link acc_trans_id)};
 783     $query = sprintf 'INSERT INTO acc_trans (%s) VALUES (%s)', join(', ', keys %$row), join(', ', map '?', values %$row);
 784     $row->{trans_id}   = $new_id;
 785     $row->{amount}    *= -1;
 786     do_query($form, $dbh, $query, (values %$row));
 787   }
 788
 789   map { IO->set_datepaid(table => 'ar', id => $_, dbh => $dbh) } ($id, $new_id);
 790
 791   $dbh->commit;
 792
 793   $main::lxdebug->leave_sub();
 794 }
 795
 796
 797 1;
 798