SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise any);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Currency;
   9 use SL::DB::Customer;
  10 use SL::DB::Language;
  11 use SL::DB::PaymentTerm;
  12 use SL::DB::Vendor;
  13 use SL::DB::Contact;
  14 use SL::DB::History;
  15
  16 use parent qw(Rose::Object);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  21  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_currencies default_currency_id all_vc vc_by) ],
  22 );
  23
  24 sub run {
  25   my ($self, %params) = @_;
  26
  27   $self->test_run($params{test_run});
  28
  29   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  30
  31   my $profile = $self->profile;
  32   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  33                                   encoding               => $self->controller->profile->get('charset'),
  34                                   profile                => [{ profile => $profile, class => $self->class }],
  35                                   ignore_unknown_columns => 1,
  36                                   strict_profile         => 1,
  37                                   case_insensitive_header => 1,
  38                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  39                                  ));
  40
  41   $self->controller->track_progress(progress => 10);
  42
  43   my $old_numberformat      = $::myconfig{numberformat};
  44   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  45
  46   $self->csv->parse;
  47
  48   $self->controller->track_progress(progress => 50);
  49
  50   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  51
  52   return if ( !$self->csv->header || $self->csv->errors );
  53
  54   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header->[0] } ] };
  55   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  56   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  57   $self->controller->headers($headers);
  58   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  59   $self->controller->info_headers({ used => { }, headers => [ ] });
  60
  61   my @objects  = $self->csv->get_objects;
  62
  63   $self->controller->track_progress(progress => 70);
  64
  65   my @raw_data = @{ $self->csv->get_data };
  66
  67   $self->controller->track_progress(progress => 80);
  68
  69   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  70
  71   $self->controller->track_progress(progress => 90);
  72
  73   $self->check_objects;
  74   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  75     $self->check_std_duplicates();
  76     $self->check_duplicates();
  77   }
  78   $self->fix_field_lengths;
  79
  80   $self->controller->track_progress(progress => 100);
  81
  82   $::myconfig{numberformat} = $old_numberformat;
  83 }
  84
  85 sub add_columns {
  86   my ($self, @columns) = @_;
  87
  88   my $h = $self->controller->headers;
  89
  90   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  91     $h->{used}->{$column} = 1;
  92     push @{ $h->{methods} }, $column;
  93     push @{ $h->{headers} }, $column;
  94   }
  95 }
  96
  97 sub add_info_columns {
  98   my ($self, @columns) = @_;
  99
 100   my $h = $self->controller->info_headers;
 101
 102   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 103     $h->{used}->{ $column->{method} } = 1;
 104     push @{ $h->{methods} }, $column->{method};
 105     push @{ $h->{headers} }, $column->{header};
 106   }
 107 }
 108
 109 sub add_raw_data_columns {
 110   my ($self, @columns) = @_;
 111
 112   my $h = $self->controller->raw_data_headers;
 113
 114   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 115     $h->{used}->{$column} = 1;
 116     push @{ $h->{headers} }, $column;
 117   }
 118 }
 119
 120 sub add_cvar_raw_data_columns {
 121   my ($self) = @_;
 122
 123   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 124 }
 125
 126 sub init_all_cvar_configs {
 127   # Must be overridden by derived specialized importer classes.
 128   return [];
 129 }
 130
 131 sub init_cvar_columns {
 132   my ($self) = @_;
 133
 134   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 135 }
 136
 137 sub init_all_languages {
 138   my ($self) = @_;
 139
 140   return SL::DB::Manager::Language->get_all;
 141 }
 142
 143 sub init_all_currencies {
 144   my ($self) = @_;
 145
 146   return SL::DB::Manager::Currency->get_all;
 147 }
 148
 149 sub init_default_currency_id {
 150   my ($self) = @_;
 151
 152   return SL::DB::Default->get->currency_id;
 153 }
 154
 155 sub init_payment_terms_by {
 156   my ($self) = @_;
 157
 158   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 159   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 160 }
 161
 162 sub init_all_vc {
 163   my ($self) = @_;
 164
 165   return { customers => SL::DB::Manager::Customer->get_all,
 166            vendors   => SL::DB::Manager::Vendor->get_all };
 167 }
 168
 169 sub force_allow_columns {
 170   return ();
 171 }
 172
 173 sub init_vc_by {
 174   my ($self)    = @_;
 175
 176   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 177   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 178                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 179   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 180                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 181
 182   return { id     => \%by_id,
 183            number => \%by_number,
 184            name   => \%by_name,   };
 185 }
 186
 187 sub check_vc {
 188   my ($self, $entry, $id_column) = @_;
 189
 190   if ($entry->{object}->$id_column) {
 191     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 192   }
 193
 194   if (!$entry->{object}->$id_column) {
 195     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 196           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 197     $entry->{object}->$id_column($vc->id) if $vc;
 198   }
 199
 200   if (!$entry->{object}->$id_column) {
 201     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 202           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 203     $entry->{object}->$id_column($vc->id) if $vc;
 204   }
 205
 206   if ($entry->{object}->$id_column) {
 207     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 208   } else {
 209     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 210   }
 211 }
 212
 213 sub handle_cvars {
 214   my ($self, $entry) = @_;
 215
 216   my %type_to_column = ( text      => 'text_value',
 217                          textfield => 'text_value',
 218                          select    => 'text_value',
 219                          date      => 'timestamp_value_as_date',
 220                          timestamp => 'timestamp_value_as_date',
 221                          number    => 'number_value_as_number',
 222                          bool      => 'bool_value' );
 223
 224   my @cvars;
 225   foreach my $config (@{ $self->all_cvar_configs }) {
 226     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 227     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 228     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 229
 230     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 231   }
 232
 233   $entry->{object}->custom_variables(\@cvars);
 234 }
 235
 236 sub init_profile {
 237   my ($self) = @_;
 238
 239   eval "require " . $self->class;
 240
 241   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 242   delete $unwanted{$_} for ($self->force_allow_columns);
 243
 244   my %profile;
 245   for my $col ($self->class->meta->columns) {
 246     next if $unwanted{$col};
 247
 248     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 249       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 250       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 251       :                                                                     $col->name;
 252
 253     $profile{$col} = $name;
 254   }
 255
 256   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 257
 258   \%profile;
 259 }
 260
 261 sub add_displayable_columns {
 262   my ($self, @columns) = @_;
 263
 264   my @cols       = @{ $self->controller->displayable_columns || [] };
 265   my %ex_col_map = map { $_->{name} => $_ } @cols;
 266
 267   foreach my $column (@columns) {
 268     if ($ex_col_map{ $column->{name} }) {
 269       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 270     } else {
 271       push @cols, $column;
 272     }
 273   }
 274
 275   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 276 }
 277
 278 sub setup_displayable_columns {
 279   my ($self) = @_;
 280
 281   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 282 }
 283
 284 sub add_cvar_columns_to_displayable_columns {
 285   my ($self) = @_;
 286
 287   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 288                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 289                                      @{ $self->all_cvar_configs });
 290 }
 291
 292 sub init_existing_objects {
 293   my ($self) = @_;
 294
 295   eval "require " . $self->class;
 296   $self->existing_objects($self->manager_class->get_all);
 297 }
 298
 299 sub init_class {
 300   die "class not set";
 301 }
 302
 303 sub init_manager_class {
 304   my ($self) = @_;
 305
 306   $self->class =~ m/^SL::DB::(.+)/;
 307   $self->manager_class("SL::DB::Manager::" . $1);
 308 }
 309
 310 sub is_multiplexed { 0 }
 311
 312 sub check_objects {
 313 }
 314
 315 sub check_duplicates {
 316 }
 317
 318 sub check_std_duplicates {
 319   my $self = shift;
 320
 321   my $duplicates = {};
 322
 323   my $all_fields = $self->get_duplicate_check_fields();
 324
 325   foreach my $key (keys(%{ $all_fields })) {
 326     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 327       $duplicates->{$key} = {};
 328     }
 329   }
 330
 331   my @duplicates_keys = keys(%{ $duplicates });
 332
 333   if ( !scalar(@duplicates_keys) ) {
 334     return;
 335   }
 336
 337   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 338     foreach my $object (@{ $self->existing_objects }) {
 339       foreach my $key (@duplicates_keys) {
 340         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 341         $duplicates->{$key}->{$value} = 'db';
 342       }
 343     }
 344   }
 345
 346   foreach my $entry (@{ $self->controller->data }) {
 347     if ( @{ $entry->{errors} } ) {
 348       next;
 349     }
 350
 351     my $object = $entry->{object};
 352
 353     foreach my $key (@duplicates_keys) {
 354       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 355
 356       if ( exists($duplicates->{$key}->{$value}) ) {
 357         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 358         last;
 359       } else {
 360         $duplicates->{$key}->{$value} = 'csv';
 361       }
 362
 363     }
 364   }
 365
 366 }
 367
 368 sub get_duplicate_check_fields {
 369   return {};
 370 }
 371
 372 sub check_payment {
 373   my ($self, $entry) = @_;
 374
 375   my $object = $entry->{object};
 376
 377   # Check whether or not payment ID is valid.
 378   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 379     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 380     return 0;
 381   }
 382
 383   # Map name to ID if given.
 384   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 385     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 386
 387     if (!$terms) {
 388       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 389       return 0;
 390     }
 391
 392     $object->payment_id($terms->id);
 393   }
 394
 395   return 1;
 396 }
 397
 398 sub save_objects {
 399   my ($self, %params) = @_;
 400
 401   my $data = $params{data} || $self->controller->data;
 402
 403   return unless $data->[0];
 404   return unless $data->[0]{object};
 405
 406   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 407
 408   my $dbh = $data->[0]{object}->db;
 409
 410   $dbh->begin_work;
 411   foreach my $entry_index (0 .. $#$data) {
 412     my $entry = $data->[$entry_index];
 413     next if @{ $entry->{errors} };
 414
 415     my $object = $entry->{object_to_save} || $entry->{object};
 416
 417     my $ret;
 418     if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 419       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $@);
 420     } elsif ( !$ret ) {
 421       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 422     } else {
 423       $self->_save_history($object);
 424       $self->controller->num_imported($self->controller->num_imported + 1);
 425     }
 426   } continue {
 427     if ($entry_index % 100 == 0) {
 428       $dbh->commit;
 429       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 430       $dbh->begin_work;
 431     }
 432   }
 433   $dbh->commit;
 434 }
 435
 436 sub field_lengths {
 437   return ();
 438 }
 439
 440 sub fix_field_lengths {
 441   my ($self) = @_;
 442
 443   my %field_lengths = $self->field_lengths;
 444   foreach my $entry (@{ $self->controller->data }) {
 445     next unless @{ $entry->{errors} };
 446     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 447   }
 448 }
 449
 450 sub clean_fields {
 451   my ($self, $illegal_chars, $object, @fields) = @_;
 452
 453   my @cleaned_fields;
 454   foreach my $field (grep { $object->can($_) } @fields) {
 455     my $value = $object->$field;
 456
 457     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 458
 459     $object->$field($value);
 460     push @cleaned_fields, $field;
 461   }
 462
 463   return @cleaned_fields;
 464 }
 465
 466 sub _save_history {
 467   my ($self, $object) = @_;
 468
 469   if (any { $_ eq $self->controller->{type} } qw(parts customers_vendors)) {
 470     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 471                  : $self->controller->{type} eq 'customers_vendors' ?
 472                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 473                  : '';
 474
 475     SL::DB::History->new(
 476       trans_id    => $object->id,
 477       snumbers    => $snumbers,
 478       employee_id => $self->controller->{employee_id},
 479       addition    => 'SAVED',
 480     )->save();
 481   }
 482 }
 483
 484 1;