SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(SL::Controller::CsvImport::Base);
  10
  11 sub run {
  12   my ($self, %params) = @_;
  13
  14   $self->test_run($params{test_run});
  15
  16   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  17
  18   my $profile = $self->profile;
  19
  20   $self->csv(SL::Helper::Csv->new(file                    => $self->file->file_name,
  21                                   encoding                => $self->controller->profile->get('charset'),
  22                                   profile                 => $profile,
  23                                   ignore_unknown_columns  => 1,
  24                                   strict_profile          => 1,
  25                                   case_insensitive_header => 1,
  26                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  27                                  ));
  28
  29   $self->controller->track_progress(progress => 10);
  30
  31   my $old_numberformat      = $::myconfig{numberformat};
  32   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  33
  34   $self->csv->parse;
  35
  36   $self->controller->track_progress(progress => 50);
  37
  38   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  39
  40   return if ( !$self->csv->header || $self->csv->errors );
  41
  42   my $headers;
  43   my $i = 0;
  44   foreach my $header (@{ $self->csv->header }) {
  45
  46     my $profile   = $self->csv->profile->[$i]->{profile};
  47     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  48
  49     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  50     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  51     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  52
  53     $headers->{$row_ident} = $h;
  54     $i++;
  55   }
  56
  57   $self->controller->headers($headers);
  58
  59   my $raw_data_headers;
  60   my $info_headers;
  61   foreach my $p (@{ $self->csv->profile }) {
  62     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  63     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  64   }
  65   $self->controller->raw_data_headers($raw_data_headers);
  66   $self->controller->info_headers($info_headers);
  67
  68   my @objects  = $self->csv->get_objects;
  69
  70   $self->controller->track_progress(progress => 70);
  71
  72   my @raw_data = @{ $self->csv->get_data };
  73
  74   $self->controller->track_progress(progress => 80);
  75
  76   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  77
  78   $self->controller->track_progress(progress => 90);
  79
  80   $self->check_objects;
  81   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  82     $self->check_std_duplicates();
  83     $self->check_duplicates();
  84   }
  85   $self->fix_field_lengths;
  86
  87   $self->controller->track_progress(progress => 100);
  88
  89   $::myconfig{numberformat} = $old_numberformat;
  90 }
  91
  92 sub add_columns {
  93   my ($self, $row_ident, @columns) = @_;
  94
  95   my $h = $self->controller->headers->{$row_ident};
  96
  97   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  98     $h->{used}->{$column} = 1;
  99     push @{ $h->{methods} }, $column;
 100     push @{ $h->{headers} }, $column;
 101   }
 102 }
 103
 104 sub add_info_columns {
 105   my ($self, $row_ident, @columns) = @_;
 106
 107   my $h = $self->controller->info_headers->{$row_ident};
 108
 109   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 110     $h->{used}->{ $column->{method} } = 1;
 111     push @{ $h->{methods} }, $column->{method};
 112     push @{ $h->{headers} }, $column->{header};
 113   }
 114 }
 115
 116 sub add_raw_data_columns {
 117   my ($self, $row_ident, @columns) = @_;
 118
 119   my $h = $self->controller->raw_data_headers->{$row_ident};
 120
 121   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 122     $h->{used}->{$column} = 1;
 123     push @{ $h->{headers} }, $column;
 124   }
 125 }
 126
 127 sub init_profile {
 128   my ($self) = @_;
 129
 130   my @profile;
 131   foreach my $class (@{ $self->class }) {
 132     eval "require " . $class;
 133
 134     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 135     my %prof;
 136     $prof{datatype} = '';
 137     for my $col ($class->meta->columns) {
 138       next if $unwanted{$col};
 139
 140       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 141           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 142           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 143           :                                                                   $col->name;
 144
 145       $prof{$col} = $name;
 146     }
 147
 148     $prof{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 149
 150     $class =~ m/^SL::DB::(.+)/;
 151     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 152   }
 153
 154   \@profile;
 155 }
 156
 157 sub add_displayable_columns {
 158   my ($self, $row_ident, @columns) = @_;
 159
 160   my $dis_cols = $self->controller->displayable_columns || {};
 161
 162   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 163   my %ex_col_map = map { $_->{name} => $_ } @cols;
 164
 165   foreach my $column (@columns) {
 166     if ($ex_col_map{ $column->{name} }) {
 167       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 168     } else {
 169       push @cols, $column;
 170     }
 171   }
 172
 173   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 174                                      'datatype' eq $b->{name} ?  1 :
 175                                      $a->{name} cmp $b->{name} };
 176   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 177
 178   $self->controller->displayable_columns($dis_cols);
 179 }
 180
 181 sub setup_displayable_columns {
 182   my ($self) = @_;
 183
 184   foreach my $p (@{ $self->profile }) {
 185     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 186   }
 187 }
 188
 189 sub is_multiplexed { 1 }
 190
 191 1;
 192