SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(SL::Controller::CsvImport::Base);
  15
  16 sub run {
  17   my ($self, %params) = @_;
  18
  19   $self->test_run($params{test_run});
  20
  21   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  22
  23   my $profile = $self->profile;
  24
  25   $self->csv(SL::Helper::Csv->new(file                    => $self->file->file_name,
  26                                   encoding                => $self->controller->profile->get('charset'),
  27                                   profile                 => $profile,
  28                                   ignore_unknown_columns  => 1,
  29                                   strict_profile          => 1,
  30                                   case_insensitive_header => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   $self->controller->track_progress(progress => 10);
  35
  36   my $old_numberformat      = $::myconfig{numberformat};
  37   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  38
  39   $self->csv->parse;
  40
  41   $self->controller->track_progress(progress => 50);
  42
  43   # bb: make sanity-check of it?
  44   #if ($self->csv->is_multiplexed != $self->is_multiplexed) {
  45   #  die "multiplex controller on simplex data or vice versa";
  46   #}
  47
  48   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  49
  50   return if ( !$self->csv->header || $self->csv->errors );
  51
  52   my $headers;
  53   my $i = 0;
  54   foreach my $header (@{ $self->csv->header }) {
  55
  56     my $profile   = $self->csv->profile->[$i]->{profile};
  57     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  58
  59     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  60     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  61     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  62
  63     $headers->{$row_ident} = $h;
  64     $i++;
  65   }
  66
  67   $self->controller->headers($headers);
  68
  69   my $raw_data_headers;
  70   my $info_headers;
  71   foreach my $p (@{ $self->csv->profile }) {
  72     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  73     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  74   }
  75   $self->controller->raw_data_headers($raw_data_headers);
  76   $self->controller->info_headers($info_headers);
  77
  78   my @objects  = $self->csv->get_objects;
  79   $self->controller->track_progress(progress => 70);
  80
  81   my @raw_data = @{ $self->csv->get_data };
  82
  83   $self->controller->track_progress(progress => 80);
  84
  85   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  86
  87   $self->controller->track_progress(progress => 90);
  88
  89   $self->check_objects;
  90   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  91     $self->check_std_duplicates();
  92     $self->check_duplicates();
  93   }
  94   $self->fix_field_lengths;
  95
  96   $self->controller->track_progress(progress => 100);
  97
  98   $::myconfig{numberformat} = $old_numberformat;
  99 }
 100
 101 sub add_columns {
 102   my ($self, $row_ident, @columns) = @_;
 103
 104   my $h = $self->controller->headers->{$row_ident};
 105
 106   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 107     $h->{used}->{$column} = 1;
 108     push @{ $h->{methods} }, $column;
 109     push @{ $h->{headers} }, $column;
 110   }
 111 }
 112
 113 sub add_info_columns {
 114   my ($self, $row_ident, @columns) = @_;
 115
 116   my $h = $self->controller->info_headers->{$row_ident};
 117
 118   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 119     $h->{used}->{ $column->{method} } = 1;
 120     push @{ $h->{methods} }, $column->{method};
 121     push @{ $h->{headers} }, $column->{header};
 122   }
 123 }
 124
 125 sub add_raw_data_columns {
 126   my ($self, $row_ident, @columns) = @_;
 127
 128   my $h = $self->controller->raw_data_headers->{$row_ident};
 129
 130   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 131     $h->{used}->{$column} = 1;
 132     push @{ $h->{headers} }, $column;
 133   }
 134 }
 135
 136 sub add_cvar_raw_data_columns {
 137   my ($self) = @_;
 138
 139   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 140 }
 141
 142 sub init_profile {
 143   my ($self) = @_;
 144
 145   my @profile;
 146   foreach my $class (@{ $self->class }) {
 147     eval "require " . $class;
 148
 149     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 150     my %prof;
 151     $prof{datatype} = '';
 152     for my $col ($class->meta->columns) {
 153       next if $unwanted{$col};
 154
 155       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 156           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 157           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 158           :                                                                   $col->name;
 159
 160       $prof{$col} = $name;
 161     }
 162
 163     $prof{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 164
 165     $class =~ m/^SL::DB::(.+)/;
 166     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 167   }
 168
 169   \@profile;
 170 }
 171
 172 sub add_displayable_columns {
 173   my ($self, $row_ident, @columns) = @_;
 174
 175   my $dis_cols = $self->controller->displayable_columns || {};
 176
 177   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 178   my %ex_col_map = map { $_->{name} => $_ } @cols;
 179
 180   foreach my $column (@columns) {
 181     if ($ex_col_map{ $column->{name} }) {
 182       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 183     } else {
 184       push @cols, $column;
 185     }
 186   }
 187
 188   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 189                                      'datatype' eq $b->{name} ?  1 :
 190                                      $a->{name} cmp $b->{name} };
 191   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 192
 193   $self->controller->displayable_columns($dis_cols);
 194 }
 195
 196 sub setup_displayable_columns {
 197   my ($self) = @_;
 198
 199   foreach my $p (@{ $self->profile }) {
 200     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 201   }
 202 }
 203
 204 sub add_cvar_columns_to_displayable_columns {
 205   my ($self) = @_;
 206
 207   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 208                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 209                                      @{ $self->all_cvar_configs });
 210 }
 211
 212 sub init_existing_objects {
 213   my ($self) = @_;
 214
 215   eval "require " . $self->class;
 216   $self->existing_objects($self->manager_class->get_all);
 217 }
 218
 219 sub init_class {
 220   die "class not set";
 221 }
 222
 223 sub init_manager_class {
 224   my ($self) = @_;
 225
 226   $self->class =~ m/^SL::DB::(.+)/;
 227   $self->manager_class("SL::DB::Manager::" . $1);
 228 }
 229
 230 sub is_multiplexed { 1 }
 231
 232 1;
 233