SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(Rose::Object);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar                  => [ qw(controller file csv save_with_cascade) ],
  19  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  20 );
  21
  22 sub run {
  23   my ($self) = @_;
  24
  25   $self->controller->track_progress(0);
  26
  27   my $profile = $self->profile;
  28   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  29                                   encoding               => $self->controller->profile->get('charset'),
  30                                   class                  => $self->class,
  31                                   profile                => $profile,
  32                                   ignore_unknown_columns => 1,
  33                                   strict_profile         => 1,
  34                                   case_insensitive_header => 1,
  35                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  36                                  ));
  37
  38   $self->controller->track_progress(1);
  39
  40   my $old_numberformat      = $::myconfig{numberformat};
  41   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  42
  43   $self->csv->parse;
  44
  45   $self->controller->track_progress(3);
  46
  47   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  48
  49   return if ( !$self->csv->header || $self->csv->errors );
  50
  51   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  52   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  53   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  54   $self->controller->headers($headers);
  55   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  56   $self->controller->info_headers({ used => { }, headers => [ ] });
  57
  58   $::lxdebug->dump(0,  "self", $self->controller->info_headers);
  59   $::lxdebug->dump(0,  "self", $self->controller->headers);
  60   $::lxdebug->dump(0,  "self", $self->controller->raw_data_headers);
  61
  62   my @objects  = $self->csv->get_objects;
  63
  64   $self->controller->track_progress(4);
  65
  66   my @raw_data = @{ $self->csv->get_data };
  67
  68   $self->controller->track_progress(4.5);
  69
  70   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  71
  72   $self->controller->track_progress(5);
  73
  74   $self->check_objects;
  75   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  76     $self->check_std_duplicates();
  77     $self->check_duplicates();
  78   }
  79   $self->fix_field_lengths;
  80
  81   $self->controller->track_progress(99);
  82
  83   $::myconfig{numberformat} = $old_numberformat;
  84 }
  85
  86 sub add_columns {
  87   my ($self, @columns) = @_;
  88
  89   my $h = $self->controller->headers;
  90
  91   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  92     $h->{used}->{$column} = 1;
  93     push @{ $h->{methods} }, $column;
  94     push @{ $h->{headers} }, $column;
  95   }
  96 }
  97
  98 sub add_info_columns {
  99   my ($self, @columns) = @_;
 100
 101   my $h = $self->controller->info_headers;
 102
 103   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 104     $h->{used}->{ $column->{method} } = 1;
 105     push @{ $h->{methods} }, $column->{method};
 106     push @{ $h->{headers} }, $column->{header};
 107   }
 108 }
 109
 110 sub add_raw_data_columns {
 111   my ($self, @columns) = @_;
 112
 113   my $h = $self->controller->raw_data_headers;
 114
 115   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 116     $h->{used}->{$column} = 1;
 117     push @{ $h->{headers} }, $column;
 118   }
 119 }
 120
 121 sub add_cvar_raw_data_columns {
 122   my ($self) = @_;
 123
 124   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 125 }
 126
 127 sub init_cvar_columns {
 128   my ($self) = @_;
 129
 130   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 131 }
 132
 133 sub init_all_languages {
 134   my ($self) = @_;
 135
 136   return SL::DB::Manager::Language->get_all;
 137 }
 138
 139 sub init_payment_terms_by {
 140   my ($self) = @_;
 141
 142   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 143   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 144 }
 145
 146 sub init_all_vc {
 147   my ($self) = @_;
 148
 149   return { customers => SL::DB::Manager::Customer->get_all,
 150            vendors   => SL::DB::Manager::Vendor->get_all };
 151 }
 152
 153 sub init_vc_by {
 154   my ($self)    = @_;
 155
 156   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 157   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 158                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 159   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 160                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 161
 162   return { id     => \%by_id,
 163            number => \%by_number,
 164            name   => \%by_name,   };
 165 }
 166
 167 sub check_vc {
 168   my ($self, $entry, $id_column) = @_;
 169
 170   if ($entry->{object}->$id_column) {
 171     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 172   }
 173
 174   if (!$entry->{object}->$id_column) {
 175     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 176           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 177     $entry->{object}->$id_column($vc->id) if $vc;
 178   }
 179
 180   if (!$entry->{object}->$id_column) {
 181     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 182           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 183     $entry->{object}->$id_column($vc->id) if $vc;
 184   }
 185
 186   if ($entry->{object}->$id_column) {
 187     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 188   } else {
 189     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 190   }
 191 }
 192
 193 sub handle_cvars {
 194   my ($self, $entry) = @_;
 195
 196   return unless $self->can('all_cvar_configs');
 197
 198   my %type_to_column = ( text      => 'text_value',
 199                          textfield => 'text_value',
 200                          select    => 'text_value',
 201                          date      => 'timestamp_value_as_date',
 202                          timestamp => 'timestamp_value_as_date',
 203                          number    => 'number_value_as_number',
 204                          bool      => 'bool_value' );
 205
 206   my @cvars;
 207   foreach my $config (@{ $self->all_cvar_configs }) {
 208     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 209     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 210     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 211
 212     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 213   }
 214
 215   $entry->{object}->custom_variables(\@cvars);
 216 }
 217
 218 sub init_profile {
 219   my ($self) = @_;
 220
 221   eval "require " . $self->class;
 222
 223   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 224   my %profile;
 225   for my $col ($self->class->meta->columns) {
 226     next if $unwanted{$col};
 227
 228     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 229       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 230       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 231       :                                                                     $col->name;
 232
 233     $profile{$col} = $name;
 234   }
 235
 236   if ($self->can('all_cvar_configs')) {
 237     for (@{ $self->all_cvar_configs }) {
 238       $profile{ 'cvar_' . $_->name } = '';
 239     }
 240   }
 241
 242   $self->profile(\%profile);
 243 }
 244
 245 sub add_displayable_columns {
 246   my ($self, @columns) = @_;
 247
 248   my @cols       = @{ $self->controller->displayable_columns || [] };
 249   my %ex_col_map = map { $_->{name} => $_ } @cols;
 250
 251   foreach my $column (@columns) {
 252     if ($ex_col_map{ $column->{name} }) {
 253       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 254     } else {
 255       push @cols, $column;
 256     }
 257   }
 258
 259   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 260 }
 261
 262 sub setup_displayable_columns {
 263   my ($self) = @_;
 264
 265   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 266 }
 267
 268 sub add_cvar_columns_to_displayable_columns {
 269   my ($self) = @_;
 270
 271   return unless $self->can('all_cvar_configs');
 272
 273   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 274                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 275                                      @{ $self->all_cvar_configs });
 276 }
 277
 278 sub init_existing_objects {
 279   my ($self) = @_;
 280
 281   eval "require " . $self->class;
 282   $self->existing_objects($self->manager_class->get_all);
 283 }
 284
 285 sub init_class {
 286   die "class not set";
 287 }
 288
 289 sub init_manager_class {
 290   my ($self) = @_;
 291
 292   $self->class =~ m/^SL::DB::(.+)/;
 293   $self->manager_class("SL::DB::Manager::" . $1);
 294 }
 295
 296 sub check_objects {
 297 }
 298
 299 sub check_duplicates {
 300 }
 301
 302 sub check_std_duplicates {
 303   my $self = shift;
 304
 305   my $duplicates = {};
 306
 307   my $all_fields = $self->get_duplicate_check_fields();
 308
 309   foreach my $key (keys(%{ $all_fields })) {
 310     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 311       $duplicates->{$key} = {};
 312     }
 313   }
 314
 315   my @duplicates_keys = keys(%{ $duplicates });
 316
 317   if ( !scalar(@duplicates_keys) ) {
 318     return;
 319   }
 320
 321   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 322     foreach my $object (@{ $self->existing_objects }) {
 323       foreach my $key (@duplicates_keys) {
 324         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 325         $duplicates->{$key}->{$value} = 'db';
 326       }
 327     }
 328   }
 329
 330   foreach my $entry (@{ $self->controller->data }) {
 331     if ( @{ $entry->{errors} } ) {
 332       next;
 333     }
 334
 335     my $object = $entry->{object};
 336
 337     foreach my $key (@duplicates_keys) {
 338       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 339
 340       if ( exists($duplicates->{$key}->{$value}) ) {
 341         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 342         last;
 343       } else {
 344         $duplicates->{$key}->{$value} = 'csv';
 345       }
 346
 347     }
 348   }
 349
 350 }
 351
 352 sub get_duplicate_check_fields {
 353   return {};
 354 }
 355
 356 sub check_payment {
 357   my ($self, $entry) = @_;
 358
 359   my $object = $entry->{object};
 360
 361   # Check whether or not payment ID is valid.
 362   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 363     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 364     return 0;
 365   }
 366
 367   # Map name to ID if given.
 368   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 369     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 370
 371     if (!$terms) {
 372       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 373       return 0;
 374     }
 375
 376     $object->payment_id($terms->id);
 377   }
 378
 379   return 1;
 380 }
 381
 382 sub save_objects {
 383   my ($self, %params) = @_;
 384
 385   my $data = $params{data} || $self->controller->data;
 386
 387   return unless $data->[0];
 388   return unless $data->[0]{object};
 389
 390   my $dbh = $data->[0]{object}->db;
 391
 392   $dbh->begin_work;
 393   foreach my $entry_index (0 .. $#$data) {
 394     my $entry = $data->[$entry_index];
 395     next if @{ $entry->{errors} };
 396
 397     my $object = $entry->{object_to_save} || $entry->{object};
 398
 399     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 400       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 401     } else {
 402       $self->controller->num_imported($self->controller->num_imported + 1);
 403     }
 404   } continue {
 405     if ($entry_index % 100 == 0) {
 406       $dbh->commit;
 407       $self->controller->track_progress(45 + $entry_index/scalar(@$data) * 50); # scale from 45..95%;
 408       $dbh->begin_work;
 409     }
 410   }
 411   $dbh->commit;
 412 }
 413
 414 sub field_lengths {
 415   return ();
 416 }
 417
 418 sub fix_field_lengths {
 419   my ($self) = @_;
 420
 421   my %field_lengths = $self->field_lengths;
 422   foreach my $entry (@{ $self->controller->data }) {
 423     next unless @{ $entry->{errors} };
 424     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 425   }
 426 }
 427
 428 1;
 429