SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::Template;
  18
  19 __PACKAGE__->run_before('check_auth');
  20
  21 use Rose::Object::MakeMethods::Generic (
  22   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates all_parts posting_options payment_options accounting_options inventory_options profit_options accounts balance_startdate_method_options) ],
  23 );
  24
  25 sub action_edit {
  26   my ($self, %params) = @_;
  27
  28   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  29   $self->edit_form;
  30 }
  31
  32 sub action_save {
  33   my ($self, %params)      = @_;
  34
  35   my $defaults             = delete($::form->{defaults}) || {};
  36   my $entered_currencies   = delete($::form->{currencies}) || [];
  37   my $original_currency_id = $self->defaults->currency_id;
  38
  39   # undef several fields if an empty value has been selected.
  40   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  41     undef $defaults->{$_} if !$defaults->{$_};
  42   }
  43
  44   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  45
  46   $self->defaults->assign_attributes(%{ $defaults });
  47
  48   my %errors_idx;
  49
  50   # Handle currencies
  51   my (%new_currency_names);
  52   foreach my $existing_currency (@{ $self->all_currencies }) {
  53     my $new_name     = $existing_currency->name;
  54     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  55     $new_name        = $new_currency->{name} if $new_currency;
  56
  57     if (!$new_name) {
  58       $errors_idx{0} = t8('Currency names must not be empty.');
  59     } elsif ($new_currency_names{$new_name}) {
  60       $errors_idx{1} = t8('Currency names must be unique.');
  61     }
  62
  63     if ($new_name) {
  64       $new_currency_names{$new_name} = 1;
  65       $existing_currency->name($new_name);
  66     }
  67   }
  68
  69   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  70     $errors_idx{1} = t8('Currency names must be unique.');
  71   }
  72
  73   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  74
  75   # Check templates
  76   $::form->{new_templates}        =~ s:/::g;
  77   $::form->{new_master_templates} =~ s:/::g;
  78
  79   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  80     push @errors, t8('You must select existing print templates or create a new set.');
  81
  82   } elsif ($::form->{use_templates} eq 'new') {
  83     if (!$::form->{new_templates}) {
  84       push @errors, t8('You must enter a name for your new print templates.');
  85     } elsif (-d "templates/" . $::form->{new_templates}) {
  86       push @errors, t8('A directory with the name for the new print templates exists already.');
  87     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  88       push @errors, t8('The master templates where not found.');
  89     }
  90   }
  91
  92   # Show form again if there were any errors. Nothing's been changed
  93   # yet in the database.
  94   if (@errors) {
  95     flash('error', @errors);
  96     return $self->edit_form;
  97   }
  98
  99   # Save currencies. As the names must be unique we cannot simply save
 100   # them as they are -- the user might want to swap to names. So make
 101   # them unique first and assign the actual names in a second step.
 102   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 103   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 104   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 105
 106   # Create new currency if required
 107   my $new_currency;
 108   if ($::form->{new_currency}) {
 109     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 110     $new_currency->save;
 111   }
 112
 113   # If the user wants the new currency to be the default then replace
 114   # the ID placeholder with the proper value. However, if no new
 115   # currency has been created then don't change the value at all.
 116   if (-1 == $self->defaults->currency_id) {
 117     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 118   }
 119
 120   # Create new templates if requested.
 121   if ($::form->{use_templates} eq 'new') {
 122     local $File::Copy::Recursive::SkipFlop = 1;
 123     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 124     $self->defaults->templates('templates/' . $::form->{new_templates});
 125   }
 126
 127   # Finally save defaults.
 128   $self->defaults->save;
 129
 130   flash_later('info', t8('Client Configuration saved!'));
 131
 132   $self->redirect_to(action => 'edit');
 133 }
 134
 135 #
 136 # initializers
 137 #
 138
 139 sub init_defaults        { SL::DB::Default->get                                                                          }
 140 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 141 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 142 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 143 sub init_all_parts       { SL::DB::Manager::Part->get_all_sorted                                                         }
 144 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 145 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 146
 147 sub init_posting_options {
 148   [ { title => t8("never"),           value => 0           },
 149     { title => t8("every time"),      value => 1           },
 150     { title => t8("on the same day"), value => 2           }, ]
 151 }
 152
 153 sub init_payment_options {
 154   [ { title => t8("never"),           value => 0           },
 155     { title => t8("every time"),      value => 1           },
 156     { title => t8("on the same day"), value => 2           }, ]
 157 }
 158
 159 sub init_accounting_options {
 160   [ { title => t8("Accrual"),         value => "accrual"   },
 161     { title => t8("cash"),            value => "cash"      }, ]
 162 }
 163
 164 sub init_inventory_options {
 165   [ { title => t8("perpetual"),       value => "perpetual" },
 166     { title => t8("periodic"),        value => "periodic"  }, ]
 167 }
 168
 169 sub init_profit_options {
 170   [ { title => t8("balance"),         value => "balance"   },
 171     { title => t8("income"),          value => "income"    }, ]
 172 }
 173
 174 sub init_balance_startdate_method_options {
 175   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 176     { title => t8("Start of year"),                             value => "start_of_year"               },
 177     { title => t8("All transactions"),                          value => "all_transactions"            },
 178     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 179     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 180 }
 181
 182 sub init_accounts {
 183   my %accounts;
 184
 185   foreach my $chart (@{ SL::DB::Manager::Chart->get_all(where => [ link => { like => '%IC%' } ], sort_by => 'accno ASC') }) {
 186     my %added;
 187
 188     foreach my $link (split m/:/, $chart->link) {
 189       my $key = lc($link =~ /cogs/ ? 'IC_expense' : $link =~ /sale/ ? 'IC_income' : $link);
 190       next if $added{$key};
 191
 192       $added{$key}      = 1;
 193       $accounts{$key} ||= [];
 194       push @{ $accounts{$key} }, $chart;
 195     }
 196   }
 197
 198   $accounts{fx_gain} = SL::DB::Manager::Chart->get_all(where => [ category => 'I', charttype => 'A' ], sort_by => 'accno ASC');
 199   $accounts{fx_loss} = SL::DB::Manager::Chart->get_all(where => [ category => 'E', charttype => 'A' ], sort_by => 'accno ASC');
 200   $accounts{ar_paid} = SL::DB::Manager::Chart->get_all(where => [ link => { like => '%AR_paid%' }   ], sort_by => 'accno ASC');
 201
 202   return \%accounts;
 203 }
 204
 205 #
 206 # filters
 207 #
 208
 209 sub check_auth {
 210   $::auth->assert('admin');
 211 }
 212
 213 #
 214 # helpers
 215 #
 216
 217 sub edit_form {
 218   my ($self) = @_;
 219
 220   $self->render('client_config/form', title => t8('Client Configuration'),
 221                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 222                 make_templates_value => sub { 'templates/' . $_[0] },
 223                 make_part_title      => sub { $_[0]->partnumber . ' ' . $_[0]->description },
 224               );
 225 }
 226
 227 1;