SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(Rose::Object);
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13  scalar                  => [ qw(controller file csv) ],
  14  'scalar --get_set_init' => [ qw(profile existing_objects class manager_class cvar_columns all_cvar_configs) ],
  15 );
  16
  17 sub run {
  18   my ($self) = @_;
  19
  20   my $profile = $self->profile;
  21   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  22                                   encoding               => $self->controller->profile->get('charset'),
  23                                   class                  => $self->class,
  24                                   profile                => $profile,
  25                                   ignore_unknown_columns => 1,
  26                                   strict_profile         => 1,
  27                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  28                                  ));
  29   $self->csv->parse;
  30
  31   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  32
  33   return unless $self->csv->header;
  34
  35   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  36   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  37   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  38   $self->controller->headers($headers);
  39   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  40
  41   # my @data;
  42   # foreach my $object ($self->csv->get_objects)
  43   my @objects  = $self->csv->get_objects;
  44   my @raw_data = @{ $self->csv->get_data };
  45   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [] } } @objects, @raw_data ]);
  46
  47   $self->check_objects;
  48   $self->check_duplicates if $self->controller->profile->get('duplicates', 'no_check') ne 'no_check';
  49   $self->fix_field_lenghts;
  50 }
  51
  52 sub add_columns {
  53   my ($self, @columns) = @_;
  54
  55   my $h = $self->controller->headers;
  56
  57   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  58     $h->{used}->{$column} = 1;
  59     push @{ $h->{methods} }, $column;
  60     push @{ $h->{headers} }, $column;
  61   }
  62 }
  63
  64 sub add_raw_data_columns {
  65   my ($self, @columns) = @_;
  66
  67   my $h = $self->controller->raw_data_headers;
  68
  69   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  70     $h->{used}->{$column} = 1;
  71     push @{ $h->{headers} }, $column;
  72   }
  73 }
  74
  75 sub add_cvar_raw_data_columns {
  76   my ($self) = @_;
  77
  78   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
  79 }
  80
  81 sub init_cvar_columns {
  82   my ($self) = @_;
  83
  84   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
  85 }
  86
  87 sub handle_cvars {
  88   my ($self, $entry) = @_;
  89
  90   return unless $self->can('all_cvar_configs');
  91
  92   my %type_to_column = ( text      => 'text_value',
  93                          textfield => 'text_value',
  94                          select    => 'text_value',
  95                          date      => 'timestamp_value_as_date',
  96                          timestamp => 'timestamp_value_as_date',
  97                          number    => 'number_value_as_number',
  98                          bool      => 'bool_value' );
  99
 100   my @cvars;
 101   foreach my $config (@{ $self->all_cvar_configs }) {
 102     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 103     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 104     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 105
 106     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value);
 107   }
 108
 109   $entry->{object}->custom_variables(\@cvars);
 110 }
 111
 112 sub init_profile {
 113   my ($self) = @_;
 114
 115   eval "require " . $self->class;
 116
 117   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 118   my %profile;
 119   for my $col ($self->class->meta->columns) {
 120     next if $unwanted{$col};
 121
 122     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 123       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 124       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 125       :                                                                     $col->name;
 126
 127     $profile{$col} = $name;
 128   }
 129
 130   $self->profile(\%profile);
 131 }
 132
 133 sub init_existing_objects {
 134   my ($self) = @_;
 135
 136   eval "require " . $self->class;
 137   $self->existing_objects($self->manager_class->get_all);
 138 }
 139
 140 sub init_class {
 141   die "class not set";
 142 }
 143
 144 sub init_manager_class {
 145   my ($self) = @_;
 146
 147   $self->class =~ m/^SL::DB::(.+)/;
 148   $self->manager_class("SL::DB::Manager::" . $1);
 149 }
 150
 151 sub check_objects {
 152 }
 153
 154 sub check_duplicates {
 155 }
 156
 157 sub save_objects {
 158   my ($self, %params) = @_;
 159
 160   my $data = $params{data} || $self->controller->data;
 161
 162   foreach my $entry (@{ $data }) {
 163     next if @{ $entry->{errors} };
 164
 165     if (!$entry->{object}->save) {
 166       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 167     } else {
 168       $self->controller->num_imported($self->controller->num_imported + 1);
 169     }
 170   }
 171 }
 172
 173 sub field_lengths {
 174   return ();
 175 }
 176
 177 sub fix_field_lenghts {
 178   my ($self) = @_;
 179
 180   my %field_lengths = $self->field_lengths;
 181   foreach my $entry (@{ $self->controller->data }) {
 182     next unless @{ $entry->{errors} };
 183     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 184   }
 185 }
 186
 187 1;