SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   my $old_numberformat      = $::myconfig{numberformat};
  49   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86
  87   $::myconfig{numberformat} = $old_numberformat;
  88 }
  89
  90 sub add_columns {
  91   my ($self, @columns) = @_;
  92
  93   my $h = $self->controller->headers;
  94
  95   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  96     $h->{used}->{$column} = 1;
  97     push @{ $h->{methods} }, $column;
  98     push @{ $h->{headers} }, $column;
  99   }
 100 }
 101
 102 sub add_info_columns {
 103   my ($self, @columns) = @_;
 104
 105   my $h = $self->controller->info_headers;
 106
 107   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 108     $h->{used}->{ $column->{method} } = 1;
 109     push @{ $h->{methods} }, $column->{method};
 110     push @{ $h->{headers} }, $column->{header};
 111   }
 112 }
 113
 114 sub add_raw_data_columns {
 115   my ($self, @columns) = @_;
 116
 117   my $h = $self->controller->raw_data_headers;
 118
 119   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 120     $h->{used}->{$column} = 1;
 121     push @{ $h->{headers} }, $column;
 122   }
 123 }
 124
 125 sub add_cvar_raw_data_columns {
 126   my ($self) = @_;
 127
 128   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 129 }
 130
 131 sub init_all_cvar_configs {
 132   # Must be overridden by derived specialized importer classes.
 133   return [];
 134 }
 135
 136 sub init_cvar_columns {
 137   my ($self) = @_;
 138
 139   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 140 }
 141
 142 sub init_all_languages {
 143   my ($self) = @_;
 144
 145   return SL::DB::Manager::Language->get_all;
 146 }
 147
 148 sub init_all_bank_accounts {
 149   my ($self) = @_;
 150
 151   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 152 }
 153
 154 sub init_payment_terms_by {
 155   my ($self) = @_;
 156
 157   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 159 }
 160
 161 sub init_delivery_terms_by {
 162   my ($self) = @_;
 163
 164   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 166 }
 167
 168 sub init_all_vc {
 169   my ($self) = @_;
 170
 171   return { customers => SL::DB::Manager::Customer->get_all,
 172            vendors   => SL::DB::Manager::Vendor->get_all };
 173 }
 174
 175 sub init_clone_methods {
 176   {}
 177 }
 178
 179 sub force_allow_columns {
 180   return ();
 181 }
 182
 183 sub init_vc_by {
 184   my ($self)    = @_;
 185
 186   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 187   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 191
 192   return { id     => \%by_id,
 193            number => \%by_number,
 194            name   => \%by_name,   };
 195 }
 196
 197 sub check_vc {
 198   my ($self, $entry, $id_column) = @_;
 199
 200   if ($entry->{object}->$id_column) {
 201     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 202   }
 203
 204   if (!$entry->{object}->$id_column) {
 205     my $vc = ($entry->{raw_data}->{customernumber} && $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} })
 206           || ($entry->{raw_data}->{vendornumber}   && $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   });
 207     $entry->{object}->$id_column($vc->id) if $vc;
 208   }
 209
 210   if (!$entry->{object}->$id_column) {
 211     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 212           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 213     $entry->{object}->$id_column($vc->id) if $vc;
 214   }
 215
 216   if ($entry->{object}->$id_column) {
 217     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 218   } else {
 219     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 220   }
 221 }
 222
 223 sub handle_cvars {
 224   my ($self, $entry) = @_;
 225
 226   my %type_to_column = ( text      => 'text_value',
 227                          textfield => 'text_value',
 228                          select    => 'text_value',
 229                          date      => 'timestamp_value_as_date',
 230                          timestamp => 'timestamp_value_as_date',
 231                          number    => 'number_value_as_number',
 232                          bool      => 'bool_value' );
 233
 234   my @cvars;
 235   my %changed_cvars;
 236   foreach my $config (@{ $self->all_cvar_configs }) {
 237     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 238     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 239     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 240
 241     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 242
 243     push @cvars, $new_cvar;
 244     $changed_cvars{$config->name} = $new_cvar;
 245   }
 246
 247   # merge existing with new cvars. swap every existing with the imported one, push the rest
 248   if (@cvars) {
 249     my @orig_cvars = ($entry->{object_to_save} || $entry->{object})->custom_variables;
 250     for (@orig_cvars) {
 251       $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 252       delete $changed_cvars{ $_->config->name };
 253     }
 254     push @orig_cvars, values %changed_cvars;
 255
 256     $entry->{object}->custom_variables(\@orig_cvars);
 257   }
 258 }
 259
 260 sub init_profile {
 261   my ($self) = @_;
 262
 263   eval "require " . $self->class;
 264
 265   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 266   delete $unwanted{$_} for ($self->force_allow_columns);
 267
 268   my %profile;
 269   for my $col ($self->class->meta->columns) {
 270     next if $unwanted{$col};
 271
 272     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 273       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 274       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 275       :                                                                     $col->name;
 276
 277     $profile{$col} = $name;
 278   }
 279
 280   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 281
 282   \%profile;
 283 }
 284
 285 sub add_displayable_columns {
 286   my ($self, @columns) = @_;
 287
 288   my @cols       = @{ $self->controller->displayable_columns || [] };
 289   my %ex_col_map = map { $_->{name} => $_ } @cols;
 290
 291   foreach my $column (@columns) {
 292     if ($ex_col_map{ $column->{name} }) {
 293       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 294     } else {
 295       push @cols, $column;
 296     }
 297   }
 298
 299   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 300 }
 301
 302 sub setup_displayable_columns {
 303   my ($self) = @_;
 304
 305   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 306 }
 307
 308 sub add_cvar_columns_to_displayable_columns {
 309   my ($self) = @_;
 310
 311   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 312                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 313                                      @{ $self->all_cvar_configs });
 314 }
 315
 316 sub init_existing_objects {
 317   my ($self) = @_;
 318
 319   eval "require " . $self->class;
 320   $self->existing_objects($self->manager_class->get_all);
 321 }
 322
 323 sub init_class {
 324   die "class not set";
 325 }
 326
 327 sub init_manager_class {
 328   my ($self) = @_;
 329
 330   $self->class =~ m/^SL::DB::(.+)/;
 331   $self->manager_class("SL::DB::Manager::" . $1);
 332 }
 333
 334 sub is_multiplexed { 0 }
 335
 336 sub check_objects {
 337 }
 338
 339 sub check_duplicates {
 340 }
 341
 342 sub check_std_duplicates {
 343   my $self = shift;
 344
 345   my $duplicates = {};
 346
 347   my $all_fields = $self->get_duplicate_check_fields();
 348
 349   foreach my $key (keys(%{ $all_fields })) {
 350     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 351       $duplicates->{$key} = {};
 352     }
 353   }
 354
 355   my @duplicates_keys = keys(%{ $duplicates });
 356
 357   if ( !scalar(@duplicates_keys) ) {
 358     return;
 359   }
 360
 361   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 362     foreach my $object (@{ $self->existing_objects }) {
 363       foreach my $key (@duplicates_keys) {
 364         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 365         $duplicates->{$key}->{$value} = 'db';
 366       }
 367     }
 368   }
 369
 370   foreach my $entry (@{ $self->controller->data }) {
 371     if ( @{ $entry->{errors} } ) {
 372       next;
 373     }
 374
 375     my $object = $entry->{object};
 376
 377     foreach my $key (@duplicates_keys) {
 378       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 379
 380       if ( exists($duplicates->{$key}->{$value}) ) {
 381         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 382         last;
 383       } else {
 384         $duplicates->{$key}->{$value} = 'csv';
 385       }
 386
 387     }
 388   }
 389
 390 }
 391
 392 sub get_duplicate_check_fields {
 393   return {};
 394 }
 395
 396 sub check_payment {
 397   my ($self, $entry) = @_;
 398
 399   my $object = $entry->{object};
 400
 401   # Check whether or not payment ID is valid.
 402   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 403     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 404     return 0;
 405   }
 406
 407   # Map name to ID if given.
 408   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 409     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 410
 411     if (!$terms) {
 412       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 413       return 0;
 414     }
 415
 416     $object->payment_id($terms->id);
 417
 418     # register payment_id for method copying later
 419     $self->clone_methods->{payment_id} = 1;
 420   }
 421
 422   return 1;
 423 }
 424
 425 sub check_delivery_term {
 426   my ($self, $entry) = @_;
 427
 428   my $object = $entry->{object};
 429
 430   # Check whether or not delivery term ID is valid.
 431   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 432     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 433     return 0;
 434   }
 435
 436   # Map name to ID if given.
 437   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 438     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 439
 440     if (!$terms) {
 441       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 442       return 0;
 443     }
 444
 445     $object->delivery_term_id($terms->id);
 446
 447     # register delivery_term_id for method copying later
 448     $self->clone_methods->{delivery_term_id} = 1;
 449   }
 450
 451   return 1;
 452 }
 453
 454 sub save_objects {
 455   my ($self, %params) = @_;
 456
 457   my $data = $params{data} || $self->controller->data;
 458
 459   return unless $data->[0];
 460   return unless $data->[0]{object};
 461
 462   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 463
 464   my $dbh = $data->[0]{object}->db->dbh;
 465
 466   my $last_index = $#$data;
 467   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 468
 469   for my $chunk (0 .. $last_index / $chunk_size) {
 470     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 471     SL::DB->client->with_transaction(sub {
 472       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 473         my $entry = $data->[$entry_index];
 474         next if @{ $entry->{errors} };
 475
 476         my $object = $entry->{object_to_save} || $entry->{object};
 477
 478         my $ret;
 479         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 480           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 481         } elsif ( !$ret ) {
 482           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 483         } else {
 484           $self->_save_history($object);
 485           $self->controller->num_imported($self->controller->num_imported + 1);
 486         }
 487       }
 488       1;
 489     }) or do { die SL::DB->client->error };
 490   }
 491   $self->controller->track_progress(progress => 100);
 492 }
 493
 494 sub field_lengths {
 495   my ($self) = @_;
 496
 497   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 498 }
 499
 500 sub fix_field_lengths {
 501   my ($self) = @_;
 502
 503   my %field_lengths = $self->field_lengths;
 504   foreach my $entry (@{ $self->controller->data }) {
 505     next unless @{ $entry->{errors} };
 506     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 507   }
 508 }
 509
 510 sub clean_fields {
 511   my ($self, $illegal_chars, $object, @fields) = @_;
 512
 513   my @cleaned_fields;
 514   foreach my $field (grep { $object->can($_) } @fields) {
 515     my $value = $object->$field;
 516
 517     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 518
 519     $object->$field($value);
 520     push @cleaned_fields, $field;
 521   }
 522
 523   return @cleaned_fields;
 524 }
 525
 526 sub _save_history {
 527   my ($self, $object) = @_;
 528
 529   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders ar_transactions)) {
 530     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 531                  : $self->controller->{type} eq 'customers_vendors' ?
 532                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 533                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 534                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 535                  : '';
 536
 537     my $what_done = $self->controller->{type} eq 'orders' ? 'sales_order'
 538                   : '';
 539
 540     SL::DB::History->new(
 541       trans_id    => $object->id,
 542       snumbers    => $snumbers,
 543       employee_id => $self->controller->{employee_id},
 544       addition    => 'SAVED',
 545       what_done   => $what_done,
 546     )->save();
 547   }
 548 }
 549
 550 1;