SL/Controller/CsvImport/Contact.pm

   1 package SL::Controller::CsvImport::Contact;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6
   7 use parent qw(SL::Controller::CsvImport::Base);
   8
   9 use Rose::Object::MakeMethods::Generic
  10 (
  11  scalar                  => [ qw(table) ],
  12  'scalar --get_set_init' => [ qw(all_vc) ],
  13 );
  14
  15 sub init_class {
  16   my ($self) = @_;
  17   $self->class('SL::DB::Contact');
  18 }
  19
  20 sub init_all_vc {
  21   my ($self) = @_;
  22
  23   $self->all_vc({ customers => SL::DB::Manager::Customer->get_all(with_objects => [ 'contacts' ]),
  24                   vendors   => SL::DB::Manager::Vendor->get_all(  with_objects => [ 'contacts' ]) });
  25 }
  26
  27 sub check_objects {
  28   my ($self) = @_;
  29
  30   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
  31   my %by_number = ( customers => { map { ( $_->customernumber => $_->id ) } @{ $self->all_vc->{customers} } },
  32                     vendors   => { map { ( $_->vendornumber   => $_->id ) } @{ $self->all_vc->{vendors}   } } );
  33   my %by_name   = ( customers => { map { ( $_->name           => $_->id ) } @{ $self->all_vc->{customers} } },
  34                     vendors   => { map { ( $_->name           => $_->id ) } @{ $self->all_vc->{vendors}   } } );
  35
  36   foreach my $entry (@{ $self->controller->data }) {
  37     my $object   = $entry->{object};
  38     my $raw_data = $entry->{raw_data};
  39
  40     my $name     =  $object->cp_name;
  41     $name        =~ s/^\s+//;
  42     $name        =~ s/\s+$//;
  43
  44     if (!$name) {
  45       push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
  46       next;
  47     }
  48
  49     if ($object->cp_cv_id) {
  50       $object->cp_cv_id(undef) if !$by_id{ $object->cp_cv_id };
  51     }
  52
  53     if (!$object->cp_cv_id) {
  54       my $vc_id = $by_number{customers}->{ $raw_data->{customernumber} } || $by_number{vendors}->{ $raw_data->{vendornumber} };
  55       $object->cp_cv_id($vc_id) if $vc_id;
  56     }
  57
  58     if (!$object->cp_cv_id) {
  59       my $vc_id = $by_name{customers}->{ $raw_data->{customer} } || $by_name{vendors}->{ $raw_data->{vendor} };
  60       $object->cp_cv_id($vc_id) if $vc_id;
  61     }
  62
  63     if (!$object->cp_cv_id) {
  64       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
  65       next;
  66     }
  67
  68     $entry->{vc} = $by_id{ $object->cp_cv_id };
  69
  70     if (($object->cp_gender ne 'm') && ($object->cp_gender ne 'f')) {
  71       push @{ $entry->{errors} }, $::locale->text('Error: Gender (cp_gender) missing or invalid');
  72       next;
  73     }
  74   }
  75 }
  76
  77 sub check_duplicates {
  78   my ($self, %params) = @_;
  79
  80   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
  81
  82   my %by_id_and_name;
  83   if ('check_db' eq $self->controller->profile->get('duplicates')) {
  84     foreach my $type (qw(customers vendors)) {
  85       foreach my $vc (@{ $self->all_vc->{$type} }) {
  86         $by_id_and_name{ $vc->id } = { map { ( $normalizer->($_->cp_name) => 'db' ) } @{ $vc->contacts } };
  87       }
  88     }
  89   }
  90
  91   foreach my $entry (@{ $self->controller->data }) {
  92     next if @{ $entry->{errors} };
  93
  94     my $name = $normalizer->($entry->{object}->cp_name);
  95
  96     $by_id_and_name{ $entry->{vc}->id } ||= { };
  97     if (!$by_id_and_name{ $entry->{vc}->id }->{ $name }) {
  98       $by_id_and_name{ $entry->{vc}->id }->{ $name } = 'csv';
  99
 100     } else {
 101       push @{ $entry->{errors} }, $by_id_and_name{ $entry->{vc}->id }->{ $name } eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
 102     }
 103   }
 104 }
 105
 106 sub field_lengths {
 107   return ( cp_title     => 75,
 108            cp_givenname => 75,
 109            cp_name      => 75,
 110            cp_phone1    => 75,
 111            cp_phone2    => 75,
 112            cp_gender    =>  1,
 113          );
 114 }
 115
 116 sub setup_displayable_columns {
 117   my ($self) = @_;
 118
 119   $self->SUPER::setup_displayable_columns;
 120
 121   $self->add_displayable_columns({ name => 'cp_abteilung',   description => $::locale->text('Department')                    },
 122                                  { name => 'cp_birthday',    description => $::locale->text('Birthday')                      },
 123                                  { name => 'cp_cv_id',       description => $::locale->text('Customer/Vendor (database ID)') },
 124                                  { name => 'cp_email',       description => $::locale->text('E-mail')                        },
 125                                  { name => 'cp_fax',         description => $::locale->text('Fax')                           },
 126                                  { name => 'cp_gender',      description => $::locale->text('Gender')                        },
 127                                  { name => 'cp_givenname',   description => $::locale->text('Given Name')                    },
 128                                  { name => 'cp_mobile1',     description => $::locale->text('Mobile1')                       },
 129                                  { name => 'cp_mobile2',     description => $::locale->text('Mobile2')                       },
 130                                  { name => 'cp_name',        description => $::locale->text('Name')                          },
 131                                  { name => 'cp_phone1',      description => $::locale->text('Phone1')                        },
 132                                  { name => 'cp_phone2',      description => $::locale->text('Phone2')                        },
 133                                  { name => 'cp_privatemail', description => $::locale->text('Private E-mail')                },
 134                                  { name => 'cp_privatphone', description => $::locale->text('Private Phone')                 },
 135                                  { name => 'cp_project',     description => $::locale->text('Project')                       },
 136                                  { name => 'cp_satfax',      description => $::locale->text('Sat. Fax')                      },
 137                                  { name => 'cp_satphone',    description => $::locale->text('Sat. Phone')                    },
 138                                  { name => 'cp_title',       description => $::locale->text('Title')                         },
 139
 140                                  { name => 'customer',       description => $::locale->text('Customer (name)')               },
 141                                  { name => 'customernumber', description => $::locale->text('Customer Number')               },
 142                                  { name => 'vendor',         description => $::locale->text('Vendor (name)')                 },
 143                                  { name => 'vendornumber',   description => $::locale->text('Vendor Number')                 },
 144                                 );
 145 }
 146
 147 1;