SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::PriceSource::ALL;
  18 use SL::Template;
  19 use SL::Controller::TopQuickSearch;
  20
  21 __PACKAGE__->run_before('check_auth');
  22
  23 use Rose::Object::MakeMethods::Generic (
  24   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates all_price_sources h_unit_name available_quick_search_modules
  25                                   all_project_statuses all_project_types
  26                                   posting_options payment_options accounting_options inventory_options profit_options balance_startdate_method_options) ],
  27 );
  28
  29 sub action_edit {
  30   my ($self, %params) = @_;
  31
  32   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  33   $self->edit_form;
  34 }
  35
  36 sub action_save {
  37   my ($self, %params)      = @_;
  38
  39   my $defaults             = delete($::form->{defaults}) || {};
  40   my $entered_currencies   = delete($::form->{currencies}) || [];
  41   my $original_currency_id = $self->defaults->currency_id;
  42   $defaults->{disabled_price_sources} ||= [];
  43
  44   # undef several fields if an empty value has been selected.
  45   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  46     undef $defaults->{$_} if !$defaults->{$_};
  47   }
  48
  49   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  50
  51   $self->defaults->assign_attributes(%{ $defaults });
  52
  53   my %errors_idx;
  54
  55   # Handle currencies
  56   my (%new_currency_names);
  57   foreach my $existing_currency (@{ $self->all_currencies }) {
  58     my $new_name     = $existing_currency->name;
  59     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  60     $new_name        = $new_currency->{name} if $new_currency;
  61
  62     if (!$new_name) {
  63       $errors_idx{0} = t8('Currency names must not be empty.');
  64     } elsif ($new_currency_names{$new_name}) {
  65       $errors_idx{1} = t8('Currency names must be unique.');
  66     }
  67
  68     if ($new_name) {
  69       $new_currency_names{$new_name} = 1;
  70       $existing_currency->name($new_name);
  71     }
  72   }
  73
  74   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  75     $errors_idx{1} = t8('Currency names must be unique.');
  76   }
  77
  78   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  79
  80   # Check templates
  81   $::form->{new_templates}        =~ s:/::g;
  82   $::form->{new_master_templates} =~ s:/::g;
  83
  84   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  85     push @errors, t8('You must select existing print templates or create a new set.');
  86
  87   } elsif ($::form->{use_templates} eq 'new') {
  88     if (!$::form->{new_templates}) {
  89       push @errors, t8('You must enter a name for your new print templates.');
  90     } elsif (-d "templates/" . $::form->{new_templates}) {
  91       push @errors, t8('A directory with the name for the new print templates exists already.');
  92     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  93       push @errors, t8('The master templates where not found.');
  94     }
  95   }
  96
  97   # Show form again if there were any errors. Nothing's been changed
  98   # yet in the database.
  99   if (@errors) {
 100     flash('error', @errors);
 101     return $self->edit_form;
 102   }
 103
 104   # Save currencies. As the names must be unique we cannot simply save
 105   # them as they are -- the user might want to swap to names. So make
 106   # them unique first and assign the actual names in a second step.
 107   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 108   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 109   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 110
 111   # Create new currency if required
 112   my $new_currency;
 113   if ($::form->{new_currency}) {
 114     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 115     $new_currency->save;
 116   }
 117
 118   # If the user wants the new currency to be the default then replace
 119   # the ID placeholder with the proper value. However, if no new
 120   # currency has been created then don't change the value at all.
 121   if (-1 == $self->defaults->currency_id) {
 122     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 123   }
 124
 125   # Create new templates if requested.
 126   if ($::form->{use_templates} eq 'new') {
 127     local $File::Copy::Recursive::SkipFlop = 1;
 128     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 129     $self->defaults->templates('templates/' . $::form->{new_templates});
 130   }
 131
 132   # Finally save defaults.
 133   $self->defaults->save;
 134
 135   flash_later('info', t8('Client Configuration saved!'));
 136
 137   $self->redirect_to(action => 'edit');
 138 }
 139
 140 #
 141 # initializers
 142 #
 143
 144 sub init_defaults        { SL::DB::Default->get                                                                          }
 145 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 146 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 147 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 148 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 149 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 150 sub init_h_unit_name     { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde)                         }
 151 sub init_all_project_types    { SL::DB::Manager::ProjectType->get_all_sorted                                             }
 152 sub init_all_project_statuses { SL::DB::Manager::ProjectStatus->get_all_sorted                                           }
 153
 154 sub init_posting_options {
 155   [ { title => t8("never"),           value => 0           },
 156     { title => t8("every time"),      value => 1           },
 157     { title => t8("on the same day"), value => 2           }, ]
 158 }
 159
 160 sub init_payment_options {
 161   [ { title => t8("never"),           value => 0           },
 162     { title => t8("every time"),      value => 1           },
 163     { title => t8("on the same day"), value => 2           }, ]
 164 }
 165
 166 sub init_accounting_options {
 167   [ { title => t8("Accrual"),         value => "accrual"   },
 168     { title => t8("cash"),            value => "cash"      }, ]
 169 }
 170
 171 sub init_inventory_options {
 172   [ { title => t8("perpetual"),       value => "perpetual" },
 173     { title => t8("periodic"),        value => "periodic"  }, ]
 174 }
 175
 176 sub init_profit_options {
 177   [ { title => t8("balance"),         value => "balance"   },
 178     { title => t8("income"),          value => "income"    }, ]
 179 }
 180
 181 sub init_balance_startdate_method_options {
 182   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 183     { title => t8("Start of year"),                             value => "start_of_year"               },
 184     { title => t8("All transactions"),                          value => "all_transactions"            },
 185     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 186     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 187 }
 188
 189 sub init_all_price_sources {
 190   my @classes = SL::PriceSource::ALL->all_price_sources;
 191
 192   [ map { [ $_->name, $_->description ] } @classes ];
 193 }
 194
 195 sub init_available_quick_search_modules {
 196   [ SL::Controller::TopQuickSearch->new->available_modules ];
 197 }
 198
 199 #
 200 # filters
 201 #
 202
 203 sub check_auth {
 204   $::auth->assert('admin');
 205 }
 206
 207 #
 208 # helpers
 209 #
 210
 211 sub edit_form {
 212   my ($self) = @_;
 213
 214   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 215
 216   $self->render('client_config/form', title => t8('Client Configuration'),
 217                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 218                 make_templates_value => sub { 'templates/' . $_[0] },
 219               );
 220 }
 221
 222 1;