SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise firstidx);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(SL::Controller::CsvImport::Base);
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13 'scalar --get_set_init' => [ qw(cvar_configs_by cvar_columns_by) ],
  14 );
  15
  16 sub run {
  17   my ($self, %params) = @_;
  18
  19   $self->test_run($params{test});
  20
  21   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  22
  23   my $profile = $self->profile;
  24
  25   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  26                                   encoding                => $self->controller->profile->get('charset'),
  27                                   profile                 => $profile,
  28                                   ignore_unknown_columns  => 1,
  29                                   strict_profile          => 1,
  30                                   case_insensitive_header => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   $self->controller->track_progress(progress => 10);
  35
  36   my $old_numberformat      = $::myconfig{numberformat};
  37   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  38
  39   $self->csv->parse;
  40
  41   $self->controller->track_progress(progress => 50);
  42
  43   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  44
  45   return if ( !$self->csv->header || $self->csv->errors );
  46
  47   my $headers;
  48   my $i = 0;
  49   foreach my $header (@{ $self->csv->header }) {
  50
  51     my $profile   = $self->csv->profile->[$i]->{profile};
  52     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  53
  54     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  55     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  56     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  57
  58     $headers->{$row_ident} = $h;
  59     $i++;
  60   }
  61
  62   $self->controller->headers($headers);
  63
  64   my $raw_data_headers;
  65   my $info_headers;
  66   foreach my $p (@{ $self->csv->profile }) {
  67     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  68     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  69   }
  70   $self->controller->raw_data_headers($raw_data_headers);
  71   $self->controller->info_headers($info_headers);
  72
  73   my $objects  = $self->csv->get_objects;
  74
  75   $self->controller->track_progress(progress => 70);
  76
  77   my @raw_data = @{ $self->csv->get_data };
  78
  79   $self->controller->track_progress(progress => 80);
  80
  81   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  82
  83   $self->controller->track_progress(progress => 90);
  84
  85   $self->check_objects;
  86   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  87     $self->check_std_duplicates();
  88     $self->check_duplicates();
  89   }
  90   $self->fix_field_lengths;
  91
  92   $self->controller->track_progress(progress => 100);
  93
  94   $::myconfig{numberformat} = $old_numberformat;
  95 }
  96
  97 sub add_columns {
  98   my ($self, $row_ident, @columns) = @_;
  99
 100   my $h = $self->controller->headers->{$row_ident};
 101
 102   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 103     $h->{used}->{$column} = 1;
 104     push @{ $h->{methods} }, $column;
 105     push @{ $h->{headers} }, $column;
 106   }
 107 }
 108
 109 sub add_info_columns {
 110   my ($self, $row_ident, @columns) = @_;
 111
 112   my $h = $self->controller->info_headers->{$row_ident};
 113
 114   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 115     $h->{used}->{ $column->{method} } = 1;
 116     push @{ $h->{methods} }, $column->{method};
 117     push @{ $h->{headers} }, $column->{header};
 118   }
 119 }
 120
 121 sub add_raw_data_columns {
 122   my ($self, $row_ident, @columns) = @_;
 123
 124   my $h = $self->controller->raw_data_headers->{$row_ident};
 125
 126   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 127     $h->{used}->{$column} = 1;
 128     push @{ $h->{headers} }, $column;
 129   }
 130 }
 131
 132 sub add_cvar_raw_data_columns {
 133   my ($self) = @_;
 134
 135   foreach my $data (@{ $self->controller->data }) {
 136     my $ri = $data->{raw_data}->{datatype};
 137     map { $self->add_raw_data_columns($ri, $_) if exists $data->{raw_data}->{$_} } @{ $self->cvar_columns_by->{row_ident}->{$ri} };
 138   }
 139 }
 140
 141 sub init_cvar_configs_by {
 142   # Must be overridden by derived specialized importer classes.
 143   return {};
 144 }
 145
 146 sub init_cvar_columns_by {
 147   my ($self) = @_;
 148
 149   my $ccb;
 150   foreach my $p (@{ $self->profile }) {
 151     my $ri = $p->{row_ident};
 152     $ccb->{row_ident}->{$ri} = [ map { "cvar_" . $_->name } (@{ $self->cvar_configs_by->{row_ident}->{$ri} }) ];
 153   }
 154
 155   return $ccb;
 156 }
 157
 158 sub handle_cvars {
 159   my ($self, $entry, %params) = @_;
 160
 161   return if @{ $entry->{errors} };
 162
 163   my %type_to_column = ( text      => 'text_value',
 164                          textfield => 'text_value',
 165                          select    => 'text_value',
 166                          date      => 'timestamp_value_as_date',
 167                          timestamp => 'timestamp_value_as_date',
 168                          number    => 'number_value_as_number',
 169                          bool      => 'bool_value' );
 170
 171   $params{sub_module} ||= '';
 172
 173   # autovivify all cvars (cvars_by_config will do that for us)
 174   my @cvars;
 175   @cvars = @{ $entry->{object}->cvars_by_config } if $entry->{object}->can('cvars_by_config');
 176
 177   foreach my $config (@{ $self->cvar_configs_by->{row_ident}->{$entry->{raw_data}->{datatype}} }) {
 178     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 179     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 180     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 181
 182     my $cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => $params{sub_module});
 183
 184     # replace autovivified cvar by new one
 185     my $idx = firstidx { $_->config_id == $config->id } @cvars;
 186     $cvars[$idx] = $cvar if -1 != $idx;
 187   }
 188
 189   $entry->{object}->custom_variables(\@cvars) if @cvars;
 190 }
 191
 192 sub init_profile {
 193   my ($self) = @_;
 194
 195   my @profile;
 196   foreach my $class (@{ $self->class }) {
 197     eval "require " . $class;
 198
 199     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 200
 201     # TODO: exceptions for AccTransaction and Invoice wh
 202     if ( $class =~ m/^SL::DB::AccTransaction/ ) {
 203       my %unwanted_acc_trans = map { ( $_ => 1 ) } (qw(acc_trans_id trans_id cleared fx_transaction ob_transaction cb_transaction itime mtime chart_link tax_id description gldate memo source transdate), map { $_->name } @{ $class->meta->primary_key_columns });
 204       @unwanted{keys %unwanted_acc_trans} = values %unwanted_acc_trans;
 205     };
 206     if ( $class =~ m/^SL::DB::Invoice/ ) {
 207       # remove fields that aren't needed / shouldn't be set for ar transaction
 208       my %unwanted_ar = map { ( $_ => 1 ) } (qw(closed currency currency_id datepaid dunning_config_id gldate invnumber_for_credit_note invoice marge_percent marge_total amount netamount paid shippingpoint shipto_id shipvia storno storno_id type cp_id), map { $_->name } @{ $class->meta->primary_key_columns });
 209       @unwanted{keys %unwanted_ar} = values %unwanted_ar;
 210     };
 211
 212     my %prof;
 213     $prof{datatype} = '';
 214     for my $col ($class->meta->columns) {
 215       next if $unwanted{$col};
 216
 217       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 218           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 219           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 220           :                                                                   $col->name;
 221
 222       $prof{$col} = $name;
 223     }
 224
 225     $prof{ 'cvar_' . $_->name } = '' for @{ $self->cvar_configs_by->{class}->{$class} };
 226
 227     $class =~ m/^SL::DB::(.+)/;
 228     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 229   }
 230
 231   \@profile;
 232 }
 233
 234 sub add_displayable_columns {
 235   my ($self, $row_ident, @columns) = @_;
 236
 237   my $dis_cols = $self->controller->displayable_columns || {};
 238
 239   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 240   my %ex_col_map = map { $_->{name} => $_ } @cols;
 241
 242   foreach my $column (@columns) {
 243     if ($ex_col_map{ $column->{name} }) {
 244       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 245     } else {
 246       push @cols, $column;
 247     }
 248   }
 249
 250   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 251                                      'datatype' eq $b->{name} ?  1 :
 252                                      $a->{name} cmp $b->{name} };
 253   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 254
 255   $self->controller->displayable_columns($dis_cols);
 256 }
 257
 258 sub setup_displayable_columns {
 259   my ($self) = @_;
 260
 261   foreach my $p (@{ $self->profile }) {
 262     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 263   }
 264 }
 265
 266 sub add_cvar_columns_to_displayable_columns {
 267   my ($self, $row_ident) = @_;
 268
 269   $self->add_displayable_columns($row_ident,
 270                                  map { { name        => 'cvar_' . $_->name,
 271                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 272                                      @{ $self->cvar_configs_by->{row_ident}->{$row_ident} });
 273 }
 274
 275 sub field_lengths {
 276   my ($self) = @_;
 277
 278   my %field_lengths_by_ri = ();
 279
 280   foreach my $p (@{ $self->profile }) {
 281     my %field_lengths = map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{ $p->{class}->meta->columns };
 282     $field_lengths_by_ri{ $p->{row_ident} } = \%field_lengths;
 283   }
 284
 285   return %field_lengths_by_ri;
 286 }
 287
 288 sub fix_field_lengths {
 289   my ($self) = @_;
 290
 291   my %field_lengths_by_ri = $self->field_lengths;
 292   foreach my $entry (@{ $self->controller->data }) {
 293     next unless defined $entry->{errors} && @{ $entry->{errors} };
 294     my %field_lengths = %{ $field_lengths_by_ri{ $entry->{raw_data}->{datatype} } };
 295     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 296   }
 297
 298   return;
 299 }
 300
 301 sub is_multiplexed { 1 }
 302
 303 1;