SL/ARAP.pm

   1 package ARAP;
   2
   3 use SL::AM;
   4 use SL::Common;
   5 use SL::DBUtils;
   6 use SL::MoreCommon;
   7 use SL::DB;
   8 use Data::Dumper;
   9
  10 use strict;
  11
  12 sub close_orders_if_billed {
  13   $main::lxdebug->enter_sub();
  14
  15   my $self   = shift;
  16   my %params = @_;
  17
  18   Common::check_params(\%params, qw(arap_id table));
  19
  20   my $myconfig  = \%main::myconfig;
  21   my $form      = $main::form;
  22
  23   my $dbh       = $params{dbh} || SL::DB->client->dbh;
  24
  25   # First, find all order IDs from which this invoice has been
  26   # created. Either directly by a conversion from an order to this invoice
  27   # or indirectly from an order to one or more delivery orders and
  28   # from those to this invoice.
  29
  30   # Direct conversion "order -> invoice":
  31   my @links     = RecordLinks->get_links('dbh'        => $dbh,
  32                                          'from_table' => 'oe',
  33                                          'to_table'   => $params{table},
  34                                          'to_id'      => $params{arap_id});
  35
  36   my %oe_id_map = map { $_->{from_id} => 1 } @links;
  37
  38   # Indirect conversion "order -> delivery orders -> invoice":
  39   my @do_links  = RecordLinks->get_links('dbh'        => $dbh,
  40                                          'from_table' => 'delivery_orders',
  41                                          'to_table'   => $params{table},
  42                                          'to_id'      => $params{arap_id});
  43
  44   foreach my $do_link (@do_links) {
  45     @links      = RecordLinks->get_links('dbh'        => $dbh,
  46                                          'from_table' => 'oe',
  47                                          'to_table'   => 'delivery_orders',
  48                                          'to_id'      => $do_link->{from_id});
  49
  50     map { $oe_id_map{$_->{from_id}} = 1 } @links;
  51   }
  52
  53   my @oe_ids = keys %oe_id_map;
  54
  55   # No orders found? Nothing to do then, so let's return.
  56   return $main::lxdebug->leave_sub unless @oe_ids;
  57
  58   my $all_units = AM->retrieve_all_units;
  59
  60   my $qtyfactor = $params{table} eq 'ap' ? '* -1' : '';
  61   my $q_billed  = qq|SELECT i.parts_id, i.qty ${qtyfactor} AS qty, i.unit, p.unit AS partunit
  62                      FROM invoice i
  63                      LEFT JOIN parts p ON (i.parts_id = p.id)
  64                      WHERE i.trans_id = ? AND i.assemblyitem is false|;
  65   my $h_billed  = prepare_query($form, $dbh, $q_billed);
  66
  67   my $q_ordered = qq|SELECT oi.parts_id, oi.qty, oi.unit, p.unit AS partunit
  68                       FROM orderitems oi
  69                       LEFT JOIN parts p ON (oi.parts_id = p.id)
  70                       WHERE oi.trans_id = ?|;
  71   my $h_ordered = prepare_query($form, $dbh, $q_ordered);
  72
  73   my @close_oe_ids;
  74
  75   # Interate over each order and look up all invoices created for
  76   # said order. Again consider both direct conversions and indirect
  77   # conversions via delivery orders.
  78   foreach my $oe_id (@oe_ids) {
  79
  80     # Dont close orders with periodic invoice
  81     next if SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $oe_id);
  82
  83     # Direct conversions "order -> invoice":
  84     @links          = RecordLinks->get_links('dbh'        => $dbh,
  85                                              'from_table' => 'oe',
  86                                              'from_id'    => $oe_id,
  87                                              'to_table'   => $params{table},);
  88
  89     my %arap_id_map = map { $_->{to_id} => 1 } @links;
  90
  91     # Indirect conversions "order -> delivery orders -> invoice":
  92     @do_links       = RecordLinks->get_links('dbh'        => $dbh,
  93                                              'from_table' => 'oe',
  94                                              'from_id'    => $oe_id,
  95                                              'to_table'   => 'delivery_orders',);
  96     foreach my $do_link (@do_links) {
  97       @links        = RecordLinks->get_links('dbh'        => $dbh,
  98                                              'from_table' => 'delivery_orders',
  99                                              'from_id'    => $do_link->{to_id},
 100                                              'to_table'   => $params{table},);
 101
 102       map { $arap_id_map{$_->{to_id}} = 1 } @links;
 103     }
 104
 105     my @arap_ids = keys %arap_id_map;
 106
 107     next if (!scalar @arap_ids);
 108
 109     # Retrieve all positions for this order. Calculate the ordered quantity for each position.
 110     my %ordered = ();
 111
 112     do_statement($form, $h_ordered, $q_ordered, $oe_id);
 113
 114     while (my $ref = $h_ordered->fetchrow_hashref()) {
 115       $ref->{baseqty} = $ref->{qty} * AM->convert_unit($ref->{unit}, $ref->{partunit}, $all_units);
 116
 117       if ($ordered{$ref->{parts_id}}) {
 118         $ordered{$ref->{parts_id}}->{baseqty} += $ref->{baseqty};
 119       } else {
 120         $ordered{$ref->{parts_id}}             = $ref;
 121       }
 122     }
 123
 124     # Retrieve all positions for all invoices that have been created from this order.
 125     my %billed  = ();
 126
 127     foreach my $arap_id (@arap_ids) {
 128       do_statement($form, $h_billed, $q_billed, $arap_id);
 129
 130       while (my $ref = $h_billed->fetchrow_hashref()) {
 131         $ref->{baseqty} = $ref->{qty} * AM->convert_unit($ref->{unit}, $ref->{partunit}, $all_units);
 132
 133         if ($billed{$ref->{parts_id}}) {
 134           $billed{$ref->{parts_id}}->{baseqty} += $ref->{baseqty};
 135         } else {
 136           $billed{$ref->{parts_id}}             = $ref;
 137         }
 138       }
 139     }
 140
 141     # Check all ordered positions. If all positions have been billed completely then this order can be closed.
 142     my $all_billed = 1;
 143     foreach my $part (values %ordered) {
 144       if (!$billed{$part->{parts_id}} || ($billed{$part->{parts_id}}->{baseqty} < $part->{baseqty})) {
 145         $all_billed = 0;
 146         last;
 147       }
 148     }
 149
 150     push @close_oe_ids, $oe_id if ($all_billed);
 151   }
 152
 153   $h_billed->finish;
 154   $h_ordered->finish;
 155
 156   # Close orders that have been billed fully.
 157   if (scalar @close_oe_ids) {
 158     SL::DB->client->with_transaction(sub {
 159       my $query = qq|UPDATE oe SET closed = TRUE WHERE id IN (| . join(', ', ('?') x scalar @close_oe_ids) . qq|)|;
 160       do_query($form, $dbh, $query, @close_oe_ids);
 161       1;
 162     }) or do { die SL::DB->client->error };
 163   }
 164
 165   $main::lxdebug->leave_sub();
 166 }
 167
 168 1;