SL/Controller/BankTransaction.pm

   1 package SL::Controller::BankTransaction;
   2
   3 # idee- möglichkeit bankdaten zu übernehmen in stammdaten
   4 # erst Kontenabgleich, um alle gl-Einträge wegzuhaben
   5 use strict;
   6
   7 use parent qw(SL::Controller::Base);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::ReportGenerator;
  12
  13 use SL::DB::BankTransaction;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String;
  16 use SL::SEPA;
  17 use SL::DB::Invoice;
  18 use SL::DB::PurchaseInvoice;
  19 use SL::DB::RecordLink;
  20 use SL::JSON;
  21 use SL::DB::Chart;
  22 use SL::DB::AccTransaction;
  23 use SL::DB::Tax;
  24 use SL::DB::Draft;
  25 use SL::DB::BankAccount;
  26 use SL::DBUtils qw(like);
  27 use SL::Presenter;
  28 use List::Util qw(max);
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  'scalar --get_set_init' => [ qw(models) ],
  33 );
  34
  35 __PACKAGE__->run_before('check_auth');
  36
  37
  38 #
  39 # actions
  40 #
  41
  42 sub action_search {
  43   my ($self) = @_;
  44
  45   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
  46
  47   $self->render('bank_transactions/search',
  48                  BANK_ACCOUNTS => $bank_accounts);
  49 }
  50
  51 sub action_list_all {
  52   my ($self) = @_;
  53
  54   $self->make_filter_summary;
  55   $self->prepare_report;
  56
  57   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  58 }
  59
  60 sub action_list {
  61   my ($self) = @_;
  62
  63   if (!$::form->{filter}{bank_account}) {
  64     flash('error', t8('No bank account chosen!'));
  65     $self->action_search;
  66     return;
  67   }
  68
  69   my $sort_by = $::form->{sort_by} || 'transdate';
  70   $sort_by = 'transdate' if $sort_by eq 'proposal';
  71   $sort_by .= $::form->{sort_dir} ? ' DESC' : ' ASC';
  72
  73   my $fromdate = $::locale->parse_date_to_object($::form->{filter}->{fromdate});
  74   my $todate   = $::locale->parse_date_to_object($::form->{filter}->{todate});
  75   $todate->add( days => 1 ) if $todate;
  76
  77   my @where = ();
  78   push @where, (transdate => { ge => $fromdate }) if ($fromdate);
  79   push @where, (transdate => { lt => $todate })   if ($todate);
  80   my $bank_account = SL::DB::Manager::BankAccount->find_by( id => $::form->{filter}{bank_account} );
  81   # bank_transactions no younger than starting date,
  82   # including starting date (same search behaviour as fromdate)
  83   # but OPEN invoices to be matched may be from before
  84   if ( $bank_account->reconciliation_starting_date ) {
  85     push @where, (transdate => { ge => $bank_account->reconciliation_starting_date });
  86   };
  87
  88   my $bank_transactions = SL::DB::Manager::BankTransaction->get_all(where => [ amount => {ne => \'invoice_amount'},
  89                                                                                local_bank_account_id => $::form->{filter}{bank_account},
  90                                                                                @where ],
  91                                                                     with_objects => [ 'local_bank_account', 'currency' ],
  92                                                                     sort_by => $sort_by, limit => 10000);
  93
  94   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'customer');
  95   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'vendor');
  96
  97   my @all_open_invoices;
  98   # filter out invoices with less than 1 cent outstanding
  99   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ar_invoices };
 100   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 101
 102   # try to match each bank_transaction with each of the possible open invoices
 103   # by awarding points
 104
 105   foreach my $bt (@{ $bank_transactions }) {
 106     next unless $bt->{remote_name};  # bank has no name, usually fees, use create invoice to assign
 107
 108     $bt->{remote_name} .= $bt->{remote_name_1} if $bt->{remote_name_1};
 109
 110     # try to match the current $bt to each of the open_invoices, saving the
 111     # results of get_agreement_with_invoice in $open_invoice->{agreement} and
 112     # $open_invoice->{rule_matches}.
 113
 114     # The values are overwritten each time a new bt is checked, so at the end
 115     # of each bt the likely results are filtered and those values are stored in
 116     # the arrays $bt->{proposals} and $bt->{rule_matches}, and the agreement
 117     # score is stored in $bt->{agreement}
 118
 119     foreach my $open_invoice (@all_open_invoices){
 120       ($open_invoice->{agreement}, $open_invoice->{rule_matches}) = $bt->get_agreement_with_invoice($open_invoice);
 121     };
 122
 123     $bt->{proposals} = [];
 124
 125     my $agreement = 15;
 126     my $min_agreement = 3; # suggestions must have at least this score
 127
 128     my $max_agreement = max map { $_->{agreement} } @all_open_invoices;
 129
 130     # add open_invoices with highest agreement into array $bt->{proposals}
 131     if ( $max_agreement >= $min_agreement ) {
 132       $bt->{proposals} = [ grep { $_->{agreement} == $max_agreement } @all_open_invoices ];
 133       $bt->{agreement} = $max_agreement; #scalar @{ $bt->{proposals} } ? $agreement + 1 : '';
 134
 135       # store the rule_matches in a separate array, so they can be displayed in template
 136       foreach ( @{ $bt->{proposals} } ) {
 137         push(@{$bt->{rule_matches}}, $_->{rule_matches});
 138       };
 139     };
 140   }  # finished one bt
 141   # finished all bt
 142
 143   # separate filter for proposals (second tab, agreement >= 5 and exactly one match)
 144   # to qualify as a proposal there has to be
 145   # * agreement >= 5  TODO: make threshold configurable in configuration
 146   # * there must be only one exact match
 147   # * depending on whether sales or purchase the amount has to have the correct sign (so Gutschriften don't work?)
 148   my $proposal_threshold = 5;
 149   my @proposals = grep { $_->{agreement} >= $proposal_threshold
 150                          and 1 == scalar @{ $_->{proposals} }
 151                          and (@{ $_->{proposals} }[0]->is_sales ? abs(@{ $_->{proposals} }[0]->amount - $_->amount) < 0.01  : abs(@{ $_->{proposals} }[0]->amount + $_->amount) < 0.01) } @{ $bank_transactions };
 152
 153   # sort bank transaction proposals by quality (score) of proposal
 154   $bank_transactions = [ sort { $a->{agreement} <=> $b->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 1;
 155   $bank_transactions = [ sort { $b->{agreement} <=> $a->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 0;
 156
 157
 158   $self->render('bank_transactions/list',
 159                 title             => t8('Bank transactions MT940'),
 160                 BANK_TRANSACTIONS => $bank_transactions,
 161                 PROPOSALS         => \@proposals,
 162                 bank_account      => $bank_account );
 163 }
 164
 165 sub action_assign_invoice {
 166   my ($self) = @_;
 167
 168   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 169
 170   $self->render('bank_transactions/assign_invoice', { layout  => 0 },
 171                 title      => t8('Assign invoice'),);
 172 }
 173
 174 sub action_create_invoice {
 175   my ($self) = @_;
 176   my %myconfig = %main::myconfig;
 177
 178   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 179   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 180
 181   my $use_vendor_filter = $self->{transaction}->{remote_account_number} && $vendor_of_transaction;
 182
 183   my $drafts = SL::DB::Manager::Draft->get_all(where => [ module => 'ap'] , with_objects => 'employee');
 184
 185   my @filtered_drafts;
 186
 187   foreach my $draft ( @{ $drafts } ) {
 188     my $draft_as_object = YAML::Load($draft->form);
 189     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 190     $draft->{vendor} = $vendor->name;
 191     $draft->{vendor_id} = $vendor->id;
 192     push @filtered_drafts, $draft;
 193   }
 194
 195   #Filter drafts
 196   @filtered_drafts = grep { $_->{vendor_id} == $vendor_of_transaction->id } @filtered_drafts if $use_vendor_filter;
 197
 198   my $all_vendors = SL::DB::Manager::Vendor->get_all();
 199
 200   $self->render('bank_transactions/create_invoice', { layout  => 0 },
 201       title      => t8('Create invoice'),
 202       DRAFTS     => \@filtered_drafts,
 203       vendor_id  => $use_vendor_filter ? $vendor_of_transaction->id : undef,
 204       vendor_name => $use_vendor_filter ? $vendor_of_transaction->name : undef,
 205       ALL_VENDORS => $all_vendors,
 206       limit      => $myconfig{vclimit},
 207       callback   => $self->url_for(action                => 'list',
 208                                    'filter.bank_account' => $::form->{filter}->{bank_account},
 209                                    'filter.todate'       => $::form->{filter}->{todate},
 210                                    'filter.fromdate'     => $::form->{filter}->{fromdate}),
 211       );
 212 }
 213
 214 sub action_ajax_payment_suggestion {
 215   my ($self) = @_;
 216
 217   # based on a BankTransaction ID and a Invoice or PurchaseInvoice ID passed via $::form,
 218   # create an HTML blob to be used by the js function add_invoices in templates/webpages/bank_transactions/list.html
 219   # and return encoded as JSON
 220
 221   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $::form->{bt_id} );
 222   my $invoice = SL::DB::Manager::Invoice->find_by( id => $::form->{prop_id} );
 223   $invoice = SL::DB::Manager::PurchaseInvoice->find_by( id => $::form->{prop_id} ) unless $invoice;
 224
 225   die unless $bt and $invoice;
 226
 227   my @select_options = $invoice->get_payment_select_options_for_bank_transaction($::form->{bt_id});
 228
 229   my $html;
 230   $html .= SL::Presenter->input_tag('invoice_ids.' . $::form->{bt_id} . '[]', $::form->{prop_id} , type => 'hidden');
 231   # better in template code - but how to ajax this
 232   $html .= SL::Presenter->escape(t8('Invno.') . ': ' . $invoice->invnumber . ' ');
 233   $html .= SL::Presenter->escape(t8('Amount') . ': ' . $::form->format_amount(\%::myconfig, $invoice->open_amount, 2) . ' ');
 234   $html .= SL::Presenter->select_tag('invoice_skontos.' . $::form->{bt_id} . '[]', \@select_options,
 235                                               value_key => 'payment_type',
 236                                               title_key => 'display' ) if @select_options;
 237   $html .= '<a href=# onclick="delete_invoice(' . $::form->{bt_id} . ',' . $::form->{prop_id} . ');">x</a>';
 238   $html = SL::Presenter->html_tag('div', $html, id => $::form->{bt_id} . '.' . $::form->{prop_id});
 239
 240   $self->render(\ SL::JSON::to_json( { 'html' => $html } ), { layout => 0, type => 'json', process => 0 });
 241 };
 242
 243 sub action_filter_drafts {
 244   my ($self) = @_;
 245
 246   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 247   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 248
 249   my $drafts = SL::DB::Manager::Draft->get_all(with_objects => 'employee');
 250
 251   my @filtered_drafts;
 252
 253   foreach my $draft ( @{ $drafts } ) {
 254     my $draft_as_object = YAML::Load($draft->form);
 255     next unless $draft_as_object->{vendor_id};  # we cannot filter for vendor name, if this is a gl draft
 256     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 257     $draft->{vendor} = $vendor->name;
 258     $draft->{vendor_id} = $vendor->id;
 259     push @filtered_drafts, $draft;
 260   }
 261
 262   my $vendor_name = $::form->{vendor};
 263   my $vendor_id = $::form->{vendor_id};
 264
 265   #Filter drafts
 266   @filtered_drafts = grep { $_->{vendor_id} == $vendor_id } @filtered_drafts if $vendor_id;
 267   @filtered_drafts = grep { $_->{vendor} =~ /$vendor_name/i } @filtered_drafts if $vendor_name;
 268
 269   my $output  = $self->render(
 270       'bank_transactions/filter_drafts',
 271       { output      => 0 },
 272       DRAFTS => \@filtered_drafts,
 273       );
 274
 275   my %result = ( count => 0, html => $output );
 276
 277   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 278 }
 279
 280 sub action_ajax_add_list {
 281   my ($self) = @_;
 282
 283   my @where_sale     = (amount => { ne => \'paid' });
 284   my @where_purchase = (amount => { ne => \'paid' });
 285
 286   if ($::form->{invnumber}) {
 287     push @where_sale,     (invnumber => { ilike => like($::form->{invnumber})});
 288     push @where_purchase, (invnumber => { ilike => like($::form->{invnumber})});
 289   }
 290
 291   if ($::form->{amount}) {
 292     push @where_sale,     (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 293     push @where_purchase, (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 294   }
 295
 296   if ($::form->{vcnumber}) {
 297     push @where_sale,     ('customer.customernumber' => { ilike => like($::form->{vcnumber})});
 298     push @where_purchase, ('vendor.vendornumber'     => { ilike => like($::form->{vcnumber})});
 299   }
 300
 301   if ($::form->{vcname}) {
 302     push @where_sale,     ('customer.name' => { ilike => like($::form->{vcname})});
 303     push @where_purchase, ('vendor.name'   => { ilike => like($::form->{vcname})});
 304   }
 305
 306   if ($::form->{transdatefrom}) {
 307     my $fromdate = $::locale->parse_date_to_object($::form->{transdatefrom});
 308     if ( ref($fromdate) eq 'DateTime' ) {
 309       push @where_sale,     ('transdate' => { ge => $fromdate});
 310       push @where_purchase, ('transdate' => { ge => $fromdate});
 311     };
 312   }
 313
 314   if ($::form->{transdateto}) {
 315     my $todate = $::locale->parse_date_to_object($::form->{transdateto});
 316     if ( ref($todate) eq 'DateTime' ) {
 317       $todate->add(days => 1);
 318       push @where_sale,     ('transdate' => { lt => $todate});
 319       push @where_purchase, ('transdate' => { lt => $todate});
 320     };
 321   }
 322
 323   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => \@where_sale, with_objects => 'customer');
 324   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => \@where_purchase, with_objects => 'vendor');
 325
 326   my @all_open_invoices = @{ $all_open_ar_invoices };
 327   # add ap invoices, filtering out subcent open amounts
 328   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 329
 330   @all_open_invoices = sort { $a->id <=> $b->id } @all_open_invoices;
 331
 332   my $output  = $self->render(
 333       'bank_transactions/add_list',
 334       { output      => 0 },
 335       INVOICES => \@all_open_invoices,
 336       );
 337
 338   my %result = ( count => 0, html => $output );
 339
 340   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 341 }
 342
 343 sub action_ajax_accept_invoices {
 344   my ($self) = @_;
 345
 346   my @selected_invoices;
 347   foreach my $invoice_id (@{ $::form->{invoice_id} || [] }) {
 348     my $invoice_object = SL::DB::Manager::Invoice->find_by(id => $invoice_id);
 349     $invoice_object ||= SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id);
 350
 351     push @selected_invoices, $invoice_object;
 352   }
 353
 354   $self->render('bank_transactions/invoices', { layout => 0 },
 355                 INVOICES => \@selected_invoices,
 356                 bt_id    => $::form->{bt_id} );
 357 }
 358
 359 sub action_save_invoices {
 360   my ($self) = @_;
 361
 362   my $invoice_hash = delete $::form->{invoice_ids}; # each key (the bt line with a bt_id) contains an array of invoice_ids
 363   my $skonto_hash  = delete $::form->{invoice_skontos} || {}; # array containing the payment type, could be empty
 364
 365   # a bank_transaction may be assigned to several invoices, i.e. a customer
 366   # might pay several open invoices with one transaction
 367
 368   while ( my ($bt_id, $invoice_ids) = each(%$invoice_hash) ) {
 369     my $bank_transaction = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 370     my $sign = $bank_transaction->amount < 0 ? -1 : 1;
 371     my $amount_of_transaction = $sign * $bank_transaction->amount;
 372
 373     my @invoices;
 374     foreach my $invoice_id (@{ $invoice_ids }) {
 375       push @invoices, (SL::DB::Manager::Invoice->find_by(id => $invoice_id) || SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id));
 376     }
 377     @invoices = sort { return 1 if ($a->is_sales and $a->amount > 0);
 378                           return 1 if (!$a->is_sales and $a->amount < 0);
 379                           return -1; } @invoices                if $bank_transaction->amount > 0;
 380     @invoices = sort { return -1 if ($a->is_sales and $a->amount > 0);
 381                        return -1 if (!$a->is_sales and $a->amount < 0);
 382                        return 1; } @invoices                    if $bank_transaction->amount < 0;
 383
 384     foreach my $invoice (@invoices) {
 385
 386       # Check if bank_transaction already has a link to the invoice, may only be linked once per invoice
 387       # This might be caused by the user reloading a page and resending the form
 388       die t8("Bank transaction with id #1 has already been linked to #2.", $bank_transaction->id, $invoice->displayable_name)
 389         if _existing_record_link($bank_transaction, $invoice);
 390
 391       my $payment_type;
 392       if ( defined $skonto_hash->{"$bt_id"} ) {
 393         $payment_type = shift(@{ $skonto_hash->{"$bt_id"} });
 394       } else {
 395         $payment_type = 'without_skonto';
 396       };
 397       if ($amount_of_transaction == 0) {
 398         flash('warning',  $::locale->text('There are invoices which could not be paid by bank transaction #1 (Account number: #2, bank code: #3)!',
 399                                             $bank_transaction->purpose,
 400                                             $bank_transaction->remote_account_number,
 401                                             $bank_transaction->remote_bank_code));
 402         last;
 403       }
 404       # pay invoice or go to the next bank transaction if the amount is not sufficiently high
 405       if ($invoice->open_amount <= $amount_of_transaction) {
 406         # first calculate new bank transaction amount ...
 407         if ($invoice->is_sales) {
 408           $amount_of_transaction -= $sign * $invoice->open_amount;
 409           $bank_transaction->invoice_amount($bank_transaction->invoice_amount + $invoice->open_amount);
 410         } else {
 411           $amount_of_transaction += $sign * $invoice->open_amount;
 412           $bank_transaction->invoice_amount($bank_transaction->invoice_amount - $invoice->open_amount);
 413         }
 414         # ... and then pay the invoice
 415         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 416                               trans_id     => $invoice->id,
 417                               amount       => $invoice->open_amount,
 418                               payment_type => $payment_type,
 419                               transdate    => $bank_transaction->transdate->to_kivitendo);
 420       } else {
 421         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 422                               trans_id     => $invoice->id,
 423                               amount       => $amount_of_transaction,
 424                               payment_type => $payment_type,
 425                               transdate    => $bank_transaction->transdate->to_kivitendo);
 426         $bank_transaction->invoice_amount($bank_transaction->amount);
 427         $amount_of_transaction = 0;
 428       }
 429
 430       # Record a record link from the bank transaction to the invoice
 431       my @props = (
 432           from_table => 'bank_transactions',
 433           from_id    => $bt_id,
 434           to_table   => $invoice->is_sales ? 'ar' : 'ap',
 435           to_id      => $invoice->id,
 436           );
 437
 438       SL::DB::RecordLink->new(@props)->save;
 439     }
 440     $bank_transaction->save;
 441   }
 442
 443   $self->action_list();
 444 }
 445
 446 sub action_save_proposals {
 447   my ($self) = @_;
 448
 449   foreach my $bt_id (@{ $::form->{proposal_ids} }) {
 450     my $bt = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 451
 452     my $arap = SL::DB::Manager::Invoice->find_by(id => $::form->{"proposed_invoice_$bt_id"});
 453     $arap    = SL::DB::Manager::PurchaseInvoice->find_by(id => $::form->{"proposed_invoice_$bt_id"}) if not defined $arap;
 454
 455     # check for existing record_link for that $bt and $arap
 456     # do this before any changes to $bt are made
 457     die t8("Bank transaction with id #1 has already been linked to #2.", $bt->id, $arap->displayable_name)
 458       if _existing_record_link($bt, $arap);
 459
 460     #mark bt as booked
 461     $bt->invoice_amount($bt->amount);
 462     $bt->save;
 463
 464     #pay invoice
 465     $arap->pay_invoice(chart_id  => $bt->local_bank_account->chart_id,
 466                        trans_id  => $arap->id,
 467                        amount    => $arap->amount,
 468                        transdate => $bt->transdate->to_kivitendo);
 469     $arap->save;
 470
 471     #create record link
 472     my @props = (
 473         from_table => 'bank_transactions',
 474         from_id    => $bt_id,
 475         to_table   => $arap->is_sales ? 'ar' : 'ap',
 476         to_id      => $arap->id,
 477         );
 478
 479     SL::DB::RecordLink->new(@props)->save;
 480   }
 481
 482   flash('ok', t8('#1 proposal(s) saved.', scalar @{ $::form->{proposal_ids} }));
 483
 484   $self->action_list();
 485 }
 486
 487 #
 488 # filters
 489 #
 490
 491 sub check_auth {
 492   $::auth->assert('bank_transaction');
 493 }
 494
 495 #
 496 # helpers
 497 #
 498
 499 sub make_filter_summary {
 500   my ($self) = @_;
 501
 502   my $filter = $::form->{filter} || {};
 503   my @filter_strings;
 504
 505   my @filters = (
 506     [ $filter->{"transdate:date::ge"},  $::locale->text('Transdate')  . " " . $::locale->text('From Date') ],
 507     [ $filter->{"transdate:date::le"},  $::locale->text('Transdate')  . " " . $::locale->text('To Date')   ],
 508     [ $filter->{"valutadate:date::ge"}, $::locale->text('Valutadate') . " " . $::locale->text('From Date') ],
 509     [ $filter->{"valutadate:date::le"}, $::locale->text('Valutadate') . " " . $::locale->text('To Date')   ],
 510     [ $filter->{"amount:number"},       $::locale->text('Amount')                                          ],
 511     [ $filter->{"bank_account_id:integer"}, $::locale->text('Local bank account')                          ],
 512   );
 513
 514   for (@filters) {
 515     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 516   }
 517
 518   $self->{filter_summary} = join ', ', @filter_strings;
 519 }
 520
 521 sub prepare_report {
 522   my ($self)      = @_;
 523
 524   my $callback    = $self->models->get_callback;
 525
 526   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 527   $self->{report} = $report;
 528
 529   my @columns     = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount invoice_amount invoices currency purpose local_account_number local_bank_code id);
 530   my @sortable    = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount                                  purpose local_account_number local_bank_code);
 531
 532   my %column_defs = (
 533     transdate             => { sub => sub { $_[0]->transdate_as_date } },
 534     valutadate            => { sub => sub { $_[0]->valutadate_as_date } },
 535     remote_name           => { },
 536     remote_account_number => { },
 537     remote_bank_code      => { },
 538     amount                => { sub => sub { $_[0]->amount_as_number },
 539                                align => 'right' },
 540     invoice_amount        => { sub => sub { $_[0]->invoice_amount_as_number },
 541                                align => 'right' },
 542     invoices              => { sub => sub { $_[0]->linked_invoices } },
 543     currency              => { sub => sub { $_[0]->currency->name } },
 544     purpose               => { },
 545     local_account_number  => { sub => sub { $_[0]->local_bank_account->account_number } },
 546     local_bank_code       => { sub => sub { $_[0]->local_bank_account->bank_code } },
 547     local_bank_name       => { sub => sub { $_[0]->local_bank_account->name } },
 548     id                    => {},
 549   );
 550
 551   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 552
 553   $report->set_options(
 554     std_column_visibility => 1,
 555     controller_class      => 'BankTransaction',
 556     output_format         => 'HTML',
 557     top_info_text         => $::locale->text('Bank transactions'),
 558     title                 => $::locale->text('Bank transactions'),
 559     allow_pdf_export      => 1,
 560     allow_csv_export      => 1,
 561   );
 562   $report->set_columns(%column_defs);
 563   $report->set_column_order(@columns);
 564   $report->set_export_options(qw(list_all filter));
 565   $report->set_options_from_form;
 566   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 567   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 568
 569   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted();
 570
 571   $report->set_options(
 572     raw_top_info_text     => $self->render('bank_transactions/report_top',    { output => 0 }, BANK_ACCOUNTS => $bank_accounts),
 573     raw_bottom_info_text  => $self->render('bank_transactions/report_bottom', { output => 0 }),
 574   );
 575 }
 576
 577 sub _existing_record_link {
 578   my ($bt, $invoice) = @_;
 579
 580   # check whether a record link from banktransaction $bt already exists to
 581   # invoice $invoice, returns 1 if that is the case
 582
 583   die unless $bt->isa("SL::DB::BankTransaction") && ( $invoice->isa("SL::DB::Invoice") || $invoice->isa("SL::DB::PurchaseInvoice") );
 584
 585   my $linked_record_to_table = $invoice->is_sales ? 'Invoice' : 'PurchaseInvoice';
 586   my $linked_records = $bt->linked_records( direction => 'to', to => $linked_record_to_table, query => [ id => $invoice->id ]  );
 587
 588   return @$linked_records ? 1 : 0;
 589 };
 590
 591
 592 sub init_models {
 593   my ($self) = @_;
 594
 595   SL::Controller::Helper::GetModels->new(
 596     controller => $self,
 597     sorted => {
 598       _default => {
 599         by    => 'transdate',
 600         dir   => 0,   # 1 = ASC, 0 = DESC : default sort is newest at top
 601       },
 602       transdate             => t8('Transdate'),
 603       remote_name           => t8('Remote name'),
 604       amount                => t8('Amount'),
 605       invoice_amount        => t8('Assigned'),
 606       invoices              => t8('Linked invoices'),
 607       valutadate            => t8('Valutadate'),
 608       remote_account_number => t8('Remote account number'),
 609       remote_bank_code      => t8('Remote bank code'),
 610       currency              => t8('Currency'),
 611       purpose               => t8('Purpose'),
 612       local_account_number  => t8('Local account number'),
 613       local_bank_code       => t8('Local bank code'),
 614       local_bank_name       => t8('Bank account'),
 615     },
 616     with_objects => [ 'local_bank_account', 'currency' ],
 617   );
 618 }
 619
 620 1;