SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12
  13 use parent qw(Rose::Object);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  scalar                  => [ qw(controller file csv) ],
  18  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  19 );
  20
  21 sub run {
  22   my ($self) = @_;
  23
  24   my $profile = $self->profile;
  25   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  26                                   encoding               => $self->controller->profile->get('charset'),
  27                                   class                  => $self->class,
  28                                   profile                => $profile,
  29                                   ignore_unknown_columns => 1,
  30                                   strict_profile         => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33   $self->csv->parse;
  34
  35   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  36
  37   return unless $self->csv->header;
  38
  39   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  40   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  41   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  42   $self->controller->headers($headers);
  43   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  44   $self->controller->info_headers({ used => { }, headers => [ ] });
  45
  46   my @objects  = $self->csv->get_objects;
  47   my @raw_data = @{ $self->csv->get_data };
  48   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  49
  50   $self->check_objects;
  51   $self->check_duplicates if $self->controller->profile->get('duplicates', 'no_check') ne 'no_check';
  52   $self->fix_field_lengths;
  53 }
  54
  55 sub add_columns {
  56   my ($self, @columns) = @_;
  57
  58   my $h = $self->controller->headers;
  59
  60   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  61     $h->{used}->{$column} = 1;
  62     push @{ $h->{methods} }, $column;
  63     push @{ $h->{headers} }, $column;
  64   }
  65 }
  66
  67 sub add_info_columns {
  68   my ($self, @columns) = @_;
  69
  70   my $h = $self->controller->info_headers;
  71
  72   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
  73     $h->{used}->{ $column->{method} } = 1;
  74     push @{ $h->{methods} }, $column->{method};
  75     push @{ $h->{headers} }, $column->{header};
  76   }
  77 }
  78
  79 sub add_raw_data_columns {
  80   my ($self, @columns) = @_;
  81
  82   my $h = $self->controller->raw_data_headers;
  83
  84   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  85     $h->{used}->{$column} = 1;
  86     push @{ $h->{headers} }, $column;
  87   }
  88 }
  89
  90 sub add_cvar_raw_data_columns {
  91   my ($self) = @_;
  92
  93   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
  94 }
  95
  96 sub init_cvar_columns {
  97   my ($self) = @_;
  98
  99   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 100 }
 101
 102 sub init_all_languages {
 103   my ($self) = @_;
 104
 105   return SL::DB::Manager::Language->get_all;
 106 }
 107
 108 sub init_payment_terms_by {
 109   my ($self) = @_;
 110
 111   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 112   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 113 }
 114
 115 sub init_all_vc {
 116   my ($self) = @_;
 117
 118   return { customers => SL::DB::Manager::Customer->get_all,
 119            vendors   => SL::DB::Manager::Vendor->get_all };
 120 }
 121
 122 sub init_vc_by {
 123   my ($self)    = @_;
 124
 125   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 126   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 127                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 128   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 129                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 130
 131   return { id     => \%by_id,
 132            number => \%by_number,
 133            name   => \%by_name,   };
 134 }
 135
 136 sub check_vc {
 137   my ($self, $entry, $id_column) = @_;
 138
 139   if ($entry->{object}->$id_column) {
 140     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 141   }
 142
 143   if (!$entry->{object}->$id_column) {
 144     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 145           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 146     $entry->{object}->$id_column($vc->id) if $vc;
 147   }
 148
 149   if (!$entry->{object}->$id_column) {
 150     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 151           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 152     $entry->{object}->$id_column($vc->id) if $vc;
 153   }
 154
 155   if ($entry->{object}->$id_column) {
 156     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 157   } else {
 158     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 159   }
 160 }
 161
 162 sub handle_cvars {
 163   my ($self, $entry) = @_;
 164
 165   return unless $self->can('all_cvar_configs');
 166
 167   my %type_to_column = ( text      => 'text_value',
 168                          textfield => 'text_value',
 169                          select    => 'text_value',
 170                          date      => 'timestamp_value_as_date',
 171                          timestamp => 'timestamp_value_as_date',
 172                          number    => 'number_value_as_number',
 173                          bool      => 'bool_value' );
 174
 175   my @cvars;
 176   foreach my $config (@{ $self->all_cvar_configs }) {
 177     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 178     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 179     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 180
 181     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value);
 182   }
 183
 184   $entry->{object}->custom_variables(\@cvars);
 185 }
 186
 187 sub init_profile {
 188   my ($self) = @_;
 189
 190   eval "require " . $self->class;
 191
 192   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 193   my %profile;
 194   for my $col ($self->class->meta->columns) {
 195     next if $unwanted{$col};
 196
 197     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 198       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 199       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 200       :                                                                     $col->name;
 201
 202     $profile{$col} = $name;
 203   }
 204
 205   $self->profile(\%profile);
 206 }
 207
 208 sub add_displayable_columns {
 209   my ($self, @columns) = @_;
 210
 211   my @cols       = @{ $self->controller->displayable_columns || [] };
 212   my %ex_col_map = map { $_->{name} => $_ } @cols;
 213
 214   foreach my $column (@columns) {
 215     if ($ex_col_map{ $column->{name} }) {
 216       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 217     } else {
 218       push @cols, $column;
 219     }
 220   }
 221
 222   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 223 }
 224
 225 sub setup_displayable_columns {
 226   my ($self) = @_;
 227
 228   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 229 }
 230
 231 sub add_cvar_columns_to_displayable_columns {
 232   my ($self) = @_;
 233
 234   return unless $self->can('all_cvar_configs');
 235
 236   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 237                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 238                                      @{ $self->all_cvar_configs });
 239 }
 240
 241 sub init_existing_objects {
 242   my ($self) = @_;
 243
 244   eval "require " . $self->class;
 245   $self->existing_objects($self->manager_class->get_all);
 246 }
 247
 248 sub init_class {
 249   die "class not set";
 250 }
 251
 252 sub init_manager_class {
 253   my ($self) = @_;
 254
 255   $self->class =~ m/^SL::DB::(.+)/;
 256   $self->manager_class("SL::DB::Manager::" . $1);
 257 }
 258
 259 sub check_objects {
 260 }
 261
 262 sub check_duplicates {
 263 }
 264
 265 sub check_payment {
 266   my ($self, $entry) = @_;
 267
 268   my $object = $entry->{object};
 269
 270   # Check whether or not payment ID is valid.
 271   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 272     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 273     return 0;
 274   }
 275
 276   # Map name to ID if given.
 277   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 278     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 279
 280     if (!$terms) {
 281       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 282       return 0;
 283     }
 284
 285     $object->payment_id($terms->id);
 286   }
 287
 288   return 1;
 289 }
 290
 291 sub save_objects {
 292   my ($self, %params) = @_;
 293
 294   my $data = $params{data} || $self->controller->data;
 295
 296   foreach my $entry (@{ $data }) {
 297     next if @{ $entry->{errors} };
 298
 299     my $object = $entry->{object_to_save} || $entry->{object};
 300
 301     if (!$object->save) {
 302       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 303     } else {
 304       $self->controller->num_imported($self->controller->num_imported + 1);
 305     }
 306   }
 307 }
 308
 309 sub field_lengths {
 310   return ();
 311 }
 312
 313 sub fix_field_lengths {
 314   my ($self) = @_;
 315
 316   my %field_lengths = $self->field_lengths;
 317   foreach my $entry (@{ $self->controller->data }) {
 318     next unless @{ $entry->{errors} };
 319     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 320   }
 321 }
 322
 323 1;