SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::PriceSource::ALL;
  18 use SL::Template;
  19 use SL::Controller::TopQuickSearch;
  20
  21 __PACKAGE__->run_before('check_auth');
  22
  23 use Rose::Object::MakeMethods::Generic (
  24   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates all_price_sources h_unit_name available_quick_search_modules
  25                                   all_project_statuses all_project_types
  26                                   posting_options payment_options accounting_options inventory_options profit_options balance_startdate_method_options) ],
  27 );
  28
  29 sub action_edit {
  30   my ($self, %params) = @_;
  31
  32   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  33   $::form->{feature_datev} = $self->defaults->feature_datev;
  34   $self->edit_form;
  35 }
  36
  37 sub action_save {
  38   my ($self, %params)      = @_;
  39
  40   my $defaults             = delete($::form->{defaults}) || {};
  41   my $entered_currencies   = delete($::form->{currencies}) || [];
  42   my $original_currency_id = $self->defaults->currency_id;
  43   $defaults->{disabled_price_sources} ||= [];
  44
  45   # undef several fields if an empty value has been selected.
  46   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  47     undef $defaults->{$_} if !$defaults->{$_};
  48   }
  49
  50   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  51
  52   $self->defaults->assign_attributes(%{ $defaults });
  53
  54   my %errors_idx;
  55
  56   # Handle currencies
  57   my (%new_currency_names);
  58   foreach my $existing_currency (@{ $self->all_currencies }) {
  59     my $new_name     = $existing_currency->name;
  60     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  61     $new_name        = $new_currency->{name} if $new_currency;
  62
  63     if (!$new_name) {
  64       $errors_idx{0} = t8('Currency names must not be empty.');
  65     } elsif ($new_currency_names{$new_name}) {
  66       $errors_idx{1} = t8('Currency names must be unique.');
  67     }
  68
  69     if ($new_name) {
  70       $new_currency_names{$new_name} = 1;
  71       $existing_currency->name($new_name);
  72     }
  73   }
  74
  75   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  76     $errors_idx{1} = t8('Currency names must be unique.');
  77   }
  78
  79   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  80
  81   # Check templates
  82   $::form->{new_templates}        =~ s:/::g;
  83   $::form->{new_master_templates} =~ s:/::g;
  84
  85   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  86     push @errors, t8('You must select existing print templates or create a new set.');
  87
  88   } elsif ($::form->{use_templates} eq 'new') {
  89     if (!$::form->{new_templates}) {
  90       push @errors, t8('You must enter a name for your new print templates.');
  91     } elsif (-d "templates/" . $::form->{new_templates}) {
  92       push @errors, t8('A directory with the name for the new print templates exists already.');
  93     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  94       push @errors, t8('The master templates where not found.');
  95     }
  96   }
  97
  98   # Show form again if there were any errors. Nothing's been changed
  99   # yet in the database.
 100   if (@errors) {
 101     flash('error', @errors);
 102     return $self->edit_form;
 103   }
 104
 105   # Save currencies. As the names must be unique we cannot simply save
 106   # them as they are -- the user might want to swap to names. So make
 107   # them unique first and assign the actual names in a second step.
 108   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 109   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 110   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 111
 112   # Create new currency if required
 113   my $new_currency;
 114   if ($::form->{new_currency}) {
 115     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 116     $new_currency->save;
 117   }
 118
 119   # If the user wants the new currency to be the default then replace
 120   # the ID placeholder with the proper value. However, if no new
 121   # currency has been created then don't change the value at all.
 122   if (-1 == $self->defaults->currency_id) {
 123     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 124   }
 125
 126   # Create new templates if requested.
 127   if ($::form->{use_templates} eq 'new') {
 128     local $File::Copy::Recursive::SkipFlop = 1;
 129     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 130     $self->defaults->templates('templates/' . $::form->{new_templates});
 131   }
 132
 133   # Finally save defaults.
 134   $self->defaults->save;
 135
 136   flash_later('info', t8('Client Configuration saved!'));
 137
 138   $self->redirect_to(action => 'edit');
 139 }
 140
 141 #
 142 # initializers
 143 #
 144
 145 sub init_defaults        { SL::DB::Default->get                                                                          }
 146 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 147 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 148 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 149 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 150 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 151 sub init_h_unit_name     { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde)                         }
 152 sub init_all_project_types    { SL::DB::Manager::ProjectType->get_all_sorted                                             }
 153 sub init_all_project_statuses { SL::DB::Manager::ProjectStatus->get_all_sorted                                           }
 154
 155 sub init_posting_options {
 156   [ { title => t8("never"),           value => 0           },
 157     { title => t8("every time"),      value => 1           },
 158     { title => t8("on the same day"), value => 2           }, ]
 159 }
 160
 161 sub init_payment_options {
 162   [ { title => t8("never"),           value => 0           },
 163     { title => t8("every time"),      value => 1           },
 164     { title => t8("on the same day"), value => 2           }, ]
 165 }
 166
 167 sub init_accounting_options {
 168   [ { title => t8("Accrual"),         value => "accrual"   },
 169     { title => t8("cash"),            value => "cash"      }, ]
 170 }
 171
 172 sub init_inventory_options {
 173   [ { title => t8("perpetual"),       value => "perpetual" },
 174     { title => t8("periodic"),        value => "periodic"  }, ]
 175 }
 176
 177 sub init_profit_options {
 178   [ { title => t8("balance"),         value => "balance"   },
 179     { title => t8("income"),          value => "income"    }, ]
 180 }
 181
 182 sub init_balance_startdate_method_options {
 183   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 184     { title => t8("Start of year"),                             value => "start_of_year"               },
 185     { title => t8("All transactions"),                          value => "all_transactions"            },
 186     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 187     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 188 }
 189
 190 sub init_all_price_sources {
 191   my @classes = SL::PriceSource::ALL->all_price_sources;
 192
 193   [ map { [ $_->name, $_->description ] } @classes ];
 194 }
 195
 196 sub init_available_quick_search_modules {
 197   [ SL::Controller::TopQuickSearch->new->available_modules ];
 198 }
 199
 200 #
 201 # filters
 202 #
 203
 204 sub check_auth {
 205   $::auth->assert('admin');
 206 }
 207
 208 #
 209 # helpers
 210 #
 211
 212 sub edit_form {
 213   my ($self) = @_;
 214
 215   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 216
 217   $self->render('client_config/form', title => t8('Client Configuration'),
 218                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 219                 make_templates_value => sub { 'templates/' . $_[0] },
 220               );
 221 }
 222
 223 1;