SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Unit;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String qw(t8);
  16 use SL::Template;
  17
  18 __PACKAGE__->run_before('check_auth');
  19
  20 use Rose::Object::MakeMethods::Generic (
  21   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates posting_options payment_options accounting_options inventory_options profit_options accounts balance_startdate_method_options) ],
  22 );
  23
  24 sub action_edit {
  25   my ($self, %params) = @_;
  26
  27   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  28   $self->edit_form;
  29 }
  30
  31 sub action_save {
  32   my ($self, %params)      = @_;
  33
  34   my $defaults             = delete($::form->{defaults}) || {};
  35   my $entered_currencies   = delete($::form->{currencies}) || [];
  36   my $original_currency_id = $self->defaults->currency_id;
  37
  38   # undef several fields if an empty value has been selected.
  39   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  40     undef $defaults->{$_} if !$defaults->{$_};
  41   }
  42
  43   $self->defaults->assign_attributes(%{ $defaults });
  44
  45   my %errors_idx;
  46
  47   # Handle currencies
  48   my (%new_currency_names);
  49   foreach my $existing_currency (@{ $self->all_currencies }) {
  50     my $new_name     = $existing_currency->name;
  51     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  52     $new_name        = $new_currency->{name} if $new_currency;
  53
  54     if (!$new_name) {
  55       $errors_idx{0} = t8('Currency names must not be empty.');
  56     } elsif ($new_currency_names{$new_name}) {
  57       $errors_idx{1} = t8('Currency names must be unique.');
  58     }
  59
  60     if ($new_name) {
  61       $new_currency_names{$new_name} = 1;
  62       $existing_currency->name($new_name);
  63     }
  64   }
  65
  66   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  67     $errors_idx{1} = t8('Currency names must be unique.');
  68   }
  69
  70   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  71
  72   # Check templates
  73   $::form->{new_templates}        =~ s:/::g;
  74   $::form->{new_master_templates} =~ s:/::g;
  75
  76   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  77     push @errors, t8('You must select existing print templates or create a new set.');
  78
  79   } elsif ($::form->{use_templates} eq 'new') {
  80     if (!$::form->{new_templates}) {
  81       push @errors, t8('You must enter a name for your new print templates.');
  82     } elsif (-d "templates/" . $::form->{new_templates}) {
  83       push @errors, t8('A directory with the name for the new print templates exists already.');
  84     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  85       push @errors, t8('The master templates where not found.');
  86     }
  87   }
  88
  89   # Show form again if there were any errors. Nothing's been changed
  90   # yet in the database.
  91   if (@errors) {
  92     flash('error', @errors);
  93     return $self->edit_form;
  94   }
  95
  96   # Save currencies. As the names must be unique we cannot simply save
  97   # them as they are -- the user might want to swap to names. So make
  98   # them unique first and assign the actual names in a second step.
  99   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 100   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 101   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 102
 103   # Create new currency if required
 104   my $new_currency;
 105   if ($::form->{new_currency}) {
 106     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 107     $new_currency->save;
 108   }
 109
 110   # If the user wants the new currency to be the default then replace
 111   # the ID placeholder with the proper value. However, if no new
 112   # currency has been created then don't change the value at all.
 113   if (-1 == $self->defaults->currency_id) {
 114     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 115   }
 116
 117   # Create new templates if requested.
 118   if ($::form->{use_templates} eq 'new') {
 119     local $File::Copy::Recursive::SkipFlop = 1;
 120     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 121     $self->defaults->templates('templates/' . $::form->{new_templates});
 122   }
 123
 124   # Finally save defaults.
 125   $self->defaults->save;
 126
 127   flash_later('info', t8('Client Configuration saved!'));
 128
 129   $self->redirect_to(action => 'edit');
 130 }
 131
 132 #
 133 # initializers
 134 #
 135
 136 sub init_defaults        { SL::DB::Default->get                                                                          }
 137 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 138 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 139 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 140 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'g'); $unit ? $unit->convertible_units : [] }
 141 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 142
 143 sub init_posting_options {
 144   [ { title => t8("never"),           value => 0           },
 145     { title => t8("every time"),      value => 1           },
 146     { title => t8("on the same day"), value => 2           }, ]
 147 }
 148
 149 sub init_payment_options {
 150   [ { title => t8("never"),           value => 0           },
 151     { title => t8("every time"),      value => 1           },
 152     { title => t8("on the same day"), value => 2           }, ]
 153 }
 154
 155 sub init_accounting_options {
 156   [ { title => t8("Accrual"),         value => "accrual"   },
 157     { title => t8("cash"),            value => "cash"      }, ]
 158 }
 159
 160 sub init_inventory_options {
 161   [ { title => t8("perpetual"),       value => "perpetual" },
 162     { title => t8("periodic"),        value => "periodic"  }, ]
 163 }
 164
 165 sub init_profit_options {
 166   [ { title => t8("balance"),         value => "balance"   },
 167     { title => t8("income"),          value => "income"    }, ]
 168 }
 169
 170 sub init_balance_startdate_method_options {
 171   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 172     { title => t8("Start of year"),                             value => "start_of_year"               },
 173     { title => t8("All transactions"),                          value => "all_transactions"            },
 174     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 175     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 176 }
 177
 178 sub init_accounts {
 179   my %accounts;
 180
 181   foreach my $chart (@{ SL::DB::Manager::Chart->get_all(where => [ link => { like => '%IC%' } ], sort_by => 'accno ASC') }) {
 182     my %added;
 183
 184     foreach my $link (split m/:/, $chart->link) {
 185       my $key = lc($link =~ /cogs/ ? 'IC_expense' : $link =~ /sale/ ? 'IC_income' : $link);
 186       next if $added{$key};
 187
 188       $added{$key}      = 1;
 189       $accounts{$key} ||= [];
 190       push @{ $accounts{$key} }, $chart;
 191     }
 192   }
 193
 194   $accounts{fx_gain} = SL::DB::Manager::Chart->get_all(where => [ category => 'I', charttype => 'A' ], sort_by => 'accno ASC');
 195   $accounts{fx_loss} = SL::DB::Manager::Chart->get_all(where => [ category => 'E', charttype => 'A' ], sort_by => 'accno ASC');
 196   $accounts{ar_paid} = SL::DB::Manager::Chart->get_all(where => [ link => { like => '%AR_paid%' }   ], sort_by => 'accno ASC');
 197
 198   return \%accounts;
 199 }
 200
 201 #
 202 # filters
 203 #
 204
 205 sub check_auth {
 206   $::auth->assert('admin');
 207 }
 208
 209 #
 210 # helpers
 211 #
 212
 213 sub edit_form {
 214   my ($self) = @_;
 215
 216   $self->render('client_config/form', title => t8('Client Configuration'),
 217                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 218                 make_templates_value => sub { 'templates/' . $_[0] },
 219               );
 220 }
 221
 222 1;