SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise any);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::DeliveryTerm;
  12 use SL::DB::Vendor;
  13 use SL::DB::Contact;
  14 use SL::DB::History;
  15
  16 use parent qw(Rose::Object);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  21  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_vc vc_by clone_methods) ],
  22 );
  23
  24 sub run {
  25   my ($self, %params) = @_;
  26
  27   $self->test_run($params{test});
  28
  29   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  30
  31   my $profile = $self->profile;
  32   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  33                                   encoding               => $self->controller->profile->get('charset'),
  34                                   profile                => [{ profile => $profile, class => $self->class }],
  35                                   ignore_unknown_columns => 1,
  36                                   strict_profile         => 1,
  37                                   case_insensitive_header => 1,
  38                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  39                                  ));
  40
  41   $self->controller->track_progress(progress => 10);
  42
  43   my $old_numberformat      = $::myconfig{numberformat};
  44   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  45
  46   $self->csv->parse;
  47
  48   $self->controller->track_progress(progress => 50);
  49
  50   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  51
  52   return if ( !$self->csv->header || $self->csv->errors );
  53
  54   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  55   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  56   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  57   $self->controller->headers($headers);
  58   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  59   $self->controller->info_headers({ used => { }, headers => [ ] });
  60
  61   my @objects  = $self->csv->get_objects;
  62
  63   $self->controller->track_progress(progress => 70);
  64
  65   my @raw_data = @{ $self->csv->get_data };
  66
  67   $self->controller->track_progress(progress => 80);
  68
  69   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  70
  71   $self->controller->track_progress(progress => 90);
  72
  73   $self->check_objects;
  74   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  75     $self->check_std_duplicates();
  76     $self->check_duplicates();
  77   }
  78   $self->fix_field_lengths;
  79
  80   $self->controller->track_progress(progress => 100);
  81
  82   $::myconfig{numberformat} = $old_numberformat;
  83 }
  84
  85 sub add_columns {
  86   my ($self, @columns) = @_;
  87
  88   my $h = $self->controller->headers;
  89
  90   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  91     $h->{used}->{$column} = 1;
  92     push @{ $h->{methods} }, $column;
  93     push @{ $h->{headers} }, $column;
  94   }
  95 }
  96
  97 sub add_info_columns {
  98   my ($self, @columns) = @_;
  99
 100   my $h = $self->controller->info_headers;
 101
 102   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 103     $h->{used}->{ $column->{method} } = 1;
 104     push @{ $h->{methods} }, $column->{method};
 105     push @{ $h->{headers} }, $column->{header};
 106   }
 107 }
 108
 109 sub add_raw_data_columns {
 110   my ($self, @columns) = @_;
 111
 112   my $h = $self->controller->raw_data_headers;
 113
 114   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 115     $h->{used}->{$column} = 1;
 116     push @{ $h->{headers} }, $column;
 117   }
 118 }
 119
 120 sub add_cvar_raw_data_columns {
 121   my ($self) = @_;
 122
 123   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 124 }
 125
 126 sub init_all_cvar_configs {
 127   # Must be overridden by derived specialized importer classes.
 128   return [];
 129 }
 130
 131 sub init_cvar_columns {
 132   my ($self) = @_;
 133
 134   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 135 }
 136
 137 sub init_all_languages {
 138   my ($self) = @_;
 139
 140   return SL::DB::Manager::Language->get_all;
 141 }
 142
 143 sub init_payment_terms_by {
 144   my ($self) = @_;
 145
 146   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 147   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 148 }
 149
 150 sub init_delivery_terms_by {
 151   my ($self) = @_;
 152
 153   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 154   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 155 }
 156
 157 sub init_all_vc {
 158   my ($self) = @_;
 159
 160   return { customers => SL::DB::Manager::Customer->get_all,
 161            vendors   => SL::DB::Manager::Vendor->get_all };
 162 }
 163
 164 sub init_clone_methods {
 165   {}
 166 }
 167
 168 sub force_allow_columns {
 169   return ();
 170 }
 171
 172 sub init_vc_by {
 173   my ($self)    = @_;
 174
 175   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 176   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 177                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 178   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 179                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 180
 181   return { id     => \%by_id,
 182            number => \%by_number,
 183            name   => \%by_name,   };
 184 }
 185
 186 sub check_vc {
 187   my ($self, $entry, $id_column) = @_;
 188
 189   if ($entry->{object}->$id_column) {
 190     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 191   }
 192
 193   if (!$entry->{object}->$id_column) {
 194     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 195           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 196     $entry->{object}->$id_column($vc->id) if $vc;
 197   }
 198
 199   if (!$entry->{object}->$id_column) {
 200     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 201           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 202     $entry->{object}->$id_column($vc->id) if $vc;
 203   }
 204
 205   if ($entry->{object}->$id_column) {
 206     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 207   } else {
 208     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 209   }
 210 }
 211
 212 sub handle_cvars {
 213   my ($self, $entry) = @_;
 214
 215   my %type_to_column = ( text      => 'text_value',
 216                          textfield => 'text_value',
 217                          select    => 'text_value',
 218                          date      => 'timestamp_value_as_date',
 219                          timestamp => 'timestamp_value_as_date',
 220                          number    => 'number_value_as_number',
 221                          bool      => 'bool_value' );
 222
 223   my @cvars;
 224   foreach my $config (@{ $self->all_cvar_configs }) {
 225     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 226     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 227     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 228
 229     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 230   }
 231
 232   $entry->{object}->custom_variables(\@cvars);
 233 }
 234
 235 sub init_profile {
 236   my ($self) = @_;
 237
 238   eval "require " . $self->class;
 239
 240   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 241   delete $unwanted{$_} for ($self->force_allow_columns);
 242
 243   my %profile;
 244   for my $col ($self->class->meta->columns) {
 245     next if $unwanted{$col};
 246
 247     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 248       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 249       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 250       :                                                                     $col->name;
 251
 252     $profile{$col} = $name;
 253   }
 254
 255   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 256
 257   \%profile;
 258 }
 259
 260 sub add_displayable_columns {
 261   my ($self, @columns) = @_;
 262
 263   my @cols       = @{ $self->controller->displayable_columns || [] };
 264   my %ex_col_map = map { $_->{name} => $_ } @cols;
 265
 266   foreach my $column (@columns) {
 267     if ($ex_col_map{ $column->{name} }) {
 268       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 269     } else {
 270       push @cols, $column;
 271     }
 272   }
 273
 274   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 275 }
 276
 277 sub setup_displayable_columns {
 278   my ($self) = @_;
 279
 280   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 281 }
 282
 283 sub add_cvar_columns_to_displayable_columns {
 284   my ($self) = @_;
 285
 286   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 287                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 288                                      @{ $self->all_cvar_configs });
 289 }
 290
 291 sub init_existing_objects {
 292   my ($self) = @_;
 293
 294   eval "require " . $self->class;
 295   $self->existing_objects($self->manager_class->get_all);
 296 }
 297
 298 sub init_class {
 299   die "class not set";
 300 }
 301
 302 sub init_manager_class {
 303   my ($self) = @_;
 304
 305   $self->class =~ m/^SL::DB::(.+)/;
 306   $self->manager_class("SL::DB::Manager::" . $1);
 307 }
 308
 309 sub is_multiplexed { 0 }
 310
 311 sub check_objects {
 312 }
 313
 314 sub check_duplicates {
 315 }
 316
 317 sub check_std_duplicates {
 318   my $self = shift;
 319
 320   my $duplicates = {};
 321
 322   my $all_fields = $self->get_duplicate_check_fields();
 323
 324   foreach my $key (keys(%{ $all_fields })) {
 325     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 326       $duplicates->{$key} = {};
 327     }
 328   }
 329
 330   my @duplicates_keys = keys(%{ $duplicates });
 331
 332   if ( !scalar(@duplicates_keys) ) {
 333     return;
 334   }
 335
 336   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 337     foreach my $object (@{ $self->existing_objects }) {
 338       foreach my $key (@duplicates_keys) {
 339         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 340         $duplicates->{$key}->{$value} = 'db';
 341       }
 342     }
 343   }
 344
 345   foreach my $entry (@{ $self->controller->data }) {
 346     if ( @{ $entry->{errors} } ) {
 347       next;
 348     }
 349
 350     my $object = $entry->{object};
 351
 352     foreach my $key (@duplicates_keys) {
 353       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 354
 355       if ( exists($duplicates->{$key}->{$value}) ) {
 356         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 357         last;
 358       } else {
 359         $duplicates->{$key}->{$value} = 'csv';
 360       }
 361
 362     }
 363   }
 364
 365 }
 366
 367 sub get_duplicate_check_fields {
 368   return {};
 369 }
 370
 371 sub check_payment {
 372   my ($self, $entry) = @_;
 373
 374   my $object = $entry->{object};
 375
 376   # Check whether or not payment ID is valid.
 377   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 378     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 379     return 0;
 380   }
 381
 382   # Map name to ID if given.
 383   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 384     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 385
 386     if (!$terms) {
 387       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 388       return 0;
 389     }
 390
 391     $object->payment_id($terms->id);
 392
 393     # register payment_id for method copying later
 394     $self->clone_methods->{payment_id} = 1;
 395   }
 396
 397   return 1;
 398 }
 399
 400 sub check_delivery_term {
 401   my ($self, $entry) = @_;
 402
 403   my $object = $entry->{object};
 404
 405   # Check whether or not delivery term ID is valid.
 406   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 407     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 408     return 0;
 409   }
 410
 411   # Map name to ID if given.
 412   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 413     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 414
 415     if (!$terms) {
 416       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 417       return 0;
 418     }
 419
 420     $object->delivery_term_id($terms->id);
 421
 422     # register delivery_term_id for method copying later
 423     $self->clone_methods->{delivery_term_id} = 1;
 424   }
 425
 426   return 1;
 427 }
 428
 429 sub save_objects {
 430   my ($self, %params) = @_;
 431
 432   my $data = $params{data} || $self->controller->data;
 433
 434   return unless $data->[0];
 435   return unless $data->[0]{object};
 436
 437   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 438
 439   my $dbh = $data->[0]{object}->db;
 440
 441   $dbh->begin_work;
 442   foreach my $entry_index (0 .. $#$data) {
 443     my $entry = $data->[$entry_index];
 444     next if @{ $entry->{errors} };
 445
 446     my $object = $entry->{object_to_save} || $entry->{object};
 447
 448     my $ret;
 449     if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 450       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $@);
 451     } elsif ( !$ret ) {
 452       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 453     } else {
 454       $self->_save_history($object);
 455       $self->controller->num_imported($self->controller->num_imported + 1);
 456     }
 457   } continue {
 458     if ($entry_index % 100 == 0) {
 459       $dbh->commit;
 460       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 461       $dbh->begin_work;
 462     }
 463   }
 464   $dbh->commit;
 465 }
 466
 467 sub field_lengths {
 468   my ($self) = @_;
 469
 470   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 471 }
 472
 473 sub fix_field_lengths {
 474   my ($self) = @_;
 475
 476   my %field_lengths = $self->field_lengths;
 477   foreach my $entry (@{ $self->controller->data }) {
 478     next unless @{ $entry->{errors} };
 479     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 480   }
 481 }
 482
 483 sub clean_fields {
 484   my ($self, $illegal_chars, $object, @fields) = @_;
 485
 486   my @cleaned_fields;
 487   foreach my $field (grep { $object->can($_) } @fields) {
 488     my $value = $object->$field;
 489
 490     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 491
 492     $object->$field($value);
 493     push @cleaned_fields, $field;
 494   }
 495
 496   return @cleaned_fields;
 497 }
 498
 499 sub _save_history {
 500   my ($self, $object) = @_;
 501
 502   if (any { $_ eq $self->controller->{type} } qw(parts customers_vendors orders)) {
 503     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 504                  : $self->controller->{type} eq 'customers_vendors' ?
 505                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 506                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 507                  : '';
 508
 509     my $what_done = $self->controller->{type} eq 'orders' ? 'sales_order'
 510                   : '';
 511
 512     SL::DB::History->new(
 513       trans_id    => $object->id,
 514       snumbers    => $snumbers,
 515       employee_id => $self->controller->{employee_id},
 516       addition    => 'SAVED',
 517       what_done   => $what_done,
 518     )->save();
 519   }
 520 }
 521
 522 1;