SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::Template;
  18
  19 __PACKAGE__->run_before('check_auth');
  20
  21 use Rose::Object::MakeMethods::Generic (
  22   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates h_unit_name
  23                                   posting_options payment_options accounting_options inventory_options profit_options accounts balance_startdate_method_options) ],
  24 );
  25
  26 sub action_edit {
  27   my ($self, %params) = @_;
  28
  29   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  30   $self->edit_form;
  31 }
  32
  33 sub action_save {
  34   my ($self, %params)      = @_;
  35
  36   my $defaults             = delete($::form->{defaults}) || {};
  37   my $entered_currencies   = delete($::form->{currencies}) || [];
  38   my $original_currency_id = $self->defaults->currency_id;
  39
  40   # undef several fields if an empty value has been selected.
  41   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  42     undef $defaults->{$_} if !$defaults->{$_};
  43   }
  44
  45   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  46
  47   $self->defaults->assign_attributes(%{ $defaults });
  48
  49   my %errors_idx;
  50
  51   # Handle currencies
  52   my (%new_currency_names);
  53   foreach my $existing_currency (@{ $self->all_currencies }) {
  54     my $new_name     = $existing_currency->name;
  55     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  56     $new_name        = $new_currency->{name} if $new_currency;
  57
  58     if (!$new_name) {
  59       $errors_idx{0} = t8('Currency names must not be empty.');
  60     } elsif ($new_currency_names{$new_name}) {
  61       $errors_idx{1} = t8('Currency names must be unique.');
  62     }
  63
  64     if ($new_name) {
  65       $new_currency_names{$new_name} = 1;
  66       $existing_currency->name($new_name);
  67     }
  68   }
  69
  70   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  71     $errors_idx{1} = t8('Currency names must be unique.');
  72   }
  73
  74   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  75
  76   # Check templates
  77   $::form->{new_templates}        =~ s:/::g;
  78   $::form->{new_master_templates} =~ s:/::g;
  79
  80   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  81     push @errors, t8('You must select existing print templates or create a new set.');
  82
  83   } elsif ($::form->{use_templates} eq 'new') {
  84     if (!$::form->{new_templates}) {
  85       push @errors, t8('You must enter a name for your new print templates.');
  86     } elsif (-d "templates/" . $::form->{new_templates}) {
  87       push @errors, t8('A directory with the name for the new print templates exists already.');
  88     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  89       push @errors, t8('The master templates where not found.');
  90     }
  91   }
  92
  93   # Show form again if there were any errors. Nothing's been changed
  94   # yet in the database.
  95   if (@errors) {
  96     flash('error', @errors);
  97     return $self->edit_form;
  98   }
  99
 100   # Save currencies. As the names must be unique we cannot simply save
 101   # them as they are -- the user might want to swap to names. So make
 102   # them unique first and assign the actual names in a second step.
 103   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 104   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 105   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 106
 107   # Create new currency if required
 108   my $new_currency;
 109   if ($::form->{new_currency}) {
 110     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 111     $new_currency->save;
 112   }
 113
 114   # If the user wants the new currency to be the default then replace
 115   # the ID placeholder with the proper value. However, if no new
 116   # currency has been created then don't change the value at all.
 117   if (-1 == $self->defaults->currency_id) {
 118     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 119   }
 120
 121   # Create new templates if requested.
 122   if ($::form->{use_templates} eq 'new') {
 123     local $File::Copy::Recursive::SkipFlop = 1;
 124     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 125     $self->defaults->templates('templates/' . $::form->{new_templates});
 126   }
 127
 128   # Finally save defaults.
 129   $self->defaults->save;
 130
 131   flash_later('info', t8('Client Configuration saved!'));
 132
 133   $self->redirect_to(action => 'edit');
 134 }
 135
 136 #
 137 # initializers
 138 #
 139
 140 sub init_defaults        { SL::DB::Default->get                                                                          }
 141 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 142 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 143 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 144 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 145 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 146 sub init_h_unit_name     { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde)                         };
 147
 148 sub init_posting_options {
 149   [ { title => t8("never"),           value => 0           },
 150     { title => t8("every time"),      value => 1           },
 151     { title => t8("on the same day"), value => 2           }, ]
 152 }
 153
 154 sub init_payment_options {
 155   [ { title => t8("never"),           value => 0           },
 156     { title => t8("every time"),      value => 1           },
 157     { title => t8("on the same day"), value => 2           }, ]
 158 }
 159
 160 sub init_accounting_options {
 161   [ { title => t8("Accrual"),         value => "accrual"   },
 162     { title => t8("cash"),            value => "cash"      }, ]
 163 }
 164
 165 sub init_inventory_options {
 166   [ { title => t8("perpetual"),       value => "perpetual" },
 167     { title => t8("periodic"),        value => "periodic"  }, ]
 168 }
 169
 170 sub init_profit_options {
 171   [ { title => t8("balance"),         value => "balance"   },
 172     { title => t8("income"),          value => "income"    }, ]
 173 }
 174
 175 sub init_balance_startdate_method_options {
 176   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 177     { title => t8("Start of year"),                             value => "start_of_year"               },
 178     { title => t8("All transactions"),                          value => "all_transactions"            },
 179     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 180     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 181 }
 182
 183 sub init_accounts {
 184   my %accounts;
 185
 186   foreach my $chart (@{ SL::DB::Manager::Chart->get_all(where => [ link => { like => '%IC%' } ], sort_by => 'accno ASC') }) {
 187     my %added;
 188
 189     foreach my $link (split m/:/, $chart->link) {
 190       my $key = lc($link =~ /cogs/ ? 'IC_expense' : $link =~ /sale/ ? 'IC_income' : $link);
 191       next if $added{$key};
 192
 193       $added{$key}      = 1;
 194       $accounts{$key} ||= [];
 195       push @{ $accounts{$key} }, $chart;
 196     }
 197   }
 198
 199   $accounts{fx_gain} = SL::DB::Manager::Chart->get_all(where => [ category => 'I', charttype => 'A' ], sort_by => 'accno ASC');
 200   $accounts{fx_loss} = SL::DB::Manager::Chart->get_all(where => [ category => 'E', charttype => 'A' ], sort_by => 'accno ASC');
 201   $accounts{ar_paid} = SL::DB::Manager::Chart->get_all(where => [ link => { like => '%AR_paid%' }   ], sort_by => 'accno ASC');
 202
 203   return \%accounts;
 204 }
 205
 206 #
 207 # filters
 208 #
 209
 210 sub check_auth {
 211   $::auth->assert('admin');
 212 }
 213
 214 #
 215 # helpers
 216 #
 217
 218 sub edit_form {
 219   my ($self) = @_;
 220
 221   $::request->layout->use_javascript("${_}.js") for qw(autocomplete_part);
 222
 223   $self->render('client_config/form', title => t8('Client Configuration'),
 224                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 225                 make_templates_value => sub { 'templates/' . $_[0] },
 226               );
 227 }
 228
 229 1;