SL/Controller/Buchungsgruppen.pm

   1 package SL::Controller::Buchungsgruppen;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::DB::TaxZone;
   8 use SL::Helper::Flash;
   9 use SL::Locale::String;
  10 use SL::DB::TaxzoneChart;
  11 use SL::Controller::ClientConfig;
  12 use SL::DB::Default;
  13
  14 use Rose::Object::MakeMethods::Generic (
  15   scalar                  => [ qw(config) ],
  16   'scalar --get_set_init' => [ qw(defaults) ],
  17 );
  18
  19 __PACKAGE__->run_before('check_auth');
  20 __PACKAGE__->run_before('load_config', only => [ qw(edit update delete) ]);
  21
  22 #
  23 # actions
  24 #
  25
  26 sub action_list {
  27   my ($self) = @_;
  28
  29   my $buchungsgruppen = SL::DB::Manager::Buchungsgruppe->get_all_sorted();
  30   my $taxzones        = SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]);
  31
  32   my %chartlist = ();
  33   foreach my $gruppe (@{ $buchungsgruppen }) {
  34       $chartlist{ $gruppe->id } = SL::DB::TaxzoneChart->get_all_accounts_by_buchungsgruppen_id($gruppe->id);
  35   }
  36
  37   $::form->header;
  38   $self->render('buchungsgruppen/list',
  39                 title           => t8('Buchungsgruppen'),
  40                 BUCHUNGSGRUPPEN => $buchungsgruppen,
  41                 CHARTLIST       => \%chartlist,
  42                 TAXZONES        => $taxzones);
  43 }
  44
  45 sub action_new {
  46   my ($self) = @_;
  47
  48   $self->config(SL::DB::Buchungsgruppe->new());
  49   $self->show_form(title => t8('Add Buchungsgruppe'));
  50 }
  51
  52 sub show_form {
  53   my ($self, %params) = @_;
  54
  55   $self->render('buchungsgruppen/form', %params,
  56                  TAXZONES       => SL::DB::Manager::TaxZone->get_all_sorted(),
  57                  ACCOUNTS       => SL::Controller::ClientConfig->init_accounts(),
  58                  account_label  => sub { "$_[0]{accno}--$_[0]{description}" });
  59 }
  60
  61 sub action_edit {
  62   my ($self) = @_;
  63
  64   # Allow editing of the charts of the Buchungsgruppe if it isn't assigned to
  65   # any parts. This is checked inside the template via the Buchungsgruppen
  66   # orphaned method, where an IF-ELSE statement toggles between L.select_tag
  67   # and text.
  68
  69   $self->show_form(title     => t8('Edit Buchungsgruppe'),
  70                    CHARTLIST => SL::DB::TaxzoneChart->get_all_accounts_by_buchungsgruppen_id($self->config->id));
  71 }
  72
  73 sub action_create {
  74   my ($self) = @_;
  75
  76   $self->config(SL::DB::Buchungsgruppe->new());
  77   $self->create_or_update;
  78 }
  79
  80 sub action_update {
  81   my ($self) = @_;
  82   $self->create_or_update;
  83 }
  84
  85 sub action_delete {
  86   my ($self) = @_;
  87
  88   # allow deletion of unused Buchungsgruppen. Will fail, due to database
  89   # constraint, if Buchungsgruppe is connected to a part
  90
  91   my $db = $self->{config}->db;
  92   $db->do_transaction(sub {
  93         my $taxzone_charts = SL::DB::Manager::TaxzoneChart->get_all(where => [ buchungsgruppen_id => $self->config->id ]);
  94         foreach my $taxzonechart ( @{$taxzone_charts} ) { $taxzonechart->delete };
  95         $self->config->delete();
  96         flash_later('info',  $::locale->text('The buchungsgruppe has been deleted.'));
  97   }) || flash_later('error', $::locale->text('The buchungsgruppe is in use and cannot be deleted.'));
  98
  99   $self->redirect_to(action => 'list');
 100
 101 }
 102
 103 sub action_reorder {
 104   my ($self) = @_;
 105
 106   SL::DB::Buchungsgruppe->reorder_list(@{ $::form->{bg_id} || [] });
 107
 108   $self->render(\'', { type => 'json' });
 109 }
 110
 111 #
 112 # filters
 113 #
 114
 115 sub check_auth {
 116   $::auth->assert('config');
 117 }
 118
 119 sub load_config {
 120   my ($self) = @_;
 121
 122   $self->config(SL::DB::Buchungsgruppe->new(id => $::form->{id})->load);
 123 }
 124
 125 #
 126 # helpers
 127 #
 128
 129 sub create_or_update {
 130   my ($self) = @_;
 131   my $is_new = !$self->config->id;
 132
 133   my $params = delete($::form->{config}) || { };
 134   delete $params->{id};
 135
 136   $self->config->assign_attributes(%{ $params });
 137
 138   my @errors = $self->config->validate;
 139
 140   if (@errors) {
 141     flash('error', @errors);
 142     $self->show_form(title => $is_new ? t8('Add taxzone') : t8('Edit taxzone'));
 143     return;
 144   }
 145
 146   $self->config->save;
 147
 148   # Save or update taxzone_charts for new or unused Buchungsgruppen
 149   if ($is_new or $self->config->orphaned) {
 150     my $taxzones = SL::DB::Manager::TaxZone->get_all_sorted();
 151
 152     foreach my $tz (@{ $taxzones }) {
 153       my $taxzone_chart = SL::DB::Manager::TaxzoneChart->find_by_or_create(buchungsgruppen_id => $self->config->id, taxzone_id => $tz->id);
 154       $taxzone_chart->taxzone_id($tz->id);
 155       $taxzone_chart->buchungsgruppen_id($self->config->id);
 156       $taxzone_chart->income_accno_id($::form->{"income_accno_id_" . $tz->id});
 157       $taxzone_chart->expense_accno_id($::form->{"expense_accno_id_" . $tz->id});
 158       $taxzone_chart->save;
 159     }
 160   }
 161
 162   flash_later('info', $is_new ? t8('The Buchungsgruppe has been created.') : t8('The Buchungsgruppe has been saved.'));
 163   $self->redirect_to(action => 'list');
 164 }
 165
 166 #
 167 # initializers
 168 #
 169
 170 sub init_defaults        { SL::DB::Default->get }
 171
 172 1;