SL/Controller/ClientConfig.pm

   1 package SL::Controller::ClientConfig;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use File::Copy::Recursive ();
   7 use List::Util qw(first);
   8
   9 use SL::DB::Chart;
  10 use SL::DB::Currency;
  11 use SL::DB::Default;
  12 use SL::DB::Language;
  13 use SL::DB::Part;
  14 use SL::DB::Unit;
  15 use SL::Helper::Flash;
  16 use SL::Locale::String qw(t8);
  17 use SL::PriceSource::ALL;
  18 use SL::Template;
  19
  20 __PACKAGE__->run_before('check_auth');
  21
  22 use Rose::Object::MakeMethods::Generic (
  23   'scalar --get_set_init' => [ qw(defaults all_warehouses all_weightunits all_languages all_currencies all_templates all_price_sources h_unit_name
  24                                   posting_options payment_options accounting_options inventory_options profit_options accounts balance_startdate_method_options) ],
  25 );
  26
  27 sub action_edit {
  28   my ($self, %params) = @_;
  29
  30   $::form->{use_templates} = $self->defaults->templates ? 'existing' : 'new';
  31   $self->edit_form;
  32 }
  33
  34 sub action_save {
  35   my ($self, %params)      = @_;
  36
  37   my $defaults             = delete($::form->{defaults}) || {};
  38   my $entered_currencies   = delete($::form->{currencies}) || [];
  39   my $original_currency_id = $self->defaults->currency_id;
  40   $defaults->{disabled_price_sources} ||= [];
  41
  42   # undef several fields if an empty value has been selected.
  43   foreach (qw(warehouse_id bin_id warehouse_id_ignore_onhand bin_id_ignore_onhand)) {
  44     undef $defaults->{$_} if !$defaults->{$_};
  45   }
  46
  47   $defaults->{$_} = $::form->parse_amount(\%::myconfig, $defaults->{$_}) for qw(customer_hourly_rate);
  48
  49   $self->defaults->assign_attributes(%{ $defaults });
  50
  51   my %errors_idx;
  52
  53   # Handle currencies
  54   my (%new_currency_names);
  55   foreach my $existing_currency (@{ $self->all_currencies }) {
  56     my $new_name     = $existing_currency->name;
  57     my $new_currency = first { $_->{id} == $existing_currency->id } @{ $entered_currencies };
  58     $new_name        = $new_currency->{name} if $new_currency;
  59
  60     if (!$new_name) {
  61       $errors_idx{0} = t8('Currency names must not be empty.');
  62     } elsif ($new_currency_names{$new_name}) {
  63       $errors_idx{1} = t8('Currency names must be unique.');
  64     }
  65
  66     if ($new_name) {
  67       $new_currency_names{$new_name} = 1;
  68       $existing_currency->name($new_name);
  69     }
  70   }
  71
  72   if ($::form->{new_currency} && $new_currency_names{ $::form->{new_currency} }) {
  73     $errors_idx{1} = t8('Currency names must be unique.');
  74   }
  75
  76   my @errors = map { $errors_idx{$_} } sort keys %errors_idx;
  77
  78   # Check templates
  79   $::form->{new_templates}        =~ s:/::g;
  80   $::form->{new_master_templates} =~ s:/::g;
  81
  82   if (($::form->{use_templates} eq 'existing') && ($self->defaults->templates !~ m:^templates/[^/]+$:)) {
  83     push @errors, t8('You must select existing print templates or create a new set.');
  84
  85   } elsif ($::form->{use_templates} eq 'new') {
  86     if (!$::form->{new_templates}) {
  87       push @errors, t8('You must enter a name for your new print templates.');
  88     } elsif (-d "templates/" . $::form->{new_templates}) {
  89       push @errors, t8('A directory with the name for the new print templates exists already.');
  90     } elsif (! -d "templates/print/" . $::form->{new_master_templates}) {
  91       push @errors, t8('The master templates where not found.');
  92     }
  93   }
  94
  95   # Show form again if there were any errors. Nothing's been changed
  96   # yet in the database.
  97   if (@errors) {
  98     flash('error', @errors);
  99     return $self->edit_form;
 100   }
 101
 102   # Save currencies. As the names must be unique we cannot simply save
 103   # them as they are -- the user might want to swap to names. So make
 104   # them unique first and assign the actual names in a second step.
 105   my %currency_names_by_id = map { ($_->id => $_->name) } @{ $self->all_currencies };
 106   $_->update_attributes(name => '__039519735__' . $_->{id})        for @{ $self->all_currencies };
 107   $_->update_attributes(name => $currency_names_by_id{ $_->{id} }) for @{ $self->all_currencies };
 108
 109   # Create new currency if required
 110   my $new_currency;
 111   if ($::form->{new_currency}) {
 112     $new_currency = SL::DB::Currency->new(name => $::form->{new_currency});
 113     $new_currency->save;
 114   }
 115
 116   # If the user wants the new currency to be the default then replace
 117   # the ID placeholder with the proper value. However, if no new
 118   # currency has been created then don't change the value at all.
 119   if (-1 == $self->defaults->currency_id) {
 120     $self->defaults->currency_id($new_currency ? $new_currency->id : $original_currency_id);
 121   }
 122
 123   # Create new templates if requested.
 124   if ($::form->{use_templates} eq 'new') {
 125     local $File::Copy::Recursive::SkipFlop = 1;
 126     File::Copy::Recursive::dircopy('templates/print/' . $::form->{new_master_templates}, 'templates/' . $::form->{new_templates});
 127     $self->defaults->templates('templates/' . $::form->{new_templates});
 128   }
 129
 130   # Finally save defaults.
 131   $self->defaults->save;
 132
 133   flash_later('info', t8('Client Configuration saved!'));
 134
 135   $self->redirect_to(action => 'edit');
 136 }
 137
 138 #
 139 # initializers
 140 #
 141
 142 sub init_defaults        { SL::DB::Default->get                                                                          }
 143 sub init_all_warehouses  { SL::DB::Manager::Warehouse->get_all_sorted                                                    }
 144 sub init_all_languages   { SL::DB::Manager::Language->get_all_sorted                                                     }
 145 sub init_all_currencies  { SL::DB::Manager::Currency->get_all_sorted                                                     }
 146 sub init_all_weightunits { my $unit = SL::DB::Manager::Unit->find_by(name => 'kg'); $unit ? $unit->convertible_units : [] }
 147 sub init_all_templates   { +{ SL::Template->available_templates }                                                        }
 148 sub init_h_unit_name     { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde)                         };
 149
 150 sub init_posting_options {
 151   [ { title => t8("never"),           value => 0           },
 152     { title => t8("every time"),      value => 1           },
 153     { title => t8("on the same day"), value => 2           }, ]
 154 }
 155
 156 sub init_payment_options {
 157   [ { title => t8("never"),           value => 0           },
 158     { title => t8("every time"),      value => 1           },
 159     { title => t8("on the same day"), value => 2           }, ]
 160 }
 161
 162 sub init_accounting_options {
 163   [ { title => t8("Accrual"),         value => "accrual"   },
 164     { title => t8("cash"),            value => "cash"      }, ]
 165 }
 166
 167 sub init_inventory_options {
 168   [ { title => t8("perpetual"),       value => "perpetual" },
 169     { title => t8("periodic"),        value => "periodic"  }, ]
 170 }
 171
 172 sub init_profit_options {
 173   [ { title => t8("balance"),         value => "balance"   },
 174     { title => t8("income"),          value => "income"    }, ]
 175 }
 176
 177 sub init_balance_startdate_method_options {
 178   [ { title => t8("After closed period"),                       value => "closed_to"                   },
 179     { title => t8("Start of year"),                             value => "start_of_year"               },
 180     { title => t8("All transactions"),                          value => "all_transactions"            },
 181     { title => t8("Last opening balance or all transactions"),  value => "last_ob_or_all_transactions" },
 182     { title => t8("Last opening balance or start of year"),     value => "last_ob_or_start_of_year"    }, ]
 183 }
 184
 185 sub init_accounts {
 186   my %accounts;
 187
 188   foreach my $chart (@{ SL::DB::Manager::Chart->get_all(where => [ link => { like => '%IC%' } ], sort_by => 'accno ASC') }) {
 189     my %added;
 190
 191     foreach my $link (split m/:/, $chart->link) {
 192       my $key = lc($link =~ /cogs/ ? 'IC_expense' : $link =~ /sale/ ? 'IC_income' : $link);
 193       next if $added{$key};
 194
 195       $added{$key}      = 1;
 196       $accounts{$key} ||= [];
 197       push @{ $accounts{$key} }, $chart;
 198     }
 199   }
 200
 201   $accounts{fx_gain} = SL::DB::Manager::Chart->get_all(where => [ category => 'I', charttype => 'A' ], sort_by => 'accno ASC');
 202   $accounts{fx_loss} = SL::DB::Manager::Chart->get_all(where => [ category => 'E', charttype => 'A' ], sort_by => 'accno ASC');
 203   $accounts{ar_paid} = SL::DB::Manager::Chart->get_all(where => [ link => { like => '%AR_paid%' }   ], sort_by => 'accno ASC');
 204
 205   return \%accounts;
 206 }
 207
 208 sub init_all_price_sources {
 209   my @classes = SL::PriceSource::ALL->all_price_sources;
 210
 211   [ map { [ $_->name, $_->description ] } @classes ];
 212 }
 213
 214 #
 215 # filters
 216 #
 217
 218 sub check_auth {
 219   $::auth->assert('admin');
 220 }
 221
 222 #
 223 # helpers
 224 #
 225
 226 sub edit_form {
 227   my ($self) = @_;
 228
 229   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 230
 231   $self->render('client_config/form', title => t8('Client Configuration'),
 232                 make_chart_title     => sub { $_[0]->accno . '--' . $_[0]->description },
 233                 make_templates_value => sub { 'templates/' . $_[0] },
 234               );
 235 }
 236
 237 1;