SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(SL::Controller::CsvImport::Base);
  15
  16 sub run {
  17   my ($self, %params) = @_;
  18
  19   $self->test_run($params{test_run});
  20
  21   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  22
  23   my $profile = $self->profile;
  24
  25   $self->csv(SL::Helper::Csv->new(file                    => $self->file->file_name,
  26                                   encoding                => $self->controller->profile->get('charset'),
  27                                   profile                 => $profile,
  28                                   ignore_unknown_columns  => 1,
  29                                   strict_profile          => 1,
  30                                   case_insensitive_header => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   $self->controller->track_progress(progress => 10);
  35
  36   my $old_numberformat      = $::myconfig{numberformat};
  37   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  38
  39   $self->csv->parse;
  40
  41   $self->controller->track_progress(progress => 50);
  42
  43   # bb: make sanity-check of it?
  44   #if ($self->csv->is_multiplexed != $self->is_multiplexed) {
  45   #  die "multiplex controller on simplex data or vice versa";
  46   #}
  47
  48   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  49
  50   return if ( !$self->csv->header || $self->csv->errors );
  51
  52   my $headers;
  53   my $i = 0;
  54   foreach my $header (@{ $self->csv->header }) {
  55
  56     my $profile   = $self->csv->profile->[$i]->{profile};
  57     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  58
  59     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  60     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  61     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  62
  63     $headers->{$row_ident} = $h;
  64     $i++;
  65   }
  66
  67   $self->controller->headers($headers);
  68
  69   my $raw_data_headers;
  70   my $info_headers;
  71   foreach my $p (@{ $self->csv->profile }) {
  72     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  73     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  74   }
  75   $self->controller->raw_data_headers($raw_data_headers);
  76   $self->controller->info_headers($info_headers);
  77
  78
  79   my @objects  = $self->csv->get_objects;
  80   $self->controller->track_progress(progress => 70);
  81
  82   my @raw_data = @{ $self->csv->get_data };
  83
  84   $self->controller->track_progress(progress => 80);
  85
  86   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  87
  88   $self->controller->track_progress(progress => 90);
  89
  90   $self->check_objects;
  91   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  92     $self->check_std_duplicates();
  93     $self->check_duplicates();
  94   }
  95   $self->fix_field_lengths;
  96
  97   $self->controller->track_progress(progress => 100);
  98
  99   $::myconfig{numberformat} = $old_numberformat;
 100 }
 101
 102 sub add_columns {
 103   my ($self, $row_ident, @columns) = @_;
 104
 105   my $h = $self->controller->headers->{$row_ident};
 106
 107   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 108     $h->{used}->{$column} = 1;
 109     push @{ $h->{methods} }, $column;
 110     push @{ $h->{headers} }, $column;
 111   }
 112 }
 113
 114 sub add_info_columns {
 115   my ($self, $row_ident, @columns) = @_;
 116
 117   my $h = $self->controller->info_headers->{$row_ident};
 118
 119   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 120     $h->{used}->{ $column->{method} } = 1;
 121     push @{ $h->{methods} }, $column->{method};
 122     push @{ $h->{headers} }, $column->{header};
 123   }
 124 }
 125
 126 sub add_raw_data_columns {
 127   my ($self, $row_ident, @columns) = @_;
 128
 129   my $h = $self->controller->raw_data_headers->{$row_ident};
 130
 131   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 132     $h->{used}->{$column} = 1;
 133     push @{ $h->{headers} }, $column;
 134   }
 135 }
 136
 137 sub add_cvar_raw_data_columns {
 138   my ($self) = @_;
 139
 140   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 141 }
 142
 143 sub init_profile {
 144   my ($self) = @_;
 145
 146   my @profile;
 147   foreach my $class (@{ $self->class }) {
 148     eval "require " . $class;
 149
 150     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 151     my %prof;
 152     $prof{datatype} = '';
 153     for my $col ($class->meta->columns) {
 154       next if $unwanted{$col};
 155
 156       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 157           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 158           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 159           :                                                                   $col->name;
 160
 161       $prof{$col} = $name;
 162     }
 163
 164     $prof{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 165
 166     $class =~ m/^SL::DB::(.+)/;
 167     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $1};
 168   }
 169
 170   \@profile;
 171 }
 172
 173 sub add_displayable_columns {
 174   my ($self, $row_ident, @columns) = @_;
 175
 176   my $dis_cols = $self->controller->displayable_columns || {};
 177
 178   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 179   my %ex_col_map = map { $_->{name} => $_ } @cols;
 180
 181   foreach my $column (@columns) {
 182     if ($ex_col_map{ $column->{name} }) {
 183       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 184     } else {
 185       push @cols, $column;
 186     }
 187   }
 188
 189   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 190                                      'datatype' eq $b->{name} ?  1 :
 191                                      $a->{name} cmp $b->{name} };
 192   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 193
 194   $self->controller->displayable_columns($dis_cols);
 195 }
 196
 197 sub setup_displayable_columns {
 198   my ($self) = @_;
 199
 200   foreach my $p (@{ $self->profile }) {
 201     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 202   }
 203 }
 204
 205 sub add_cvar_columns_to_displayable_columns {
 206   my ($self) = @_;
 207
 208   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 209                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 210                                      @{ $self->all_cvar_configs });
 211 }
 212
 213 sub init_existing_objects {
 214   my ($self) = @_;
 215
 216   eval "require " . $self->class;
 217   $self->existing_objects($self->manager_class->get_all);
 218 }
 219
 220 sub init_class {
 221   die "class not set";
 222 }
 223
 224 sub init_manager_class {
 225   my ($self) = @_;
 226
 227   $self->class =~ m/^SL::DB::(.+)/;
 228   $self->manager_class("SL::DB::Manager::" . $1);
 229 }
 230
 231 1;
 232