SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(Rose::Object);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar                  => [ qw(controller file csv save_with_cascade) ],
  19  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  20 );
  21
  22 sub run {
  23   my ($self) = @_;
  24
  25   my $profile = $self->profile;
  26   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  27                                   encoding               => $self->controller->profile->get('charset'),
  28                                   class                  => $self->class,
  29                                   profile                => $profile,
  30                                   ignore_unknown_columns => 1,
  31                                   strict_profile         => 1,
  32                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  33                                  ));
  34
  35   my $old_numberformat      = $::myconfig{numberformat};
  36   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  37
  38   $self->csv->parse;
  39
  40   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  41
  42   return if ( !$self->csv->header || $self->csv->errors );
  43
  44   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  45   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  46   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  47   $self->controller->headers($headers);
  48   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  49   $self->controller->info_headers({ used => { }, headers => [ ] });
  50
  51   my @objects  = $self->csv->get_objects;
  52   my @raw_data = @{ $self->csv->get_data };
  53   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  54
  55   $self->check_objects;
  56   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  57     $self->check_std_duplicates();
  58     $self->check_duplicates();
  59   }
  60   $self->fix_field_lengths;
  61
  62   $::myconfig{numberformat} = $old_numberformat;
  63 }
  64
  65 sub add_columns {
  66   my ($self, @columns) = @_;
  67
  68   my $h = $self->controller->headers;
  69
  70   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  71     $h->{used}->{$column} = 1;
  72     push @{ $h->{methods} }, $column;
  73     push @{ $h->{headers} }, $column;
  74   }
  75 }
  76
  77 sub add_info_columns {
  78   my ($self, @columns) = @_;
  79
  80   my $h = $self->controller->info_headers;
  81
  82   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
  83     $h->{used}->{ $column->{method} } = 1;
  84     push @{ $h->{methods} }, $column->{method};
  85     push @{ $h->{headers} }, $column->{header};
  86   }
  87 }
  88
  89 sub add_raw_data_columns {
  90   my ($self, @columns) = @_;
  91
  92   my $h = $self->controller->raw_data_headers;
  93
  94   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  95     $h->{used}->{$column} = 1;
  96     push @{ $h->{headers} }, $column;
  97   }
  98 }
  99
 100 sub add_cvar_raw_data_columns {
 101   my ($self) = @_;
 102
 103   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 104 }
 105
 106 sub init_cvar_columns {
 107   my ($self) = @_;
 108
 109   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 110 }
 111
 112 sub init_all_languages {
 113   my ($self) = @_;
 114
 115   return SL::DB::Manager::Language->get_all;
 116 }
 117
 118 sub init_payment_terms_by {
 119   my ($self) = @_;
 120
 121   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 122   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 123 }
 124
 125 sub init_all_vc {
 126   my ($self) = @_;
 127
 128   return { customers => SL::DB::Manager::Customer->get_all,
 129            vendors   => SL::DB::Manager::Vendor->get_all };
 130 }
 131
 132 sub init_vc_by {
 133   my ($self)    = @_;
 134
 135   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 136   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 137                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 138   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 139                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 140
 141   return { id     => \%by_id,
 142            number => \%by_number,
 143            name   => \%by_name,   };
 144 }
 145
 146 sub check_vc {
 147   my ($self, $entry, $id_column) = @_;
 148
 149   if ($entry->{object}->$id_column) {
 150     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 151   }
 152
 153   if (!$entry->{object}->$id_column) {
 154     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 155           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 156     $entry->{object}->$id_column($vc->id) if $vc;
 157   }
 158
 159   if (!$entry->{object}->$id_column) {
 160     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 161           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 162     $entry->{object}->$id_column($vc->id) if $vc;
 163   }
 164
 165   if ($entry->{object}->$id_column) {
 166     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 167   } else {
 168     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 169   }
 170 }
 171
 172 sub handle_cvars {
 173   my ($self, $entry) = @_;
 174
 175   return unless $self->can('all_cvar_configs');
 176
 177   my %type_to_column = ( text      => 'text_value',
 178                          textfield => 'text_value',
 179                          select    => 'text_value',
 180                          date      => 'timestamp_value_as_date',
 181                          timestamp => 'timestamp_value_as_date',
 182                          number    => 'number_value_as_number',
 183                          bool      => 'bool_value' );
 184
 185   my @cvars;
 186   foreach my $config (@{ $self->all_cvar_configs }) {
 187     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 188     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 189     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 190
 191     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 192   }
 193
 194   $entry->{object}->custom_variables(\@cvars);
 195 }
 196
 197 sub init_profile {
 198   my ($self) = @_;
 199
 200   eval "require " . $self->class;
 201
 202   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 203   my %profile;
 204   for my $col ($self->class->meta->columns) {
 205     next if $unwanted{$col};
 206
 207     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 208       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 209       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 210       :                                                                     $col->name;
 211
 212     $profile{$col} = $name;
 213   }
 214
 215   $self->profile(\%profile);
 216 }
 217
 218 sub add_displayable_columns {
 219   my ($self, @columns) = @_;
 220
 221   my @cols       = @{ $self->controller->displayable_columns || [] };
 222   my %ex_col_map = map { $_->{name} => $_ } @cols;
 223
 224   foreach my $column (@columns) {
 225     if ($ex_col_map{ $column->{name} }) {
 226       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 227     } else {
 228       push @cols, $column;
 229     }
 230   }
 231
 232   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 233 }
 234
 235 sub setup_displayable_columns {
 236   my ($self) = @_;
 237
 238   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 239 }
 240
 241 sub add_cvar_columns_to_displayable_columns {
 242   my ($self) = @_;
 243
 244   return unless $self->can('all_cvar_configs');
 245
 246   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 247                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 248                                      @{ $self->all_cvar_configs });
 249 }
 250
 251 sub init_existing_objects {
 252   my ($self) = @_;
 253
 254   eval "require " . $self->class;
 255   $self->existing_objects($self->manager_class->get_all);
 256 }
 257
 258 sub init_class {
 259   die "class not set";
 260 }
 261
 262 sub init_manager_class {
 263   my ($self) = @_;
 264
 265   $self->class =~ m/^SL::DB::(.+)/;
 266   $self->manager_class("SL::DB::Manager::" . $1);
 267 }
 268
 269 sub check_objects {
 270 }
 271
 272 sub check_duplicates {
 273 }
 274
 275 sub check_std_duplicates {
 276   my $self = shift;
 277
 278   my $duplicates = {};
 279
 280   my $all_fields = $self->get_duplicate_check_fields();
 281
 282   foreach my $key (keys(%{ $all_fields })) {
 283     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 284       $duplicates->{$key} = {};
 285     }
 286   }
 287
 288   my @duplicates_keys = keys(%{ $duplicates });
 289
 290   if ( !scalar(@duplicates_keys) ) {
 291     return;
 292   }
 293
 294   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 295     foreach my $object (@{ $self->existing_objects }) {
 296       foreach my $key (@duplicates_keys) {
 297         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 298         $duplicates->{$key}->{$value} = 'db';
 299       }
 300     }
 301   }
 302
 303   foreach my $entry (@{ $self->controller->data }) {
 304     if ( @{ $entry->{errors} } ) {
 305       next;
 306     }
 307
 308     my $object = $entry->{object};
 309
 310     foreach my $key (@duplicates_keys) {
 311       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 312
 313       if ( exists($duplicates->{$key}->{$value}) ) {
 314         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 315         last;
 316       } else {
 317         $duplicates->{$key}->{$value} = 'csv';
 318       }
 319
 320     }
 321   }
 322
 323 }
 324
 325 sub get_duplicate_check_fields {
 326   return {};
 327 }
 328
 329 sub check_payment {
 330   my ($self, $entry) = @_;
 331
 332   my $object = $entry->{object};
 333
 334   # Check whether or not payment ID is valid.
 335   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 336     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 337     return 0;
 338   }
 339
 340   # Map name to ID if given.
 341   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 342     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 343
 344     if (!$terms) {
 345       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 346       return 0;
 347     }
 348
 349     $object->payment_id($terms->id);
 350   }
 351
 352   return 1;
 353 }
 354
 355 sub save_objects {
 356   my ($self, %params) = @_;
 357
 358   my $data = $params{data} || $self->controller->data;
 359
 360   foreach my $entry (@{ $data }) {
 361     next if @{ $entry->{errors} };
 362
 363     my $object = $entry->{object_to_save} || $entry->{object};
 364
 365     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 366       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 367     } else {
 368       $self->controller->num_imported($self->controller->num_imported + 1);
 369     }
 370   }
 371 }
 372
 373 sub field_lengths {
 374   return ();
 375 }
 376
 377 sub fix_field_lengths {
 378   my ($self) = @_;
 379
 380   my %field_lengths = $self->field_lengths;
 381   foreach my $entry (@{ $self->controller->data }) {
 382     next unless @{ $entry->{errors} };
 383     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 384   }
 385 }
 386
 387 1;
 388