SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by vc_counts_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   my $old_numberformat      = $::myconfig{numberformat};
  49   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86
  87   $::myconfig{numberformat} = $old_numberformat;
  88 }
  89
  90 sub add_columns {
  91   my ($self, @columns) = @_;
  92
  93   my $h = $self->controller->headers;
  94
  95   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  96     $h->{used}->{$column} = 1;
  97     push @{ $h->{methods} }, $column;
  98     push @{ $h->{headers} }, $column;
  99   }
 100 }
 101
 102 sub add_info_columns {
 103   my ($self, @columns) = @_;
 104
 105   my $h = $self->controller->info_headers;
 106
 107   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 108     $h->{used}->{ $column->{method} } = 1;
 109     push @{ $h->{methods} }, $column->{method};
 110     push @{ $h->{headers} }, $column->{header};
 111   }
 112 }
 113
 114 sub add_raw_data_columns {
 115   my ($self, @columns) = @_;
 116
 117   my $h = $self->controller->raw_data_headers;
 118
 119   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 120     $h->{used}->{$column} = 1;
 121     push @{ $h->{headers} }, $column;
 122   }
 123 }
 124
 125 sub add_cvar_raw_data_columns {
 126   my ($self) = @_;
 127
 128   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 129 }
 130
 131 sub init_all_cvar_configs {
 132   # Must be overridden by derived specialized importer classes.
 133   return [];
 134 }
 135
 136 sub init_cvar_columns {
 137   my ($self) = @_;
 138
 139   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 140 }
 141
 142 sub init_all_languages {
 143   my ($self) = @_;
 144
 145   return SL::DB::Manager::Language->get_all;
 146 }
 147
 148 sub init_all_bank_accounts {
 149   my ($self) = @_;
 150
 151   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 152 }
 153
 154 sub init_payment_terms_by {
 155   my ($self) = @_;
 156
 157   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 159 }
 160
 161 sub init_delivery_terms_by {
 162   my ($self) = @_;
 163
 164   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 166 }
 167
 168 sub init_all_vc {
 169   my ($self) = @_;
 170
 171   return { customers => SL::DB::Manager::Customer->get_all,
 172            vendors   => SL::DB::Manager::Vendor->get_all };
 173 }
 174
 175 sub init_clone_methods {
 176   {}
 177 }
 178
 179 sub force_allow_columns {
 180   return ();
 181 }
 182
 183 sub init_vc_by {
 184   my ($self)    = @_;
 185
 186   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 187   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 191   my %by_gln    = ( customers => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{customers} } },
 192                     vendors   => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{vendors}   } } );
 193
 194   return { id     => \%by_id,
 195            number => \%by_number,
 196            name   => \%by_name,
 197            gln    => \%by_gln };
 198 }
 199
 200 sub init_vc_counts_by {
 201   my ($self) = @_;
 202
 203   my $vc_counts_by = {};
 204
 205   $vc_counts_by->{number}->{customers}->{$_->customernumber}++ for @{ $self->all_vc->{customers} };
 206   $vc_counts_by->{number}->{vendors}->  {$_->vendornumber}++   for @{ $self->all_vc->{vendors} };
 207   $vc_counts_by->{name}->  {customers}->{$_->name}++           for @{ $self->all_vc->{customers} };
 208   $vc_counts_by->{name}->  {vendors}->  {$_->name}++           for @{ $self->all_vc->{vendors} };
 209   $vc_counts_by->{gln}->   {customers}->{$_->gln}++            for grep $_->gln, @{ $self->all_vc->{customers} };
 210   $vc_counts_by->{gln}->   {vendors}->  {$_->gln}++            for grep $_->gln, @{ $self->all_vc->{vendors} };
 211
 212   return $vc_counts_by;
 213 }
 214
 215 sub check_vc {
 216   my ($self, $entry, $id_column) = @_;
 217
 218   if ($entry->{object}->$id_column) {
 219     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 220   }
 221
 222   my $is_ambiguous;
 223   if (!$entry->{object}->$id_column) {
 224     my $vc;
 225     if ($entry->{raw_data}->{customernumber}) {
 226       $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} };
 227       if ($vc && $self->vc_counts_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} } > 1) {
 228         $vc = undef;
 229         $is_ambiguous = 1;
 230       }
 231     } elsif ($entry->{raw_data}->{vendornumber}) {
 232       $vc = $self->vc_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} };
 233       if ($vc && $self->vc_counts_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} } > 1) {
 234         $vc = undef;
 235         $is_ambiguous = 1;
 236       }
 237     }
 238
 239     $entry->{object}->$id_column($vc->id) if $vc;
 240   }
 241
 242   if (!$entry->{object}->$id_column) {
 243     my $vc;
 244     if ($entry->{raw_data}->{customer}) {
 245       $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} };
 246       if ($vc && $self->vc_counts_by->{name}->{customers}->{ $entry->{raw_data}->{customer} } > 1) {
 247         $vc = undef;
 248         $is_ambiguous = 1;
 249       }
 250     } elsif ($entry->{raw_data}->{vendor}) {
 251       $vc = $self->vc_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} };
 252       if ($vc && $self->vc_counts_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} } > 1) {
 253         $vc = undef;
 254         $is_ambiguous = 1;
 255       }
 256     }
 257
 258     $entry->{object}->$id_column($vc->id) if $vc;
 259   }
 260
 261   if (!$entry->{object}->$id_column) {
 262     my $vc;
 263     if ($entry->{raw_data}->{customer_gln}) {
 264       $vc = $self->vc_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} };
 265       if ($vc && $self->vc_counts_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} } > 1) {
 266         $vc = undef;
 267         $is_ambiguous = 1;
 268       }
 269     } elsif ($entry->{raw_data}->{vendor_gln}) {
 270       $vc = $self->vc_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} };
 271       if ($vc && $self->vc_counts_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} } > 1) {
 272         $vc = undef;
 273         $is_ambiguous = 1;
 274       }
 275     }
 276     $entry->{object}->$id_column($vc->id) if $vc;
 277   }
 278
 279   if ($entry->{object}->$id_column) {
 280     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 281   } else {
 282     if ($is_ambiguous) {
 283       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor is ambiguous');
 284     } else {
 285       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 286     }
 287   }
 288 }
 289
 290 sub handle_cvars {
 291   my ($self, $entry) = @_;
 292
 293   my %type_to_column = ( text      => 'text_value',
 294                          textfield => 'text_value',
 295                          select    => 'text_value',
 296                          date      => 'timestamp_value_as_date',
 297                          timestamp => 'timestamp_value_as_date',
 298                          number    => 'number_value_as_number',
 299                          bool      => 'bool_value' );
 300
 301   my @cvars;
 302   my %changed_cvars;
 303   foreach my $config (@{ $self->all_cvar_configs }) {
 304     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 305     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 306     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 307
 308     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 309
 310     push @cvars, $new_cvar;
 311     $changed_cvars{$config->name} = $new_cvar;
 312   }
 313
 314   # merge existing with new cvars. swap every existing with the imported one, push the rest
 315   if (@cvars) {
 316     my @orig_cvars = ($entry->{object_to_save} || $entry->{object})->custom_variables;
 317     for (@orig_cvars) {
 318       $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 319       delete $changed_cvars{ $_->config->name };
 320     }
 321     push @orig_cvars, values %changed_cvars;
 322
 323     $entry->{object}->custom_variables(\@orig_cvars);
 324   }
 325 }
 326
 327 sub init_profile {
 328   my ($self) = @_;
 329
 330   eval "require " . $self->class;
 331
 332   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 333   delete $unwanted{$_} for ($self->force_allow_columns);
 334
 335   my %profile;
 336   for my $col ($self->class->meta->columns) {
 337     next if $unwanted{$col};
 338
 339     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 340       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 341       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 342       :                                                                     $col->name;
 343
 344     $profile{$col} = $name;
 345   }
 346
 347   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 348
 349   \%profile;
 350 }
 351
 352 sub add_displayable_columns {
 353   my ($self, @columns) = @_;
 354
 355   my @cols       = @{ $self->controller->displayable_columns || [] };
 356   my %ex_col_map = map { $_->{name} => $_ } @cols;
 357
 358   foreach my $column (@columns) {
 359     if ($ex_col_map{ $column->{name} }) {
 360       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 361     } else {
 362       push @cols, $column;
 363     }
 364   }
 365
 366   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 367 }
 368
 369 sub setup_displayable_columns {
 370   my ($self) = @_;
 371
 372   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 373 }
 374
 375 sub add_cvar_columns_to_displayable_columns {
 376   my ($self) = @_;
 377
 378   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 379                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 380                                      @{ $self->all_cvar_configs });
 381 }
 382
 383 sub init_existing_objects {
 384   my ($self) = @_;
 385
 386   eval "require " . $self->class;
 387   $self->existing_objects($self->manager_class->get_all);
 388 }
 389
 390 sub init_class {
 391   die "class not set";
 392 }
 393
 394 sub init_manager_class {
 395   my ($self) = @_;
 396
 397   $self->class =~ m/^SL::DB::(.+)/;
 398   $self->manager_class("SL::DB::Manager::" . $1);
 399 }
 400
 401 sub is_multiplexed { 0 }
 402
 403 sub check_objects {
 404 }
 405
 406 sub check_duplicates {
 407 }
 408
 409 sub check_auth {
 410   $::auth->assert('config');
 411 }
 412
 413 sub check_std_duplicates {
 414   my $self = shift;
 415
 416   my $duplicates = {};
 417
 418   my $all_fields = $self->get_duplicate_check_fields();
 419
 420   foreach my $key (keys(%{ $all_fields })) {
 421     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 422       $duplicates->{$key} = {};
 423     }
 424   }
 425
 426   my @duplicates_keys = keys(%{ $duplicates });
 427
 428   if ( !scalar(@duplicates_keys) ) {
 429     return;
 430   }
 431
 432   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 433     foreach my $object (@{ $self->existing_objects }) {
 434       foreach my $key (@duplicates_keys) {
 435         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 436         $duplicates->{$key}->{$value} = 'db';
 437       }
 438     }
 439   }
 440
 441   foreach my $entry (@{ $self->controller->data }) {
 442     if ( @{ $entry->{errors} } ) {
 443       next;
 444     }
 445
 446     my $object = $entry->{object};
 447
 448     foreach my $key (@duplicates_keys) {
 449       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 450
 451       if ( exists($duplicates->{$key}->{$value}) ) {
 452         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 453         last;
 454       } else {
 455         $duplicates->{$key}->{$value} = 'csv';
 456       }
 457
 458     }
 459   }
 460
 461 }
 462
 463 sub get_duplicate_check_fields {
 464   return {};
 465 }
 466
 467 sub check_payment {
 468   my ($self, $entry) = @_;
 469
 470   my $object = $entry->{object};
 471
 472   # Check whether or not payment ID is valid.
 473   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 474     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 475     return 0;
 476   }
 477
 478   # Map name to ID if given.
 479   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 480     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 481
 482     if (!$terms) {
 483       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 484       return 0;
 485     }
 486
 487     $object->payment_id($terms->id);
 488
 489     # register payment_id for method copying later
 490     $self->clone_methods->{payment_id} = 1;
 491   }
 492
 493   return 1;
 494 }
 495
 496 sub check_delivery_term {
 497   my ($self, $entry) = @_;
 498
 499   my $object = $entry->{object};
 500
 501   # Check whether or not delivery term ID is valid.
 502   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 503     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 504     return 0;
 505   }
 506
 507   # Map name to ID if given.
 508   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 509     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 510
 511     if (!$terms) {
 512       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 513       return 0;
 514     }
 515
 516     $object->delivery_term_id($terms->id);
 517
 518     # register delivery_term_id for method copying later
 519     $self->clone_methods->{delivery_term_id} = 1;
 520   }
 521
 522   return 1;
 523 }
 524
 525 sub save_objects {
 526   my ($self, %params) = @_;
 527
 528   my $data = $params{data} || $self->controller->data;
 529
 530   return unless $data->[0];
 531   return unless $data->[0]{object};
 532
 533   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 534
 535   my $last_index = $#$data;
 536   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 537
 538   for my $chunk (0 .. $last_index / $chunk_size) {
 539     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 540     SL::DB->client->with_transaction(sub {
 541       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 542         my $entry = $data->[$entry_index];
 543         next if @{ $entry->{errors} };
 544
 545         my $object = $entry->{object_to_save} || $entry->{object};
 546
 547         my $ret;
 548         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 549           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 550         } elsif ( !$ret ) {
 551           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 552         } else {
 553           $self->_save_history($object);
 554           $self->save_additions($object);
 555           $self->controller->num_imported($self->controller->num_imported + 1);
 556         }
 557       }
 558       1;
 559     }) or do { die SL::DB->client->error };
 560   }
 561   $self->controller->track_progress(progress => 100);
 562 }
 563
 564 sub field_lengths {
 565   my ($self) = @_;
 566
 567   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 568 }
 569
 570 sub fix_field_lengths {
 571   my ($self) = @_;
 572
 573   my %field_lengths = $self->field_lengths;
 574   foreach my $entry (@{ $self->controller->data }) {
 575     next unless @{ $entry->{errors} };
 576     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 577   }
 578 }
 579
 580 sub clean_fields {
 581   my ($self, $illegal_chars, $object, @fields) = @_;
 582
 583   my @cleaned_fields;
 584   foreach my $field (grep { $object->can($_) } @fields) {
 585     my $value = $object->$field;
 586
 587     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 588
 589     $object->$field($value);
 590     push @cleaned_fields, $field;
 591   }
 592
 593   return @cleaned_fields;
 594 }
 595
 596 sub save_additions {
 597   my ($self, $object) = @_;
 598
 599   # Can be overridden by derived specialized importer classes to save
 600   # additional tables (e.g. record links).
 601   # This sub is called after the object is saved successfully in an transaction.
 602
 603   return;
 604 }
 605
 606 sub _save_history {
 607   my ($self, $object) = @_;
 608
 609   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders delivery_orders ar_transactions)) {
 610     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 611                  : $self->controller->{type} eq 'customers_vendors' ?
 612                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 613                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 614                  : $self->controller->{type} eq 'delivery_orders'   ? 'donumber_'  . $object->donumber
 615                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 616                  : '';
 617
 618     my $what_done = '';
 619     if ($self->controller->{type} eq 'orders') {
 620       $what_done = $object->customer_id ? 'sales_order' : 'purchase_order';
 621     }
 622     if ($self->controller->{type} eq 'delivery_orders') {
 623       $what_done = $object->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
 624     }
 625
 626     SL::DB::History->new(
 627       trans_id    => $object->id,
 628       snumbers    => $snumbers,
 629       employee_id => $self->controller->{employee_id},
 630       addition    => 'SAVED',
 631       what_done   => $what_done,
 632     )->save();
 633   }
 634 }
 635
 636 1;