SL/Controller/BankTransaction.pm

   1 package SL::Controller::BankTransaction;
   2
   3 # idee- möglichkeit bankdaten zu übernehmen in stammdaten
   4 # erst Kontenabgleich, um alle gl-Einträge wegzuhaben
   5 use strict;
   6
   7 use parent qw(SL::Controller::Base);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::ReportGenerator;
  12
  13 use SL::DB::BankTransaction;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String;
  16 use SL::SEPA;
  17 use SL::DB::Invoice;
  18 use SL::DB::PurchaseInvoice;
  19 use SL::DB::RecordLink;
  20 use SL::JSON;
  21 use SL::DB::Chart;
  22 use SL::DB::AccTransaction;
  23 use SL::DB::Tax;
  24 use SL::DB::Draft;
  25 use SL::DB::BankAccount;
  26 use SL::DBUtils qw(like);
  27 use SL::Presenter;
  28 use List::Util qw(max);
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  'scalar --get_set_init' => [ qw(models) ],
  33 );
  34
  35 __PACKAGE__->run_before('check_auth');
  36
  37
  38 #
  39 # actions
  40 #
  41
  42 sub action_search {
  43   my ($self) = @_;
  44
  45   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
  46
  47   $self->render('bank_transactions/search',
  48                  BANK_ACCOUNTS => $bank_accounts);
  49 }
  50
  51 sub action_list_all {
  52   my ($self) = @_;
  53
  54   $self->make_filter_summary;
  55   $self->prepare_report;
  56
  57   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  58 }
  59
  60 sub action_list {
  61   my ($self) = @_;
  62
  63   if (!$::form->{filter}{bank_account}) {
  64     flash('error', t8('No bank account chosen!'));
  65     $self->action_search;
  66     return;
  67   }
  68
  69   my $sort_by = $::form->{sort_by} || 'transdate';
  70   $sort_by = 'transdate' if $sort_by eq 'proposal';
  71   $sort_by .= $::form->{sort_dir} ? ' DESC' : ' ASC';
  72
  73   my $fromdate = $::locale->parse_date_to_object($::form->{filter}->{fromdate});
  74   my $todate   = $::locale->parse_date_to_object($::form->{filter}->{todate});
  75   $todate->add( days => 1 ) if $todate;
  76
  77   my @where = ();
  78   push @where, (transdate => { ge => $fromdate }) if ($fromdate);
  79   push @where, (transdate => { lt => $todate })   if ($todate);
  80   my $bank_account = SL::DB::Manager::BankAccount->find_by( id => $::form->{filter}{bank_account} );
  81   # bank_transactions no younger than starting date,
  82   # including starting date (same search behaviour as fromdate)
  83   # but OPEN invoices to be matched may be from before
  84   if ( $bank_account->reconciliation_starting_date ) {
  85     push @where, (transdate => { ge => $bank_account->reconciliation_starting_date });
  86   };
  87
  88   my $bank_transactions = SL::DB::Manager::BankTransaction->get_all(where => [ amount => {ne => \'invoice_amount'},
  89                                                                                local_bank_account_id => $::form->{filter}{bank_account},
  90                                                                                @where ],
  91                                                                     with_objects => [ 'local_bank_account', 'currency' ],
  92                                                                     sort_by => $sort_by, limit => 10000);
  93
  94   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'customer');
  95   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => [amount => { gt => \'paid' }], with_objects => 'vendor');
  96
  97   my @all_open_invoices;
  98   # filter out invoices with less than 1 cent outstanding
  99   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ar_invoices };
 100   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 101
 102   # try to match each bank_transaction with each of the possible open invoices
 103   # by awarding points
 104
 105   foreach my $bt (@{ $bank_transactions }) {
 106     next unless $bt->{remote_name};  # bank has no name, usually fees, use create invoice to assign
 107
 108     $bt->{remote_name} .= $bt->{remote_name_1} if $bt->{remote_name_1};
 109
 110     # try to match the current $bt to each of the open_invoices, saving the
 111     # results of get_agreement_with_invoice in $open_invoice->{agreement} and
 112     # $open_invoice->{rule_matches}.
 113
 114     # The values are overwritten each time a new bt is checked, so at the end
 115     # of each bt the likely results are filtered and those values are stored in
 116     # the arrays $bt->{proposals} and $bt->{rule_matches}, and the agreement
 117     # score is stored in $bt->{agreement}
 118
 119     foreach my $open_invoice (@all_open_invoices){
 120       ($open_invoice->{agreement}, $open_invoice->{rule_matches}) = $bt->get_agreement_with_invoice($open_invoice);
 121     };
 122
 123     $bt->{proposals} = [];
 124
 125     my $agreement = 15;
 126     my $min_agreement = 3; # suggestions must have at least this score
 127
 128     my $max_agreement = max map { $_->{agreement} } @all_open_invoices;
 129
 130     # add open_invoices with highest agreement into array $bt->{proposals}
 131     if ( $max_agreement >= $min_agreement ) {
 132       $bt->{proposals} = [ grep { $_->{agreement} == $max_agreement } @all_open_invoices ];
 133       $bt->{agreement} = $max_agreement; #scalar @{ $bt->{proposals} } ? $agreement + 1 : '';
 134
 135       # store the rule_matches in a separate array, so they can be displayed in template
 136       foreach ( @{ $bt->{proposals} } ) {
 137         push(@{$bt->{rule_matches}}, $_->{rule_matches});
 138       };
 139     };
 140   }  # finished one bt
 141   # finished all bt
 142
 143   # separate filter for proposals (second tab, agreement >= 5 and exactly one match)
 144   # to qualify as a proposal there has to be
 145   # * agreement >= 5  TODO: make threshold configurable in configuration
 146   # * there must be only one exact match
 147   # * depending on whether sales or purchase the amount has to have the correct sign (so Gutschriften don't work?)
 148   my $proposal_threshold = 5;
 149   my @proposals = grep { $_->{agreement} >= $proposal_threshold
 150                          and 1 == scalar @{ $_->{proposals} }
 151                          and (@{ $_->{proposals} }[0]->is_sales ? abs(@{ $_->{proposals} }[0]->amount - $_->amount) < 0.01  : abs(@{ $_->{proposals} }[0]->amount + $_->amount) < 0.01) } @{ $bank_transactions };
 152
 153   # sort bank transaction proposals by quality (score) of proposal
 154   $bank_transactions = [ sort { $a->{agreement} <=> $b->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 1;
 155   $bank_transactions = [ sort { $b->{agreement} <=> $a->{agreement} } @{ $bank_transactions } ] if $::form->{sort_by} eq 'proposal' and $::form->{sort_dir} == 0;
 156
 157
 158   $self->render('bank_transactions/list',
 159                 title             => t8('Bank transactions MT940'),
 160                 BANK_TRANSACTIONS => $bank_transactions,
 161                 PROPOSALS         => \@proposals,
 162                 bank_account      => $bank_account );
 163 }
 164
 165 sub action_assign_invoice {
 166   my ($self) = @_;
 167
 168   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 169
 170   $self->render('bank_transactions/assign_invoice', { layout  => 0 },
 171                 title      => t8('Assign invoice'),);
 172 }
 173
 174 sub action_create_invoice {
 175   my ($self) = @_;
 176   my %myconfig = %main::myconfig;
 177
 178   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 179   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 180
 181   my $drafts = SL::DB::Manager::Draft->get_all(where => [ module => 'ap'] , with_objects => 'employee');
 182
 183   my @filtered_drafts;
 184
 185   foreach my $draft ( @{ $drafts } ) {
 186     my $draft_as_object = YAML::Load($draft->form);
 187     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 188     $draft->{vendor} = $vendor->name;
 189     $draft->{vendor_id} = $vendor->id;
 190     push @filtered_drafts, $draft;
 191   }
 192
 193   #Filter drafts
 194   @filtered_drafts = grep { $_->{vendor_id} == $vendor_of_transaction->id } @filtered_drafts if $vendor_of_transaction;
 195
 196   my $all_vendors = SL::DB::Manager::Vendor->get_all();
 197
 198   $self->render('bank_transactions/create_invoice', { layout  => 0 },
 199       title      => t8('Create invoice'),
 200       DRAFTS     => \@filtered_drafts,
 201       vendor_id  => $vendor_of_transaction ? $vendor_of_transaction->id : undef,
 202       vendor_name => $vendor_of_transaction ? $vendor_of_transaction->name : undef,
 203       ALL_VENDORS => $all_vendors,
 204       limit      => $myconfig{vclimit},
 205       callback   => $self->url_for(action                => 'list',
 206                                    'filter.bank_account' => $::form->{filter}->{bank_account},
 207                                    'filter.todate'       => $::form->{filter}->{todate},
 208                                    'filter.fromdate'     => $::form->{filter}->{fromdate}),
 209       );
 210 }
 211
 212 sub action_ajax_payment_suggestion {
 213   my ($self) = @_;
 214
 215   # based on a BankTransaction ID and a Invoice or PurchaseInvoice ID passed via $::form,
 216   # create an HTML blob to be used by the js function add_invoices in templates/webpages/bank_transactions/list.html
 217   # and return encoded as JSON
 218
 219   my $bt = SL::DB::Manager::BankTransaction->find_by( id => $::form->{bt_id} );
 220   my $invoice = SL::DB::Manager::Invoice->find_by( id => $::form->{prop_id} );
 221   $invoice = SL::DB::Manager::PurchaseInvoice->find_by( id => $::form->{prop_id} ) unless $invoice;
 222
 223   die unless $bt and $invoice;
 224
 225   my @select_options = $invoice->get_payment_select_options_for_bank_transaction($::form->{bt_id});
 226
 227   my $html;
 228   $html .= SL::Presenter->input_tag('invoice_ids.' . $::form->{bt_id} . '[]', $::form->{prop_id} , type => 'hidden');
 229   $html .= SL::Presenter->escape( $invoice->invnumber );
 230   $html .= SL::Presenter->select_tag('invoice_skontos.' . $::form->{bt_id} . '[]', \@select_options,
 231                                               value_key => 'payment_type',
 232                                               title_key => 'display' ) if @select_options;
 233   $html .= '<a href=# onclick="delete_invoice(' . $::form->{bt_id} . ',' . $::form->{prop_id} . ');">x</a>';
 234   $html = SL::Presenter->html_tag('div', $html, id => $::form->{bt_id} . '.' . $::form->{prop_id});
 235
 236   $self->render(\ SL::JSON::to_json( { 'html' => $html } ), { layout => 0, type => 'json', process => 0 });
 237 };
 238
 239 sub action_filter_drafts {
 240   my ($self) = @_;
 241
 242   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 243   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(account_number => $self->{transaction}->{remote_account_number});
 244
 245   my $drafts = SL::DB::Manager::Draft->get_all(with_objects => 'employee');
 246
 247   my @filtered_drafts;
 248
 249   foreach my $draft ( @{ $drafts } ) {
 250     my $draft_as_object = YAML::Load($draft->form);
 251     my $vendor = SL::DB::Manager::Vendor->find_by(id => $draft_as_object->{vendor_id});
 252     $draft->{vendor} = $vendor->name;
 253     $draft->{vendor_id} = $vendor->id;
 254     push @filtered_drafts, $draft;
 255   }
 256
 257   my $vendor_name = $::form->{vendor};
 258   my $vendor_id = $::form->{vendor_id};
 259
 260   #Filter drafts
 261   @filtered_drafts = grep { $_->{vendor_id} == $vendor_id } @filtered_drafts if $vendor_id;
 262   @filtered_drafts = grep { $_->{vendor} =~ /$vendor_name/i } @filtered_drafts if $vendor_name;
 263
 264   my $output  = $self->render(
 265       'bank_transactions/filter_drafts',
 266       { output      => 0 },
 267       DRAFTS => \@filtered_drafts,
 268       );
 269
 270   my %result = ( count => 0, html => $output );
 271
 272   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 273 }
 274
 275 sub action_ajax_add_list {
 276   my ($self) = @_;
 277
 278   my @where_sale     = (amount => { ne => \'paid' });
 279   my @where_purchase = (amount => { ne => \'paid' });
 280
 281   if ($::form->{invnumber}) {
 282     push @where_sale,     (invnumber => { ilike => like($::form->{invnumber})});
 283     push @where_purchase, (invnumber => { ilike => like($::form->{invnumber})});
 284   }
 285
 286   if ($::form->{amount}) {
 287     push @where_sale,     (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 288     push @where_purchase, (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 289   }
 290
 291   if ($::form->{vcnumber}) {
 292     push @where_sale,     ('customer.customernumber' => { ilike => like($::form->{vcnumber})});
 293     push @where_purchase, ('vendor.vendornumber'     => { ilike => like($::form->{vcnumber})});
 294   }
 295
 296   if ($::form->{vcname}) {
 297     push @where_sale,     ('customer.name' => { ilike => like($::form->{vcname})});
 298     push @where_purchase, ('vendor.name'   => { ilike => like($::form->{vcname})});
 299   }
 300
 301   if ($::form->{transdatefrom}) {
 302     my $fromdate = $::locale->parse_date_to_object($::form->{transdatefrom});
 303     if ( ref($fromdate) eq 'DateTime' ) {
 304       push @where_sale,     ('transdate' => { ge => $fromdate});
 305       push @where_purchase, ('transdate' => { ge => $fromdate});
 306     };
 307   }
 308
 309   if ($::form->{transdateto}) {
 310     my $todate = $::locale->parse_date_to_object($::form->{transdateto});
 311     if ( ref($todate) eq 'DateTime' ) {
 312       $todate->add(days => 1);
 313       push @where_sale,     ('transdate' => { lt => $todate});
 314       push @where_purchase, ('transdate' => { lt => $todate});
 315     };
 316   }
 317
 318   my $all_open_ar_invoices = SL::DB::Manager::Invoice->get_all(where => \@where_sale, with_objects => 'customer');
 319   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => \@where_purchase, with_objects => 'vendor');
 320
 321   my @all_open_invoices = @{ $all_open_ar_invoices };
 322   # add ap invoices, filtering out subcent open amounts
 323   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 324
 325   @all_open_invoices = sort { $a->id <=> $b->id } @all_open_invoices;
 326
 327   my $output  = $self->render(
 328       'bank_transactions/add_list',
 329       { output      => 0 },
 330       INVOICES => \@all_open_invoices,
 331       );
 332
 333   my %result = ( count => 0, html => $output );
 334
 335   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 336 }
 337
 338 sub action_ajax_accept_invoices {
 339   my ($self) = @_;
 340
 341   my @selected_invoices;
 342   foreach my $invoice_id (@{ $::form->{invoice_id} || [] }) {
 343     my $invoice_object = SL::DB::Manager::Invoice->find_by(id => $invoice_id);
 344     $invoice_object ||= SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id);
 345
 346     push @selected_invoices, $invoice_object;
 347   }
 348
 349   $self->render('bank_transactions/invoices', { layout => 0 },
 350                 INVOICES => \@selected_invoices,
 351                 bt_id    => $::form->{bt_id} );
 352 }
 353
 354 sub action_save_invoices {
 355   my ($self) = @_;
 356
 357   my $invoice_hash = delete $::form->{invoice_ids}; # each key (the bt line with a bt_id) contains an array of invoice_ids
 358   my $skonto_hash  = delete $::form->{invoice_skontos} || {}; # array containing the payment type, could be empty
 359
 360   # a bank_transaction may be assigned to several invoices, i.e. a customer
 361   # might pay several open invoices with one transaction
 362
 363   while ( my ($bt_id, $invoice_ids) = each(%$invoice_hash) ) {
 364     my $bank_transaction = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 365     my $sign = $bank_transaction->amount < 0 ? -1 : 1;
 366     my $amount_of_transaction = $sign * $bank_transaction->amount;
 367
 368     my @invoices;
 369     foreach my $invoice_id (@{ $invoice_ids }) {
 370       push @invoices, (SL::DB::Manager::Invoice->find_by(id => $invoice_id) || SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id));
 371     }
 372     @invoices = sort { return 1 if ($a->is_sales and $a->amount > 0);
 373                           return 1 if (!$a->is_sales and $a->amount < 0);
 374                           return -1; } @invoices                if $bank_transaction->amount > 0;
 375     @invoices = sort { return -1 if ($a->is_sales and $a->amount > 0);
 376                        return -1 if (!$a->is_sales and $a->amount < 0);
 377                        return 1; } @invoices                    if $bank_transaction->amount < 0;
 378
 379     foreach my $invoice (@invoices) {
 380
 381       # Check if bank_transaction already has a link to the invoice, may only be linked once per invoice
 382       # This might be caused by the user reloading a page and resending the form
 383       die t8("Bank transaction with id #1 has already been linked to #2.", $bank_transaction->id, $invoice->displayable_name)
 384         if _existing_record_link($bank_transaction, $invoice);
 385
 386       my $payment_type;
 387       if ( defined $skonto_hash->{"$bt_id"} ) {
 388         $payment_type = shift(@{ $skonto_hash->{"$bt_id"} });
 389       } else {
 390         $payment_type = 'without_skonto';
 391       };
 392       if ($amount_of_transaction == 0) {
 393         flash('warning',  $::locale->text('There are invoices which could not be paid by bank transaction #1 (Account number: #2, bank code: #3)!',
 394                                             $bank_transaction->purpose,
 395                                             $bank_transaction->remote_account_number,
 396                                             $bank_transaction->remote_bank_code));
 397         last;
 398       }
 399       # pay invoice or go to the next bank transaction if the amount is not sufficiently high
 400       if ($invoice->open_amount <= $amount_of_transaction) {
 401         # first calculate new bank transaction amount ...
 402         if ($invoice->is_sales) {
 403           $amount_of_transaction -= $sign * $invoice->open_amount;
 404           $bank_transaction->invoice_amount($bank_transaction->invoice_amount + $invoice->open_amount);
 405         } else {
 406           $amount_of_transaction += $sign * $invoice->open_amount if (!$invoice->is_sales);
 407           $bank_transaction->invoice_amount($bank_transaction->invoice_amount - $invoice->open_amount);
 408         }
 409         # ... and then pay the invoice
 410         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 411                               trans_id     => $invoice->id,
 412                               amount       => $invoice->open_amount,
 413                               payment_type => $payment_type,
 414                               transdate    => $bank_transaction->transdate->to_kivitendo);
 415       } else {
 416         $invoice->pay_invoice(chart_id     => $bank_transaction->local_bank_account->chart_id,
 417                               trans_id     => $invoice->id,
 418                               amount       => $amount_of_transaction,
 419                               payment_type => $payment_type,
 420                               transdate    => $bank_transaction->transdate->to_kivitendo);
 421         $bank_transaction->invoice_amount($bank_transaction->amount) if $invoice->is_sales;
 422         $bank_transaction->invoice_amount($bank_transaction->amount) if !$invoice->is_sales;
 423         $amount_of_transaction = 0;
 424       }
 425
 426       # Record a record link from the bank transaction to the invoice
 427       my @props = (
 428           from_table => 'bank_transactions',
 429           from_id    => $bt_id,
 430           to_table   => $invoice->is_sales ? 'ar' : 'ap',
 431           to_id      => $invoice->id,
 432           );
 433
 434       SL::DB::RecordLink->new(@props)->save;
 435     }
 436     $bank_transaction->save;
 437   }
 438
 439   $self->action_list();
 440 }
 441
 442 sub action_save_proposals {
 443   my ($self) = @_;
 444
 445   foreach my $bt_id (@{ $::form->{proposal_ids} }) {
 446     my $bt = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 447
 448     my $arap = SL::DB::Manager::Invoice->find_by(id => $::form->{"proposed_invoice_$bt_id"});
 449     $arap    = SL::DB::Manager::PurchaseInvoice->find_by(id => $::form->{"proposed_invoice_$bt_id"}) if not defined $arap;
 450
 451     # check for existing record_link for that $bt and $arap
 452     # do this before any changes to $bt are made
 453     die t8("Bank transaction with id #1 has already been linked to #2.", $bt->id, $arap->displayable_name)
 454       if _existing_record_link($bt, $arap);
 455
 456     #mark bt as booked
 457     $bt->invoice_amount($bt->amount);
 458     $bt->save;
 459
 460     #pay invoice
 461     $arap->pay_invoice(chart_id  => $bt->local_bank_account->chart_id,
 462                        trans_id  => $arap->id,
 463                        amount    => $arap->amount,
 464                        transdate => $bt->transdate->to_kivitendo);
 465     $arap->save;
 466
 467     #create record link
 468     my @props = (
 469         from_table => 'bank_transactions',
 470         from_id    => $bt_id,
 471         to_table   => $arap->is_sales ? 'ar' : 'ap',
 472         to_id      => $arap->id,
 473         );
 474
 475     SL::DB::RecordLink->new(@props)->save;
 476   }
 477
 478   flash('ok', t8('#1 proposal(s) saved.', scalar @{ $::form->{proposal_ids} }));
 479
 480   $self->action_list();
 481 }
 482
 483 #
 484 # filters
 485 #
 486
 487 sub check_auth {
 488   $::auth->assert('bank_transaction');
 489 }
 490
 491 #
 492 # helpers
 493 #
 494
 495 sub make_filter_summary {
 496   my ($self) = @_;
 497
 498   my $filter = $::form->{filter} || {};
 499   my @filter_strings;
 500
 501   my @filters = (
 502     [ $filter->{"transdate:date::ge"},  $::locale->text('Transdate')  . " " . $::locale->text('From Date') ],
 503     [ $filter->{"transdate:date::le"},  $::locale->text('Transdate')  . " " . $::locale->text('To Date')   ],
 504     [ $filter->{"valutadate:date::ge"}, $::locale->text('Valutadate') . " " . $::locale->text('From Date') ],
 505     [ $filter->{"valutadate:date::le"}, $::locale->text('Valutadate') . " " . $::locale->text('To Date')   ],
 506     [ $filter->{"amount:number"},       $::locale->text('Amount')                                          ],
 507     [ $filter->{"bank_account_id:integer"}, $::locale->text('Local bank account')                          ],
 508   );
 509
 510   for (@filters) {
 511     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 512   }
 513
 514   $self->{filter_summary} = join ', ', @filter_strings;
 515 }
 516
 517 sub prepare_report {
 518   my ($self)      = @_;
 519
 520   my $callback    = $self->models->get_callback;
 521
 522   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 523   $self->{report} = $report;
 524
 525   my @columns     = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount invoice_amount invoices currency purpose local_account_number local_bank_code id);
 526   my @sortable    = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount                                  purpose local_account_number local_bank_code);
 527
 528   my %column_defs = (
 529     transdate             => { sub => sub { $_[0]->transdate_as_date } },
 530     valutadate            => { sub => sub { $_[0]->valutadate_as_date } },
 531     remote_name           => { },
 532     remote_account_number => { },
 533     remote_bank_code      => { },
 534     amount                => { sub => sub { $_[0]->amount_as_number },
 535                                align => 'right' },
 536     invoice_amount        => { sub => sub { $_[0]->invoice_amount_as_number },
 537                                align => 'right' },
 538     invoices              => { sub => sub { $_[0]->linked_invoices } },
 539     currency              => { sub => sub { $_[0]->currency->name } },
 540     purpose               => { },
 541     local_account_number  => { sub => sub { $_[0]->local_bank_account->account_number } },
 542     local_bank_code       => { sub => sub { $_[0]->local_bank_account->bank_code } },
 543     local_bank_name       => { sub => sub { $_[0]->local_bank_account->name } },
 544     id                    => {},
 545   );
 546
 547   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 548
 549   $report->set_options(
 550     std_column_visibility => 1,
 551     controller_class      => 'BankTransaction',
 552     output_format         => 'HTML',
 553     top_info_text         => $::locale->text('Bank transactions'),
 554     title                 => $::locale->text('Bank transactions'),
 555     allow_pdf_export      => 1,
 556     allow_csv_export      => 1,
 557   );
 558   $report->set_columns(%column_defs);
 559   $report->set_column_order(@columns);
 560   $report->set_export_options(qw(list_all filter));
 561   $report->set_options_from_form;
 562   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 563   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 564
 565   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted();
 566
 567   $report->set_options(
 568     raw_top_info_text     => $self->render('bank_transactions/report_top',    { output => 0 }, BANK_ACCOUNTS => $bank_accounts),
 569     raw_bottom_info_text  => $self->render('bank_transactions/report_bottom', { output => 0 }),
 570   );
 571 }
 572
 573 sub _existing_record_link {
 574   my ($bt, $invoice) = @_;
 575
 576   # check whether a record link from banktransaction $bt already exists to
 577   # invoice $invoice, returns 1 if that is the case
 578
 579   die unless $bt->isa("SL::DB::BankTransaction") && ( $invoice->isa("SL::DB::Invoice") || $invoice->isa("SL::DB::PurchaseInvoice") );
 580
 581   my $linked_record_to_table = $invoice->is_sales ? 'Invoice' : 'PurchaseInvoice';
 582   my $linked_records = $bt->linked_records( direction => 'to', to => $linked_record_to_table, query => [ id => $invoice->id ]  );
 583
 584   return @$linked_records ? 1 : 0;
 585 };
 586
 587
 588 sub init_models {
 589   my ($self) = @_;
 590
 591   SL::Controller::Helper::GetModels->new(
 592     controller => $self,
 593     sorted => {
 594       _default => {
 595         by    => 'transdate',
 596         dir   => 0,   # 1 = ASC, 0 = DESC : default sort is newest at top
 597       },
 598       transdate             => t8('Transdate'),
 599       remote_name           => t8('Remote name'),
 600       amount                => t8('Amount'),
 601       invoice_amount        => t8('Assigned'),
 602       invoices              => t8('Linked invoices'),
 603       valutadate            => t8('Valutadate'),
 604       remote_account_number => t8('Remote account number'),
 605       remote_bank_code      => t8('Remote bank code'),
 606       currency              => t8('Currency'),
 607       purpose               => t8('Purpose'),
 608       local_account_number  => t8('Local account number'),
 609       local_bank_code       => t8('Local bank code'),
 610       local_bank_name       => t8('Bank account'),
 611     },
 612     with_objects => [ 'local_bank_account', 'currency' ],
 613   );
 614 }
 615
 616 1;