SL/ARAP.pm

   1 package ARAP;
   2
   3 use SL::AM;
   4 use SL::Common;
   5 use SL::DBUtils;
   6 use SL::MoreCommon;
   7 use SL::DB;
   8 use Data::Dumper;
   9
  10 use strict;
  11
  12 sub close_orders_if_billed {
  13   $main::lxdebug->enter_sub();
  14
  15   my $self   = shift;
  16   my %params = @_;
  17
  18   Common::check_params(\%params, qw(arap_id table));
  19
  20   my $myconfig  = \%main::myconfig;
  21   my $form      = $main::form;
  22
  23   my $dbh       = $params{dbh} || SL::DB->client->dbh;
  24
  25   # First, find all order IDs from which this invoice has been
  26   # created. Either directly by a conversion from an order to this invoice
  27   # or indirectly from an order to one or more delivery orders and
  28   # from those to this invoice.
  29
  30   # Direct conversion "order -> invoice":
  31   my @links     = RecordLinks->get_links('dbh'        => $dbh,
  32                                          'from_table' => 'oe',
  33                                          'to_table'   => $params{table},
  34                                          'to_id'      => $params{arap_id});
  35
  36   my %oe_id_map = map { $_->{from_id} => 1 } @links;
  37
  38   # Indirect conversion "order -> delivery orders -> invoice":
  39   my @do_links  = RecordLinks->get_links('dbh'        => $dbh,
  40                                          'from_table' => 'delivery_orders',
  41                                          'to_table'   => $params{table},
  42                                          'to_id'      => $params{arap_id});
  43
  44   foreach my $do_link (@do_links) {
  45     @links      = RecordLinks->get_links('dbh'        => $dbh,
  46                                          'from_table' => 'oe',
  47                                          'to_table'   => 'delivery_orders',
  48                                          'to_id'      => $do_link->{from_id});
  49
  50     map { $oe_id_map{$_->{from_id}} = 1 } @links;
  51   }
  52
  53   my @oe_ids = keys %oe_id_map;
  54
  55   # No orders found? Nothing to do then, so let's return.
  56   return $main::lxdebug->leave_sub unless @oe_ids;
  57
  58   my $all_units = AM->retrieve_all_units;
  59
  60   my $qtyfactor = $params{table} eq 'ap' ? '* -1' : '';
  61   my $q_billed  = qq|SELECT i.parts_id, i.qty ${qtyfactor} AS qty, i.unit, p.unit AS partunit
  62                      FROM invoice i
  63                      LEFT JOIN parts p ON (i.parts_id = p.id)
  64                      WHERE i.trans_id = ? AND i.assemblyitem is false|;
  65   my $h_billed  = prepare_query($form, $dbh, $q_billed);
  66
  67   my $q_ordered = qq|SELECT oi.parts_id, oi.qty, oi.unit, p.unit AS partunit
  68                       FROM orderitems oi
  69                       LEFT JOIN parts p ON (oi.parts_id = p.id)
  70                       WHERE oi.trans_id = ?|;
  71   my $h_ordered = prepare_query($form, $dbh, $q_ordered);
  72
  73   my @close_oe_ids;
  74
  75   # Interate over each order and look up all invoices created for
  76   # said order. Again consider both direct conversions and indirect
  77   # conversions via delivery orders.
  78   foreach my $oe_id (@oe_ids) {
  79     # Direct conversions "order -> invoice":
  80     @links          = RecordLinks->get_links('dbh'        => $dbh,
  81                                              'from_table' => 'oe',
  82                                              'from_id'    => $oe_id,
  83                                              'to_table'   => $params{table},);
  84
  85     my %arap_id_map = map { $_->{to_id} => 1 } @links;
  86
  87     # Indirect conversions "order -> delivery orders -> invoice":
  88     @do_links       = RecordLinks->get_links('dbh'        => $dbh,
  89                                              'from_table' => 'oe',
  90                                              'from_id'    => $oe_id,
  91                                              'to_table'   => 'delivery_orders',);
  92     foreach my $do_link (@do_links) {
  93       @links        = RecordLinks->get_links('dbh'        => $dbh,
  94                                              'from_table' => 'delivery_orders',
  95                                              'from_id'    => $do_link->{to_id},
  96                                              'to_table'   => $params{table},);
  97
  98       map { $arap_id_map{$_->{to_id}} = 1 } @links;
  99     }
 100
 101     my @arap_ids = keys %arap_id_map;
 102
 103     next if (!scalar @arap_ids);
 104
 105     # Retrieve all positions for this order. Calculate the ordered quantity for each position.
 106     my %ordered = ();
 107
 108     do_statement($form, $h_ordered, $q_ordered, $oe_id);
 109
 110     while (my $ref = $h_ordered->fetchrow_hashref()) {
 111       $ref->{baseqty} = $ref->{qty} * AM->convert_unit($ref->{unit}, $ref->{partunit}, $all_units);
 112
 113       if ($ordered{$ref->{parts_id}}) {
 114         $ordered{$ref->{parts_id}}->{baseqty} += $ref->{baseqty};
 115       } else {
 116         $ordered{$ref->{parts_id}}             = $ref;
 117       }
 118     }
 119
 120     # Retrieve all positions for all invoices that have been created from this order.
 121     my %billed  = ();
 122
 123     foreach my $arap_id (@arap_ids) {
 124       do_statement($form, $h_billed, $q_billed, $arap_id);
 125
 126       while (my $ref = $h_billed->fetchrow_hashref()) {
 127         $ref->{baseqty} = $ref->{qty} * AM->convert_unit($ref->{unit}, $ref->{partunit}, $all_units);
 128
 129         if ($billed{$ref->{parts_id}}) {
 130           $billed{$ref->{parts_id}}->{baseqty} += $ref->{baseqty};
 131         } else {
 132           $billed{$ref->{parts_id}}             = $ref;
 133         }
 134       }
 135     }
 136
 137     # Check all ordered positions. If all positions have been billed completely then this order can be closed.
 138     my $all_billed = 1;
 139     foreach my $part (values %ordered) {
 140       if (!$billed{$part->{parts_id}} || ($billed{$part->{parts_id}}->{baseqty} < $part->{baseqty})) {
 141         $all_billed = 0;
 142         last;
 143       }
 144     }
 145
 146     push @close_oe_ids, $oe_id if ($all_billed);
 147   }
 148
 149   $h_billed->finish;
 150   $h_ordered->finish;
 151
 152   # Close orders that have been billed fully.
 153   if (scalar @close_oe_ids) {
 154     SL::DB->client->with_transaction(sub {
 155       my $query = qq|UPDATE oe SET closed = TRUE WHERE id IN (| . join(', ', ('?') x scalar @close_oe_ids) . qq|)|;
 156       do_query($form, $dbh, $query, @close_oe_ids);
 157     });
 158   }
 159
 160   $main::lxdebug->leave_sub();
 161 }
 162
 163 1;