SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Unit;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String qw(t8);
  16 use SL::Template;
  17
  18 __PACKAGE__->run_before('check_auth');
  19
  20 use Rose::Object::MakeMethods::Generic (
  21   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates posting_options payment_options accounting_options inventory_options profit_options accounts balance_startdate_method_options) ],
  22 );
  23
  24 sub action_edit {
  25   my ($self, %params) = @_;
  26
  27   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  28   $self->edit_form;
  29 }
  30
  31 sub action_save {
  32   my ($self, %params)      = @_;
  33
  34   my $defaults             = delete($::form->{defaults}) || {};
  35   my $entered_currencies   = delete($::form->{currencies}) || [];
  36   my $original_currency_id = $self->defaults->currency_id;
  37
  38   # undef several fields if an empty value has been selected.
  39   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  40     undef $defaults->{$_} if !$defaults->{$_};
  41   }
  42
  43   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  44
  45   $self->defaults->assign_attributes(%{ $defaults });
  46
  47   my %errors_idx;
  48
  49   # Handle currencies
  50   my (%new_currency_names);
  51   foreach my $existing_currency (@{ $self->all_currencies }) {
  52     my $new_name     = $existing_currency->name;
  53     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  54     $new_name        = $new_currency->{name} if $new_currency;
  55
  56     if (!$new_name) {
  57       $errors_idx{0} = t8('Currency names must not be empty.');
  58     } elsif ($new_currency_names{$new_name}) {
  59       $errors_idx{1} = t8('Currency names must be unique.');
  60     }
  61
  62     if ($new_name) {
  63       $new_currency_names{$new_name} = 1;
  64       $existing_currency->name($new_name);
  65     }
  66   }
  67
  68   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  69     $errors_idx{1} = t8('Currency names must be unique.');
  70   }
  71
  72   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  73
  74   # Check templates
  75   $::form->{new_templates}        =~ s:/::g;
  76   $::form->{new_master_templates} =~ s:/::g;
  77
  78   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  79     push @errors, t8('You must select existing print templates or create a new set.');
  80
  81   } elsif ($::form->{use_templates} eq 'new') {
  82     if (!$::form->{new_templates}) {
  83       push @errors, t8('You must enter a name for your new print templates.');
  84     } elsif (-d "templates/" . $::form->{new_templates}) {
  85       push @errors, t8('A directory with the name for the new print templates exists already.');
  86     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  87       push @errors, t8('The master templates where not found.');
  88     }
  89   }
  90
  91   # Show form again if there were any errors. Nothing's been changed
  92   # yet in the database.
  93   if (@errors) {
  94     flash('error', @errors);
  95     return $self->edit_form;
  96   }
  97
  98   # Save currencies. As the names must be unique we cannot simply save
  99   # them as they are -- the user might want to swap to names. So make
 100   # them unique first and assign the actual names in a second step.
 101   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 102   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 103   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 104
 105   # Create new currency if required
 106   my $new_currency;
 107   if ($::form->{new_currency}) {
 108     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 109     $new_currency->save;
 110   }
 111
 112   # If the user wants the new currency to be the default then replace
 113   # the ID placeholder with the proper value. However, if no new
 114   # currency has been created then don't change the value at all.
 115   if (-1 == $self->defaults->currency_id) {
 116     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 117   }
 118
 119   # Create new templates if requested.
 120   if ($::form->{use_templates} eq 'new') {
 121     local $File::Copy::Recursive::SkipFlop = 1;
 122     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 123     $self->defaults->templates('templates/' . $::form->{new_templates});
 124   }
 125
 126   # Finally save defaults.
 127   $self->defaults->save;
 128
 129   flash_later('info', t8('Client Configuration saved!'));
 130
 131   $self->redirect_to(action => 'edit');
 132 }
 133
 134 #
 135 # initializers
 136 #
 137
 138 sub init_defaults        { SL::DB::Default->get                                                                          }
 139 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 140 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 141 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 142 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 143 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 144
 145 sub init_posting_options {
 146   [ { title => t8("never"),           value => 0           },
 147     { title => t8("every time"),      value => 1           },
 148     { title => t8("on the same day"), value => 2           }, ]
 149 }
 150
 151 sub init_payment_options {
 152   [ { title => t8("never"),           value => 0           },
 153     { title => t8("every time"),      value => 1           },
 154     { title => t8("on the same day"), value => 2           }, ]
 155 }
 156
 157 sub init_accounting_options {
 158   [ { title => t8("Accrual"),         value => "accrual"   },
 159     { title => t8("cash"),            value => "cash"      }, ]
 160 }
 161
 162 sub init_inventory_options {
 163   [ { title => t8("perpetual"),       value => "perpetual" },
 164     { title => t8("periodic"),        value => "periodic"  }, ]
 165 }
 166
 167 sub init_profit_options {
 168   [ { title => t8("balance"),         value => "balance"   },
 169     { title => t8("income"),          value => "income"    }, ]
 170 }
 171
 172 sub init_balance_startdate_method_options {
 173   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 174     { title => t8("Start of year"),                             value => "start_of_year"               },
 175     { title => t8("All transactions"),                          value => "all_transactions"            },
 176     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 177     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 178 }
 179
 180 sub init_accounts {
 181   my %accounts;
 182
 183   foreach my $chart (@{ SL::DB::Manager::Chart->get_all(where => [ link => { like => '%IC%' } ], sort_by => 'accno ASC') }) {
 184     my %added;
 185
 186     foreach my $link (split m/:/, $chart->link) {
 187       my $key = lc($link =~ /cogs/ ? 'IC_expense' : $link =~ /sale/ ? 'IC_income' : $link);
 188       next if $added{$key};
 189
 190       $added{$key}      = 1;
 191       $accounts{$key} ||= [];
 192       push @{ $accounts{$key} }, $chart;
 193     }
 194   }
 195
 196   $accounts{fx_gain} = SL::DB::Manager::Chart->get_all(where => [ category => 'I', charttype => 'A' ], sort_by => 'accno ASC');
 197   $accounts{fx_loss} = SL::DB::Manager::Chart->get_all(where => [ category => 'E', charttype => 'A' ], sort_by => 'accno ASC');
 198   $accounts{ar_paid} = SL::DB::Manager::Chart->get_all(where => [ link => { like => '%AR_paid%' }   ], sort_by => 'accno ASC');
 199
 200   return \%accounts;
 201 }
 202
 203 #
 204 # filters
 205 #
 206
 207 sub check_auth {
 208   $::auth->assert('admin');
 209 }
 210
 211 #
 212 # helpers
 213 #
 214
 215 sub edit_form {
 216   my ($self) = @_;
 217
 218   $self->render('client_config/form', title => t8('Client Configuration'),
 219                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 220                 make_templates_value => sub { 'templates/' . $_[0] },
 221               );
 222 }
 223
 224 1;