SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(SL::Controller::CsvImport::Base);
  10
  11 sub run {
  12   my ($self, %params) = @_;
  13
  14   $self->test_run($params{test_run});
  15
  16   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  17
  18   my $profile = $self->profile;
  19
  20   $self->csv(SL::Helper::Csv->new(file                    => $self->file->file_name,
  21                                   encoding                => $self->controller->profile->get('charset'),
  22                                   profile                 => $profile,
  23                                   ignore_unknown_columns  => 1,
  24                                   strict_profile          => 1,
  25                                   case_insensitive_header => 1,
  26                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  27                                  ));
  28
  29   $self->controller->track_progress(progress => 10);
  30
  31   my $old_numberformat      = $::myconfig{numberformat};
  32   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  33
  34   $self->csv->parse;
  35
  36   $self->controller->track_progress(progress => 50);
  37
  38   # bb: make sanity-check of it?
  39   #if ($self->csv->is_multiplexed != $self->is_multiplexed) {
  40   #  die "multiplex controller on simplex data or vice versa";
  41   #}
  42
  43   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  44
  45   return if ( !$self->csv->header || $self->csv->errors );
  46
  47   my $headers;
  48   my $i = 0;
  49   foreach my $header (@{ $self->csv->header }) {
  50
  51     my $profile   = $self->csv->profile->[$i]->{profile};
  52     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  53
  54     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  55     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  56     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  57
  58     $headers->{$row_ident} = $h;
  59     $i++;
  60   }
  61
  62   $self->controller->headers($headers);
  63
  64   my $raw_data_headers;
  65   my $info_headers;
  66   foreach my $p (@{ $self->csv->profile }) {
  67     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  68     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  69   }
  70   $self->controller->raw_data_headers($raw_data_headers);
  71   $self->controller->info_headers($info_headers);
  72
  73   my @objects  = $self->csv->get_objects;
  74
  75   $self->controller->track_progress(progress => 70);
  76
  77   my @raw_data = @{ $self->csv->get_data };
  78
  79   $self->controller->track_progress(progress => 80);
  80
  81   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  82
  83   $self->controller->track_progress(progress => 90);
  84
  85   $self->check_objects;
  86   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  87     $self->check_std_duplicates();
  88     $self->check_duplicates();
  89   }
  90   $self->fix_field_lengths;
  91
  92   $self->controller->track_progress(progress => 100);
  93
  94   $::myconfig{numberformat} = $old_numberformat;
  95 }
  96
  97 sub add_columns {
  98   my ($self, $row_ident, @columns) = @_;
  99
 100   my $h = $self->controller->headers->{$row_ident};
 101
 102   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 103     $h->{used}->{$column} = 1;
 104     push @{ $h->{methods} }, $column;
 105     push @{ $h->{headers} }, $column;
 106   }
 107 }
 108
 109 sub add_info_columns {
 110   my ($self, $row_ident, @columns) = @_;
 111
 112   my $h = $self->controller->info_headers->{$row_ident};
 113
 114   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 115     $h->{used}->{ $column->{method} } = 1;
 116     push @{ $h->{methods} }, $column->{method};
 117     push @{ $h->{headers} }, $column->{header};
 118   }
 119 }
 120
 121 sub add_raw_data_columns {
 122   my ($self, $row_ident, @columns) = @_;
 123
 124   my $h = $self->controller->raw_data_headers->{$row_ident};
 125
 126   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 127     $h->{used}->{$column} = 1;
 128     push @{ $h->{headers} }, $column;
 129   }
 130 }
 131
 132 sub init_profile {
 133   my ($self) = @_;
 134
 135   my @profile;
 136   foreach my $class (@{ $self->class }) {
 137     eval "require " . $class;
 138
 139     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 140     my %prof;
 141     $prof{datatype} = '';
 142     for my $col ($class->meta->columns) {
 143       next if $unwanted{$col};
 144
 145       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 146           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 147           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 148           :                                                                   $col->name;
 149
 150       $prof{$col} = $name;
 151     }
 152
 153     $prof{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 154
 155     $class =~ m/^SL::DB::(.+)/;
 156     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 157   }
 158
 159   \@profile;
 160 }
 161
 162 sub add_displayable_columns {
 163   my ($self, $row_ident, @columns) = @_;
 164
 165   my $dis_cols = $self->controller->displayable_columns || {};
 166
 167   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 168   my %ex_col_map = map { $_->{name} => $_ } @cols;
 169
 170   foreach my $column (@columns) {
 171     if ($ex_col_map{ $column->{name} }) {
 172       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 173     } else {
 174       push @cols, $column;
 175     }
 176   }
 177
 178   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 179                                      'datatype' eq $b->{name} ?  1 :
 180                                      $a->{name} cmp $b->{name} };
 181   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 182
 183   $self->controller->displayable_columns($dis_cols);
 184 }
 185
 186 sub setup_displayable_columns {
 187   my ($self) = @_;
 188
 189   foreach my $p (@{ $self->profile }) {
 190     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 191   }
 192 }
 193
 194 sub is_multiplexed { 1 }
 195
 196 1;
 197