SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Language;
   9 use SL::DB::PaymentTerm;
  10
  11 use parent qw(Rose::Object);
  12
  13 use Rose::Object::MakeMethods::Generic
  14 (
  15  scalar                  => [ qw(controller file csv) ],
  16  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by) ],
  17 );
  18
  19 sub run {
  20   my ($self) = @_;
  21
  22   my $profile = $self->profile;
  23   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  24                                   encoding               => $self->controller->profile->get('charset'),
  25                                   class                  => $self->class,
  26                                   profile                => $profile,
  27                                   ignore_unknown_columns => 1,
  28                                   strict_profile         => 1,
  29                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  30                                  ));
  31   $self->csv->parse;
  32
  33   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  34
  35   return unless $self->csv->header;
  36
  37   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  38   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  39   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  40   $self->controller->headers($headers);
  41   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  42
  43   # my @data;
  44   # foreach my $object ($self->csv->get_objects)
  45   my @objects  = $self->csv->get_objects;
  46   my @raw_data = @{ $self->csv->get_data };
  47   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [] } } @objects, @raw_data ]);
  48   $::lxdebug->dump(0, "DATA", $self->controller->data);
  49
  50   $self->check_objects;
  51   $self->check_duplicates if $self->controller->profile->get('duplicates', 'no_check') ne 'no_check';
  52   $self->fix_field_lengths;
  53 }
  54
  55 sub add_columns {
  56   my ($self, @columns) = @_;
  57
  58   my $h = $self->controller->headers;
  59
  60   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  61     $h->{used}->{$column} = 1;
  62     push @{ $h->{methods} }, $column;
  63     push @{ $h->{headers} }, $column;
  64   }
  65 }
  66
  67 sub add_raw_data_columns {
  68   my ($self, @columns) = @_;
  69
  70   my $h = $self->controller->raw_data_headers;
  71
  72   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  73     $h->{used}->{$column} = 1;
  74     push @{ $h->{headers} }, $column;
  75   }
  76 }
  77
  78 sub add_cvar_raw_data_columns {
  79   my ($self) = @_;
  80
  81   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
  82 }
  83
  84 sub init_cvar_columns {
  85   my ($self) = @_;
  86
  87   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
  88 }
  89
  90 sub init_all_languages {
  91   my ($self) = @_;
  92
  93   return SL::DB::Manager::Language->get_all;
  94 }
  95
  96 sub init_payment_terms_by {
  97   my ($self) = @_;
  98
  99   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 100   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 101 }
 102
 103 sub handle_cvars {
 104   my ($self, $entry) = @_;
 105
 106   return unless $self->can('all_cvar_configs');
 107
 108   my %type_to_column = ( text      => 'text_value',
 109                          textfield => 'text_value',
 110                          select    => 'text_value',
 111                          date      => 'timestamp_value_as_date',
 112                          timestamp => 'timestamp_value_as_date',
 113                          number    => 'number_value_as_number',
 114                          bool      => 'bool_value' );
 115
 116   my @cvars;
 117   foreach my $config (@{ $self->all_cvar_configs }) {
 118     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 119     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 120     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 121
 122     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value);
 123   }
 124
 125   $entry->{object}->custom_variables(\@cvars);
 126 }
 127
 128 sub init_profile {
 129   my ($self) = @_;
 130
 131   eval "require " . $self->class;
 132
 133   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 134   my %profile;
 135   for my $col ($self->class->meta->columns) {
 136     next if $unwanted{$col};
 137
 138     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 139       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 140       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 141       :                                                                     $col->name;
 142
 143     $profile{$col} = $name;
 144   }
 145
 146   $self->profile(\%profile);
 147 }
 148
 149 sub add_displayable_columns {
 150   my ($self, @columns) = @_;
 151
 152   my @cols       = @{ $self->controller->displayable_columns || [] };
 153   my %ex_col_map = map { $_->{name} => $_ } @cols;
 154
 155   foreach my $column (@columns) {
 156     if ($ex_col_map{ $column->{name} }) {
 157       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 158     } else {
 159       push @cols, $column;
 160     }
 161   }
 162
 163   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 164 }
 165
 166 sub setup_displayable_columns {
 167   my ($self) = @_;
 168
 169   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 170 }
 171
 172 sub add_cvar_columns_to_displayable_columns {
 173   my ($self) = @_;
 174
 175   return unless $self->can('all_cvar_configs');
 176
 177   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 178                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 179                                      @{ $self->all_cvar_configs });
 180 }
 181
 182 sub init_existing_objects {
 183   my ($self) = @_;
 184
 185   eval "require " . $self->class;
 186   $self->existing_objects($self->manager_class->get_all);
 187 }
 188
 189 sub init_class {
 190   die "class not set";
 191 }
 192
 193 sub init_manager_class {
 194   my ($self) = @_;
 195
 196   $self->class =~ m/^SL::DB::(.+)/;
 197   $self->manager_class("SL::DB::Manager::" . $1);
 198 }
 199
 200 sub check_objects {
 201 }
 202
 203 sub check_duplicates {
 204 }
 205
 206 sub check_payment {
 207   my ($self, $entry) = @_;
 208
 209   my $object = $entry->{object};
 210
 211   # Check whether or not payment ID is valid.
 212   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 213     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 214     return 0;
 215   }
 216
 217   # Map name to ID if given.
 218   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 219     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 220
 221     if (!$terms) {
 222       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 223       return 0;
 224     }
 225
 226     $object->payment_id($terms->id);
 227   }
 228
 229   return 1;
 230 }
 231
 232 sub save_objects {
 233   my ($self, %params) = @_;
 234
 235   my $data = $params{data} || $self->controller->data;
 236
 237   foreach my $entry (@{ $data }) {
 238     next if @{ $entry->{errors} };
 239
 240     if (!$entry->{object}->save) {
 241       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 242     } else {
 243       $self->controller->num_imported($self->controller->num_imported + 1);
 244     }
 245   }
 246 }
 247
 248 sub field_lengths {
 249   return ();
 250 }
 251
 252 sub fix_field_lengths {
 253   my ($self) = @_;
 254
 255   my %field_lengths = $self->field_lengths;
 256   foreach my $entry (@{ $self->controller->data }) {
 257     next unless @{ $entry->{errors} };
 258     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 259   }
 260 }
 261
 262 1;