SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(Rose::Object);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  19  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  20 );
  21
  22 sub run {
  23   my ($self, %params) = @_;
  24
  25   $self->test_run($params{test_run});
  26
  27   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  28
  29   my $profile = $self->profile;
  30   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  31                                   encoding               => $self->controller->profile->get('charset'),
  32                                   class                  => $self->class,
  33                                   profile                => $profile,
  34                                   ignore_unknown_columns => 1,
  35                                   strict_profile         => 1,
  36                                   case_insensitive_header => 1,
  37                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  38                                  ));
  39
  40   $self->controller->track_progress(progress => 10);
  41
  42   my $old_numberformat      = $::myconfig{numberformat};
  43   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  44
  45   $self->csv->parse;
  46
  47   $self->controller->track_progress(progress => 50);
  48
  49   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  50
  51   return if ( !$self->csv->header || $self->csv->errors );
  52
  53   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  54   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  55   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  56   $self->controller->headers($headers);
  57   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  58   $self->controller->info_headers({ used => { }, headers => [ ] });
  59
  60   my @objects  = $self->csv->get_objects;
  61
  62   $self->controller->track_progress(progress => 70);
  63
  64   my @raw_data = @{ $self->csv->get_data };
  65
  66   $self->controller->track_progress(progress => 80);
  67
  68   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  69
  70   $self->controller->track_progress(progress => 90);
  71
  72   $self->check_objects;
  73   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  74     $self->check_std_duplicates();
  75     $self->check_duplicates();
  76   }
  77   $self->fix_field_lengths;
  78
  79   $self->controller->track_progress(progress => 100);
  80
  81   $::myconfig{numberformat} = $old_numberformat;
  82 }
  83
  84 sub add_columns {
  85   my ($self, @columns) = @_;
  86
  87   my $h = $self->controller->headers;
  88
  89   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  90     $h->{used}->{$column} = 1;
  91     push @{ $h->{methods} }, $column;
  92     push @{ $h->{headers} }, $column;
  93   }
  94 }
  95
  96 sub add_info_columns {
  97   my ($self, @columns) = @_;
  98
  99   my $h = $self->controller->info_headers;
 100
 101   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 102     $h->{used}->{ $column->{method} } = 1;
 103     push @{ $h->{methods} }, $column->{method};
 104     push @{ $h->{headers} }, $column->{header};
 105   }
 106 }
 107
 108 sub add_raw_data_columns {
 109   my ($self, @columns) = @_;
 110
 111   my $h = $self->controller->raw_data_headers;
 112
 113   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 114     $h->{used}->{$column} = 1;
 115     push @{ $h->{headers} }, $column;
 116   }
 117 }
 118
 119 sub add_cvar_raw_data_columns {
 120   my ($self) = @_;
 121
 122   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 123 }
 124
 125 sub init_cvar_columns {
 126   my ($self) = @_;
 127
 128   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 129 }
 130
 131 sub init_all_languages {
 132   my ($self) = @_;
 133
 134   return SL::DB::Manager::Language->get_all;
 135 }
 136
 137 sub init_payment_terms_by {
 138   my ($self) = @_;
 139
 140   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 141   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 142 }
 143
 144 sub init_all_vc {
 145   my ($self) = @_;
 146
 147   return { customers => SL::DB::Manager::Customer->get_all,
 148            vendors   => SL::DB::Manager::Vendor->get_all };
 149 }
 150
 151 sub init_vc_by {
 152   my ($self)    = @_;
 153
 154   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 155   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 156                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 157   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 158                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 159
 160   return { id     => \%by_id,
 161            number => \%by_number,
 162            name   => \%by_name,   };
 163 }
 164
 165 sub check_vc {
 166   my ($self, $entry, $id_column) = @_;
 167
 168   if ($entry->{object}->$id_column) {
 169     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 170   }
 171
 172   if (!$entry->{object}->$id_column) {
 173     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 174           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 175     $entry->{object}->$id_column($vc->id) if $vc;
 176   }
 177
 178   if (!$entry->{object}->$id_column) {
 179     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 180           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 181     $entry->{object}->$id_column($vc->id) if $vc;
 182   }
 183
 184   if ($entry->{object}->$id_column) {
 185     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 186   } else {
 187     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 188   }
 189 }
 190
 191 sub handle_cvars {
 192   my ($self, $entry) = @_;
 193
 194   return unless $self->can('all_cvar_configs');
 195
 196   my %type_to_column = ( text      => 'text_value',
 197                          textfield => 'text_value',
 198                          select    => 'text_value',
 199                          date      => 'timestamp_value_as_date',
 200                          timestamp => 'timestamp_value_as_date',
 201                          number    => 'number_value_as_number',
 202                          bool      => 'bool_value' );
 203
 204   my @cvars;
 205   foreach my $config (@{ $self->all_cvar_configs }) {
 206     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 207     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 208     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 209
 210     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 211   }
 212
 213   $entry->{object}->custom_variables(\@cvars);
 214 }
 215
 216 sub init_profile {
 217   my ($self) = @_;
 218
 219   eval "require " . $self->class;
 220
 221   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 222   my %profile;
 223   for my $col ($self->class->meta->columns) {
 224     next if $unwanted{$col};
 225
 226     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 227       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 228       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 229       :                                                                     $col->name;
 230
 231     $profile{$col} = $name;
 232   }
 233
 234   if ($self->can('all_cvar_configs')) {
 235     for (@{ $self->all_cvar_configs }) {
 236       $profile{ 'cvar_' . $_->name } = '';
 237     }
 238   }
 239
 240   \%profile;
 241 }
 242
 243 sub add_displayable_columns {
 244   my ($self, @columns) = @_;
 245
 246   my @cols       = @{ $self->controller->displayable_columns || [] };
 247   my %ex_col_map = map { $_->{name} => $_ } @cols;
 248
 249   foreach my $column (@columns) {
 250     if ($ex_col_map{ $column->{name} }) {
 251       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 252     } else {
 253       push @cols, $column;
 254     }
 255   }
 256
 257   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 258 }
 259
 260 sub setup_displayable_columns {
 261   my ($self) = @_;
 262
 263   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 264 }
 265
 266 sub add_cvar_columns_to_displayable_columns {
 267   my ($self) = @_;
 268
 269   return unless $self->can('all_cvar_configs');
 270
 271   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 272                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 273                                      @{ $self->all_cvar_configs });
 274 }
 275
 276 sub init_existing_objects {
 277   my ($self) = @_;
 278
 279   eval "require " . $self->class;
 280   $self->existing_objects($self->manager_class->get_all);
 281 }
 282
 283 sub init_class {
 284   die "class not set";
 285 }
 286
 287 sub init_manager_class {
 288   my ($self) = @_;
 289
 290   $self->class =~ m/^SL::DB::(.+)/;
 291   $self->manager_class("SL::DB::Manager::" . $1);
 292 }
 293
 294 sub check_objects {
 295 }
 296
 297 sub check_duplicates {
 298 }
 299
 300 sub check_std_duplicates {
 301   my $self = shift;
 302
 303   my $duplicates = {};
 304
 305   my $all_fields = $self->get_duplicate_check_fields();
 306
 307   foreach my $key (keys(%{ $all_fields })) {
 308     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 309       $duplicates->{$key} = {};
 310     }
 311   }
 312
 313   my @duplicates_keys = keys(%{ $duplicates });
 314
 315   if ( !scalar(@duplicates_keys) ) {
 316     return;
 317   }
 318
 319   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 320     foreach my $object (@{ $self->existing_objects }) {
 321       foreach my $key (@duplicates_keys) {
 322         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 323         $duplicates->{$key}->{$value} = 'db';
 324       }
 325     }
 326   }
 327
 328   foreach my $entry (@{ $self->controller->data }) {
 329     if ( @{ $entry->{errors} } ) {
 330       next;
 331     }
 332
 333     my $object = $entry->{object};
 334
 335     foreach my $key (@duplicates_keys) {
 336       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 337
 338       if ( exists($duplicates->{$key}->{$value}) ) {
 339         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 340         last;
 341       } else {
 342         $duplicates->{$key}->{$value} = 'csv';
 343       }
 344
 345     }
 346   }
 347
 348 }
 349
 350 sub get_duplicate_check_fields {
 351   return {};
 352 }
 353
 354 sub check_payment {
 355   my ($self, $entry) = @_;
 356
 357   my $object = $entry->{object};
 358
 359   # Check whether or not payment ID is valid.
 360   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 361     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 362     return 0;
 363   }
 364
 365   # Map name to ID if given.
 366   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 367     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 368
 369     if (!$terms) {
 370       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 371       return 0;
 372     }
 373
 374     $object->payment_id($terms->id);
 375   }
 376
 377   return 1;
 378 }
 379
 380 sub save_objects {
 381   my ($self, %params) = @_;
 382
 383   my $data = $params{data} || $self->controller->data;
 384
 385   return unless $data->[0];
 386   return unless $data->[0]{object};
 387
 388   $self->controller->track_progress(phase => 'saving objects', progress => 0); # scale from 45..95%;
 389
 390   my $dbh = $data->[0]{object}->db;
 391
 392   $dbh->begin_work;
 393   foreach my $entry_index (0 .. $#$data) {
 394     my $entry = $data->[$entry_index];
 395     next if @{ $entry->{errors} };
 396
 397     my $object = $entry->{object_to_save} || $entry->{object};
 398
 399     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 400       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 401     } else {
 402       $self->controller->num_imported($self->controller->num_imported + 1);
 403     }
 404   } continue {
 405     if ($entry_index % 100 == 0) {
 406       $dbh->commit;
 407       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 408       $dbh->begin_work;
 409     }
 410   }
 411   $dbh->commit;
 412 }
 413
 414 sub field_lengths {
 415   return ();
 416 }
 417
 418 sub fix_field_lengths {
 419   my ($self) = @_;
 420
 421   my %field_lengths = $self->field_lengths;
 422   foreach my $entry (@{ $self->controller->data }) {
 423     next unless @{ $entry->{errors} };
 424     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 425   }
 426 }
 427
 428 1;
 429