e97b369705cf77e580f27892f3b10e3944595295
[kivitendo-erp.git] / SL / Controller / BackgroundJob.pm
1 package SL::Controller::BackgroundJob;
2
3 use strict;
4
5 use parent qw(SL::Controller::Base);
6
7 use SL::BackgroundJob::Base;
8 use SL::Controller::Helper::GetModels;
9 use SL::DB::BackgroundJob;
10 use SL::Helper::Flash;
11 use SL::JSON;
12 use SL::Locale::String;
13 use SL::System::TaskServer;
14
15 use Rose::Object::MakeMethods::Generic
16 (
17   'scalar --get_set_init' => [ qw(task_server back_to models background_job) ],
18 );
19
20 __PACKAGE__->run_before('check_auth');
21 __PACKAGE__->run_before('check_task_server');
22
23 #
24 # actions
25 #
26
27 sub action_list {
28   my ($self) = @_;
29
30   $self->setup_list_action_bar;
31   $self->render('background_job/list',
32                 title           => $::locale->text('Background jobs'),
33                 BACKGROUND_JOBS => $self->models->get,
34                 MODELS          => $self->models);
35 }
36
37 sub action_new {
38   my ($self) = @_;
39
40   $self->background_job(SL::DB::BackgroundJob->new(cron_spec => '* * * * *',  package_name => 'Test')) unless $self->background_job;
41   $self->setup_form_action_bar;
42   $self->render('background_job/form',
43                 title       => $::locale->text('Create a new background job'),
44                 JOB_CLASSES => [ SL::BackgroundJob::Base->get_known_job_classes ]);
45 }
46
47 sub action_edit {
48   my ($self) = @_;
49
50   $self->setup_form_action_bar;
51   $self->render('background_job/form',
52                 title       => $::locale->text('Edit background job'),
53                 JOB_CLASSES => [ SL::BackgroundJob::Base->get_known_job_classes ]);
54 }
55
56 sub action_edit_as_new {
57   my ($self) = @_;
58
59   delete $::form->{background_job}->{id};
60   $self->background_job(SL::DB::BackgroundJob->new(%{ $::form->{background_job} }));
61   $self->action_new;
62 }
63
64 sub action_show {
65   my ($self) = @_;
66
67   if ($::request->type eq 'json') {
68     $self->render(\ SL::JSON::to_json($self->background_job->as_tree), { type => 'json' });
69   } else {
70     $self->action_edit;
71   }
72 }
73
74 sub action_create {
75   my ($self) = @_;
76
77   $self->background_job(SL::DB::BackgroundJob->new);
78   $self->create_or_update;
79 }
80
81 sub action_update {
82   my ($self) = @_;
83   $self->create_or_update;
84 }
85
86 sub action_destroy {
87   my ($self) = @_;
88
89   if (eval { $self->background_job->delete; 1; }) {
90     flash_later('info',  $::locale->text('The background job has been deleted.'));
91   } else {
92     flash_later('error', $::locale->text('The background job could not be destroyed.'));
93   }
94
95   $self->redirect_to($self->back_to);
96 }
97
98 sub action_save_and_execute {
99   my ($self) = @_;
100
101   $self->background_job(SL::DB::BackgroundJob->new) if !$self->background_job;
102   return unless $self->create_or_update;
103   $self->action_execute;
104 }
105
106 sub action_execute {
107   my ($self) = @_;
108
109   my $history = $self->background_job->run;
110   if ($history->status eq 'success') {
111     flash_later('info', $::locale->text('The background job was executed successfully.'));
112   } else {
113     flash_later('error', $::locale->text('There was an error executing the background job.'));
114   }
115
116   $self->redirect_to(controller => 'BackgroundJobHistory',
117                      action     => 'show',
118                      id         => $history->id,
119                      back_to    => $self->url_for(action => 'edit', id => $self->background_job->id));
120 }
121
122 sub action_execute_class {
123   my ($self) = @_;
124
125   my $result;
126
127   my $ok = eval {
128     die "no class name given in parameter 'class'" if !$::form->{class} || ($::form->{class} =~ m{[^a-z0-9]}i);
129     die "invalid class"                            if ! -f "SL/BackgroundJob/" . $::form->{class} . ".pm";
130
131     my $package = "SL::BackgroundJob::" . $::form->{class};
132
133     eval "require $package" or die $@;
134     $result = $package->new->run(SL::DB::BackgroundJob->new);
135
136     1;
137   };
138
139   my $reply = {
140     status => $ok ? 'succeeded' : 'failed',
141     result => $ok ? $result     : $@,
142   };
143
144   $self->render(\to_json($reply), { type => 'json' });
145 }
146
147 #
148 # filters
149 #
150
151 sub check_auth {
152   $::auth->assert('admin');
153 }
154
155 #
156 # helpers
157 #
158
159 sub create_or_update {
160   my $self   = shift;
161   my $return = shift;
162   my $is_new = !$self->background_job->id;
163   my $params = delete($::form->{background_job}) || { };
164
165   $self->background_job->assign_attributes(%{ $params });
166
167   my @errors = $self->background_job->validate;
168
169   if (@errors) {
170     flash('error', @errors);
171     $self->render('background_job/form', title => $is_new ? $::locale->text('Create a new background job') : $::locale->text('Edit background job'));
172     return;
173   }
174
175   $self->background_job->update_next_run_at;
176   $self->background_job->save;
177
178   flash_later('info', $is_new ? $::locale->text('The background job has been created.') : $::locale->text('The background job has been saved.'));
179   return if $return;
180
181   $self->redirect_to($self->back_to);
182 }
183
184 sub init_background_job {
185   return $::form->{id} ? SL::DB::BackgroundJob->new(id => $::form->{id})->load : undef;
186 }
187
188 sub init_task_server {
189   return SL::System::TaskServer->new;
190 }
191
192 sub check_task_server {
193   my ($self) = @_;
194   flash('warning', $::locale->text('The task server does not appear to be running.')) if !$self->task_server->is_running;
195 }
196
197 sub init_back_to {
198   my ($self) = @_;
199   return $::form->{back_to} || $self->url_for(action => 'list');
200 }
201
202 sub init_models {
203   SL::Controller::Helper::GetModels->new(
204     controller => $_[0],
205     filtered => 0,
206     sorted => {
207       package_name => t8('Package name'),
208       type         => t8('Execution type'),
209       active       => t8('Active'),
210       cron_spec    => t8('Execution schedule'),
211       last_run_at  => t8('Last run at'),
212       next_run_at  => t8('Next run at'),
213     },
214     query => [
215       package_name => [ SL::BackgroundJob::Base->get_known_job_classes ],
216     ],
217   );
218 }
219
220 sub setup_list_action_bar {
221   my ($self) = @_;
222
223   for my $bar ($::request->layout->get('actionbar')) {
224     $bar->add(
225       link => [
226         t8('Add'),
227         link      => $self->url_for(action => 'new'),
228         accesskey => 'enter',
229       ],
230       link => [
231         t8('Server control'),
232         link => $self->url_for(controller => 'TaskServer', action => 'show'),
233       ],
234       link => [
235         t8('Job history'),
236         link => $self->url_for(controller => 'BackgroundJobHistory', action => 'list'),
237       ],
238     );
239   }
240 }
241
242 sub setup_form_action_bar {
243   my ($self) = @_;
244
245   my $is_new = !$self->background_job->id;
246
247   for my $bar ($::request->layout->get('actionbar')) {
248     $bar->add(
249       combobox => [
250         action => [
251           t8('Save'),
252           submit    => [ '#form', { action => 'BackgroundJob/' . ($is_new ? 'create' : 'update') } ],
253           accesskey => 'enter',
254         ],
255         action => [
256           t8('Save and execute'),
257           submit => [ '#form', { action => 'BackgroundJob/save_and_execute' } ],
258         ],
259         action => [
260           t8('Use as new'),
261           submit   => [ '#form', { action => 'BackgroundJob/edit_as_new' } ],
262           disabled => $is_new ? t8('The object has not been saved yet.') : undef,
263         ],
264       ], # end of combobox "Save"
265
266       action => [
267         t8('Delete'),
268         submit   => [ '#form', { action => 'BackgroundJob/destroy' } ],
269         confirm  => t8('Do you really want to delete this object?'),
270         disabled => $is_new ? t8('This object has not been saved yet.') : undef,
271       ],
272
273       link => [
274         t8('Abort'),
275         link => $self->url_for(action => 'list'),
276       ],
277
278       link => [
279         t8('Job history'),
280         link     => $self->url_for(controller => 'BackgroundJobHistory', action => 'list', 'filter.package_name:substr::ilike' => $self->background_job->package_name),
281         disabled => $is_new ? t8('This object has not been saved yet.') : undef,
282       ],
283     );
284   }
285 }
286
287 1;