SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise firstidx);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(SL::Controller::CsvImport::Base);
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13 'scalar --get_set_init' => [ qw(cvar_configs_by cvar_columns_by) ],
  14 );
  15
  16 sub run {
  17   my ($self, %params) = @_;
  18
  19   $self->test_run($params{test});
  20
  21   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  22
  23   my $profile = $self->profile;
  24
  25   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  26                                   encoding                => $self->controller->profile->get('charset'),
  27                                   profile                 => $profile,
  28                                   ignore_unknown_columns  => 1,
  29                                   strict_profile          => 1,
  30                                   case_insensitive_header => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   $self->controller->track_progress(progress => 10);
  35
  36   my $old_numberformat      = $::myconfig{numberformat};
  37   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  38
  39   $self->csv->parse;
  40
  41   $self->controller->track_progress(progress => 50);
  42
  43   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  44
  45   return if ( !$self->csv->header || $self->csv->errors );
  46
  47   my $headers;
  48   my $i = 0;
  49   foreach my $header (@{ $self->csv->header }) {
  50
  51     my $profile   = $self->csv->profile->[$i]->{profile};
  52     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  53
  54     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  55     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  56     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  57
  58     $headers->{$row_ident} = $h;
  59     $i++;
  60   }
  61
  62   $self->controller->headers($headers);
  63
  64   my $raw_data_headers;
  65   my $info_headers;
  66   foreach my $p (@{ $self->csv->profile }) {
  67     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  68     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  69   }
  70   $self->controller->raw_data_headers($raw_data_headers);
  71   $self->controller->info_headers($info_headers);
  72
  73   my $objects  = $self->csv->get_objects;
  74
  75   $self->controller->track_progress(progress => 70);
  76
  77   my @raw_data = @{ $self->csv->get_data };
  78
  79   $self->controller->track_progress(progress => 80);
  80
  81   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  82
  83   $self->controller->track_progress(progress => 90);
  84
  85   $self->check_objects;
  86   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  87     $self->check_std_duplicates();
  88     $self->check_duplicates();
  89   }
  90   $self->fix_field_lengths;
  91
  92   $self->controller->track_progress(progress => 100);
  93
  94   $::myconfig{numberformat} = $old_numberformat;
  95 }
  96
  97 sub init_manager_class {
  98   my ($self) = @_;
  99
 100   my @manager_classes;
 101   foreach my $class (@{ $self->class }) {
 102     $class =~ m/^SL::DB::(.+)/;
 103     push @manager_classes, "SL::DB::Manager::" . $1;
 104   }
 105   $self->manager_class(\@manager_classes);
 106 }
 107
 108 sub add_columns {
 109   my ($self, $row_ident, @columns) = @_;
 110
 111   my $h = $self->controller->headers->{$row_ident};
 112
 113   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 114     $h->{used}->{$column} = 1;
 115     push @{ $h->{methods} }, $column;
 116     push @{ $h->{headers} }, $column;
 117   }
 118 }
 119
 120 sub add_info_columns {
 121   my ($self, $row_ident, @columns) = @_;
 122
 123   my $h = $self->controller->info_headers->{$row_ident};
 124
 125   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 126     $h->{used}->{ $column->{method} } = 1;
 127     push @{ $h->{methods} }, $column->{method};
 128     push @{ $h->{headers} }, $column->{header};
 129   }
 130 }
 131
 132 sub add_raw_data_columns {
 133   my ($self, $row_ident, @columns) = @_;
 134
 135   my $h = $self->controller->raw_data_headers->{$row_ident};
 136
 137   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 138     $h->{used}->{$column} = 1;
 139     push @{ $h->{headers} }, $column;
 140   }
 141 }
 142
 143 sub add_cvar_raw_data_columns {
 144   my ($self) = @_;
 145
 146   foreach my $data (@{ $self->controller->data }) {
 147     my $ri = $data->{raw_data}->{datatype};
 148     map { $self->add_raw_data_columns($ri, $_) if exists $data->{raw_data}->{$_} } @{ $self->cvar_columns_by->{row_ident}->{$ri} };
 149   }
 150 }
 151
 152 sub init_cvar_configs_by {
 153   # Must be overridden by derived specialized importer classes.
 154   return {};
 155 }
 156
 157 sub init_cvar_columns_by {
 158   my ($self) = @_;
 159
 160   my $ccb;
 161   foreach my $p (@{ $self->profile }) {
 162     my $ri = $p->{row_ident};
 163     $ccb->{row_ident}->{$ri} = [ map { "cvar_" . $_->name } (@{ $self->cvar_configs_by->{row_ident}->{$ri} }) ];
 164   }
 165
 166   return $ccb;
 167 }
 168
 169 sub handle_cvars {
 170   my ($self, $entry, %params) = @_;
 171
 172   return if @{ $entry->{errors} };
 173   return unless $entry->{object}->can('cvars_by_config');
 174
 175   my %type_to_column = ( text      => 'text_value',
 176                          textfield => 'text_value',
 177                          htmlfield => 'text_value',
 178                          select    => 'text_value',
 179                          date      => 'timestamp_value_as_date',
 180                          timestamp => 'timestamp_value_as_date',
 181                          number    => 'number_value_as_number',
 182                          bool      => 'bool_value' );
 183
 184   $params{sub_module} ||= '';
 185
 186   # autovivify all cvars (cvars_by_config will do that for us)
 187   my @cvars;
 188   @cvars = @{ $entry->{object}->cvars_by_config };
 189
 190   foreach my $config (@{ $self->cvar_configs_by->{row_ident}->{$entry->{raw_data}->{datatype}} }) {
 191     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 192     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 193     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 194
 195     my $cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => $params{sub_module});
 196
 197     # replace autovivified cvar by new one
 198     my $idx = firstidx { $_->config_id == $config->id } @cvars;
 199     $cvars[$idx] = $cvar if -1 != $idx;
 200   }
 201
 202   $entry->{object}->custom_variables(\@cvars) if @cvars;
 203 }
 204
 205 sub init_profile {
 206   my ($self) = @_;
 207
 208   my @profile;
 209   foreach my $class (@{ $self->class }) {
 210     eval "require " . $class;
 211
 212     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 213
 214     # TODO: exceptions for AccTransaction and Invoice wh
 215     if ( $class =~ m/^SL::DB::AccTransaction/ ) {
 216       my %unwanted_acc_trans = map { ( $_ => 1 ) } (qw(acc_trans_id trans_id cleared fx_transaction ob_transaction cb_transaction itime mtime chart_link tax_id description gldate memo source transdate), map { $_->name } @{ $class->meta->primary_key_columns });
 217       @unwanted{keys %unwanted_acc_trans} = values %unwanted_acc_trans;
 218     };
 219     if ( $class =~ m/^SL::DB::Invoice/ ) {
 220       # remove fields that aren't needed / shouldn't be set for ar transaction
 221       my %unwanted_ar = map { ( $_ => 1 ) } (qw(closed currency currency_id datepaid dunning_config_id gldate invnumber_for_credit_note invoice marge_percent marge_total amount netamount paid shippingpoint shipto_id shipvia storno storno_id type cp_id), map { $_->name } @{ $class->meta->primary_key_columns });
 222       @unwanted{keys %unwanted_ar} = values %unwanted_ar;
 223     };
 224
 225     my %prof;
 226     $prof{datatype} = '';
 227     for my $col ($class->meta->columns) {
 228       next if $unwanted{$col};
 229
 230       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 231           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 232           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 233           :                                                                   $col->name;
 234
 235       $prof{$col} = $name;
 236     }
 237
 238     $prof{ 'cvar_' . $_->name } = '' for @{ $self->cvar_configs_by->{class}->{$class} };
 239
 240     $class =~ m/^SL::DB::(.+)/;
 241     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 242   }
 243
 244   \@profile;
 245 }
 246
 247 sub add_displayable_columns {
 248   my ($self, $row_ident, @columns) = @_;
 249
 250   my $dis_cols = $self->controller->displayable_columns || {};
 251
 252   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 253   my %ex_col_map = map { $_->{name} => $_ } @cols;
 254
 255   foreach my $column (@columns) {
 256     if ($ex_col_map{ $column->{name} }) {
 257       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 258     } else {
 259       push @cols, $column;
 260     }
 261   }
 262
 263   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 264                                      'datatype' eq $b->{name} ?  1 :
 265                                      $a->{name} cmp $b->{name} };
 266   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 267
 268   $self->controller->displayable_columns($dis_cols);
 269 }
 270
 271 sub setup_displayable_columns {
 272   my ($self) = @_;
 273
 274   foreach my $p (@{ $self->profile }) {
 275     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 276   }
 277 }
 278
 279 sub add_cvar_columns_to_displayable_columns {
 280   my ($self, $row_ident) = @_;
 281
 282   $self->add_displayable_columns($row_ident,
 283                                  map { { name        => 'cvar_' . $_->name,
 284                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 285                                      @{ $self->cvar_configs_by->{row_ident}->{$row_ident} });
 286 }
 287
 288 sub field_lengths {
 289   my ($self) = @_;
 290
 291   my %field_lengths_by_ri = ();
 292
 293   foreach my $p (@{ $self->profile }) {
 294     my %field_lengths = map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{ $p->{class}->meta->columns };
 295     $field_lengths_by_ri{ $p->{row_ident} } = \%field_lengths;
 296   }
 297
 298   return %field_lengths_by_ri;
 299 }
 300
 301 sub fix_field_lengths {
 302   my ($self) = @_;
 303
 304   my %field_lengths_by_ri = $self->field_lengths;
 305   foreach my $entry (@{ $self->controller->data }) {
 306     next unless defined $entry->{errors} && @{ $entry->{errors} };
 307     my %field_lengths = %{ $field_lengths_by_ri{ $entry->{raw_data}->{datatype} } };
 308     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 309   }
 310
 311   return;
 312 }
 313
 314 sub is_multiplexed { 1 }
 315
 316 1;