SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(Rose::Object);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  19  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  20 );
  21
  22 sub run {
  23   my ($self, %params) = @_;
  24
  25   $self->test_run($params{test_run});
  26
  27   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  28
  29   my $profile = $self->profile;
  30   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  31                                   encoding               => $self->controller->profile->get('charset'),
  32                                   class                  => $self->class,
  33                                   profile                => $profile,
  34                                   ignore_unknown_columns => 1,
  35                                   strict_profile         => 1,
  36                                   case_insensitive_header => 1,
  37                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  38                                  ));
  39
  40   $self->controller->track_progress(progress => 10);
  41
  42   my $old_numberformat      = $::myconfig{numberformat};
  43   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  44
  45   $self->csv->parse;
  46
  47   $self->controller->track_progress(progress => 50);
  48
  49   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  50
  51   return if ( !$self->csv->header || $self->csv->errors );
  52
  53   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  54   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  55   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  56   $self->controller->headers($headers);
  57   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  58   $self->controller->info_headers({ used => { }, headers => [ ] });
  59
  60   my @objects  = $self->csv->get_objects;
  61
  62   $self->controller->track_progress(progress => 70);
  63
  64   my @raw_data = @{ $self->csv->get_data };
  65
  66   $self->controller->track_progress(progress => 80);
  67
  68   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  69
  70   $self->controller->track_progress(progress => 90);
  71
  72   $self->check_objects;
  73   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  74     $self->check_std_duplicates();
  75     $self->check_duplicates();
  76   }
  77   $self->fix_field_lengths;
  78
  79   $self->controller->track_progress(progress => 100);
  80
  81   $::myconfig{numberformat} = $old_numberformat;
  82 }
  83
  84 sub add_columns {
  85   my ($self, @columns) = @_;
  86
  87   my $h = $self->controller->headers;
  88
  89   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  90     $h->{used}->{$column} = 1;
  91     push @{ $h->{methods} }, $column;
  92     push @{ $h->{headers} }, $column;
  93   }
  94 }
  95
  96 sub add_info_columns {
  97   my ($self, @columns) = @_;
  98
  99   my $h = $self->controller->info_headers;
 100
 101   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 102     $h->{used}->{ $column->{method} } = 1;
 103     push @{ $h->{methods} }, $column->{method};
 104     push @{ $h->{headers} }, $column->{header};
 105   }
 106 }
 107
 108 sub add_raw_data_columns {
 109   my ($self, @columns) = @_;
 110
 111   my $h = $self->controller->raw_data_headers;
 112
 113   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 114     $h->{used}->{$column} = 1;
 115     push @{ $h->{headers} }, $column;
 116   }
 117 }
 118
 119 sub add_cvar_raw_data_columns {
 120   my ($self) = @_;
 121
 122   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 123 }
 124
 125 sub init_all_cvar_configs {
 126   # Must be overridden by derived specialized importer classes.
 127   return [];
 128 }
 129
 130 sub init_cvar_columns {
 131   my ($self) = @_;
 132
 133   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 134 }
 135
 136 sub init_all_languages {
 137   my ($self) = @_;
 138
 139   return SL::DB::Manager::Language->get_all;
 140 }
 141
 142 sub init_payment_terms_by {
 143   my ($self) = @_;
 144
 145   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 146   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 147 }
 148
 149 sub init_all_vc {
 150   my ($self) = @_;
 151
 152   return { customers => SL::DB::Manager::Customer->get_all,
 153            vendors   => SL::DB::Manager::Vendor->get_all };
 154 }
 155
 156 sub init_vc_by {
 157   my ($self)    = @_;
 158
 159   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 160   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 161                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 162   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 163                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 164
 165   return { id     => \%by_id,
 166            number => \%by_number,
 167            name   => \%by_name,   };
 168 }
 169
 170 sub check_vc {
 171   my ($self, $entry, $id_column) = @_;
 172
 173   if ($entry->{object}->$id_column) {
 174     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 175   }
 176
 177   if (!$entry->{object}->$id_column) {
 178     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 179           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 180     $entry->{object}->$id_column($vc->id) if $vc;
 181   }
 182
 183   if (!$entry->{object}->$id_column) {
 184     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 185           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 186     $entry->{object}->$id_column($vc->id) if $vc;
 187   }
 188
 189   if ($entry->{object}->$id_column) {
 190     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 191   } else {
 192     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 193   }
 194 }
 195
 196 sub handle_cvars {
 197   my ($self, $entry) = @_;
 198
 199   my %type_to_column = ( text      => 'text_value',
 200                          textfield => 'text_value',
 201                          select    => 'text_value',
 202                          date      => 'timestamp_value_as_date',
 203                          timestamp => 'timestamp_value_as_date',
 204                          number    => 'number_value_as_number',
 205                          bool      => 'bool_value' );
 206
 207   my @cvars;
 208   foreach my $config (@{ $self->all_cvar_configs }) {
 209     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 210     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 211     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 212
 213     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 214   }
 215
 216   $entry->{object}->custom_variables(\@cvars);
 217 }
 218
 219 sub init_profile {
 220   my ($self) = @_;
 221
 222   eval "require " . $self->class;
 223
 224   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 225   my %profile;
 226   for my $col ($self->class->meta->columns) {
 227     next if $unwanted{$col};
 228
 229     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 230       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 231       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 232       :                                                                     $col->name;
 233
 234     $profile{$col} = $name;
 235   }
 236
 237   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 238
 239   \%profile;
 240 }
 241
 242 sub add_displayable_columns {
 243   my ($self, @columns) = @_;
 244
 245   my @cols       = @{ $self->controller->displayable_columns || [] };
 246   my %ex_col_map = map { $_->{name} => $_ } @cols;
 247
 248   foreach my $column (@columns) {
 249     if ($ex_col_map{ $column->{name} }) {
 250       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 251     } else {
 252       push @cols, $column;
 253     }
 254   }
 255
 256   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 257 }
 258
 259 sub setup_displayable_columns {
 260   my ($self) = @_;
 261
 262   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 263 }
 264
 265 sub add_cvar_columns_to_displayable_columns {
 266   my ($self) = @_;
 267
 268   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 269                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 270                                      @{ $self->all_cvar_configs });
 271 }
 272
 273 sub init_existing_objects {
 274   my ($self) = @_;
 275
 276   eval "require " . $self->class;
 277   $self->existing_objects($self->manager_class->get_all);
 278 }
 279
 280 sub init_class {
 281   die "class not set";
 282 }
 283
 284 sub init_manager_class {
 285   my ($self) = @_;
 286
 287   $self->class =~ m/^SL::DB::(.+)/;
 288   $self->manager_class("SL::DB::Manager::" . $1);
 289 }
 290
 291 sub check_objects {
 292 }
 293
 294 sub check_duplicates {
 295 }
 296
 297 sub check_std_duplicates {
 298   my $self = shift;
 299
 300   my $duplicates = {};
 301
 302   my $all_fields = $self->get_duplicate_check_fields();
 303
 304   foreach my $key (keys(%{ $all_fields })) {
 305     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 306       $duplicates->{$key} = {};
 307     }
 308   }
 309
 310   my @duplicates_keys = keys(%{ $duplicates });
 311
 312   if ( !scalar(@duplicates_keys) ) {
 313     return;
 314   }
 315
 316   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 317     foreach my $object (@{ $self->existing_objects }) {
 318       foreach my $key (@duplicates_keys) {
 319         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 320         $duplicates->{$key}->{$value} = 'db';
 321       }
 322     }
 323   }
 324
 325   foreach my $entry (@{ $self->controller->data }) {
 326     if ( @{ $entry->{errors} } ) {
 327       next;
 328     }
 329
 330     my $object = $entry->{object};
 331
 332     foreach my $key (@duplicates_keys) {
 333       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 334
 335       if ( exists($duplicates->{$key}->{$value}) ) {
 336         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 337         last;
 338       } else {
 339         $duplicates->{$key}->{$value} = 'csv';
 340       }
 341
 342     }
 343   }
 344
 345 }
 346
 347 sub get_duplicate_check_fields {
 348   return {};
 349 }
 350
 351 sub check_payment {
 352   my ($self, $entry) = @_;
 353
 354   my $object = $entry->{object};
 355
 356   # Check whether or not payment ID is valid.
 357   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 358     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 359     return 0;
 360   }
 361
 362   # Map name to ID if given.
 363   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 364     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 365
 366     if (!$terms) {
 367       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 368       return 0;
 369     }
 370
 371     $object->payment_id($terms->id);
 372   }
 373
 374   return 1;
 375 }
 376
 377 sub save_objects {
 378   my ($self, %params) = @_;
 379
 380   my $data = $params{data} || $self->controller->data;
 381
 382   return unless $data->[0];
 383   return unless $data->[0]{object};
 384
 385   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 386
 387   my $dbh = $data->[0]{object}->db;
 388
 389   $dbh->begin_work;
 390   foreach my $entry_index (0 .. $#$data) {
 391     my $entry = $data->[$entry_index];
 392     next if @{ $entry->{errors} };
 393
 394     my $object = $entry->{object_to_save} || $entry->{object};
 395
 396     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 397       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 398     } else {
 399       $self->controller->num_imported($self->controller->num_imported + 1);
 400     }
 401   } continue {
 402     if ($entry_index % 100 == 0) {
 403       $dbh->commit;
 404       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 405       $dbh->begin_work;
 406     }
 407   }
 408   $dbh->commit;
 409 }
 410
 411 sub field_lengths {
 412   return ();
 413 }
 414
 415 sub fix_field_lengths {
 416   my ($self) = @_;
 417
 418   my %field_lengths = $self->field_lengths;
 419   foreach my $entry (@{ $self->controller->data }) {
 420     next unless @{ $entry->{errors} };
 421     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 422   }
 423 }
 424
 425 sub clean_fields {
 426   my ($self, $illegal_chars, $object, @fields) = @_;
 427
 428   my @cleaned_fields;
 429   foreach my $field (grep { $object->can($_) } @fields) {
 430     my $value = $object->$field;
 431
 432     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 433
 434     $object->$field($value);
 435     push @cleaned_fields, $field;
 436   }
 437
 438   return @cleaned_fields;
 439 }
 440
 441 1;