SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Controller::CsvImport::Helper::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PaymentTerm;
  11 use SL::TransNumber;
  12
  13 use parent qw(SL::Controller::CsvImport::Base);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  18 );
  19
  20 sub init_table {
  21   my ($self) = @_;
  22   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  23 }
  24
  25 sub init_class {
  26   my ($self) = @_;
  27   $self->class('SL::DB::' . ucfirst($self->table));
  28 }
  29
  30 sub init_all_cvar_configs {
  31   my ($self) = @_;
  32
  33   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  34 }
  35
  36 sub init_businesses_by {
  37   my ($self) = @_;
  38
  39   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  40 }
  41
  42 sub init_languages_by {
  43   my ($self) = @_;
  44
  45   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  46 }
  47
  48 sub check_objects {
  49   my ($self) = @_;
  50
  51   $self->controller->track_progress(phase => 'building data', progress => 0);
  52
  53   my $vc            = $self->controller->profile->get('table');
  54   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  55   my $numbercolumn  = "${vc}number";
  56   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  57   my $methods       = $self->controller->headers->{methods};
  58
  59   my $i;
  60   my $num_data = scalar @{ $self->controller->data };
  61   foreach my $entry (@{ $self->controller->data }) {
  62     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  63     my $object = $entry->{object};
  64
  65     $self->check_name($entry);
  66     $self->check_language($entry);
  67     $self->check_business($entry);
  68     $self->check_payment($entry);
  69     $self->check_delivery_term($entry);
  70     $self->check_taxzone($entry,  take_default => 1);
  71     $self->check_currency($entry, take_default => 1);
  72     $self->handle_cvars($entry);
  73
  74     next if @{ $entry->{errors} };
  75
  76     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country contact phone fax homepage email cc bcc
  77                                                                      taxnumber account_number bank_code bank username greeting taxzone));
  78
  79     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  80       if @cleaned_fields;
  81
  82     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  83     if (!$existing_vc) {
  84       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  85
  86     } elsif ($update_policy eq 'skip') {
  87       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
  88
  89     } elsif ($update_policy eq 'update_existing') {
  90       # Update existing customer/vendor records.
  91       $entry->{object_to_save} = $existing_vc;
  92
  93       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
  94
  95       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
  96
  97     } else {
  98       $object->$numbercolumn('####');
  99     }
 100   } continue {
 101     $i++;
 102   }
 103
 104   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment delivery_term taxzone));
 105   $self->add_cvar_raw_data_columns;
 106 }
 107
 108 sub get_duplicate_check_fields {
 109   return {
 110     name => {
 111       label     => $::locale->text('Customer Name'),
 112       default   => 1,
 113       maker     => sub {
 114         my $name = shift->name;
 115         $name =~ s/[\s,\.\-]//g;
 116         return $name;
 117       }
 118     },
 119   };
 120 }
 121
 122 sub check_name {
 123   my ($self, $entry) = @_;
 124
 125   my $name =  $entry->{object}->name;
 126   $name    =~ s/^\s+//;
 127   $name    =~ s/\s+$//;
 128
 129   return 1 if $name;
 130
 131   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 132   return 0;
 133 }
 134
 135 sub check_language {
 136   my ($self, $entry) = @_;
 137
 138   my $object = $entry->{object};
 139
 140   # Check whether or not language ID is valid.
 141   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 142     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 143     return 0;
 144   }
 145
 146   # Map name to ID if given.
 147   if (!$object->language_id && $entry->{raw_data}->{language}) {
 148     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 149                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 150
 151     if (!$language) {
 152       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 153       return 0;
 154     }
 155
 156     $object->language_id($language->id);
 157
 158     # register language_id for method copying later
 159     $self->clone_methods->{language_id} = 1;
 160   }
 161
 162   return 1;
 163 }
 164
 165 sub check_business {
 166   my ($self, $entry) = @_;
 167
 168   my $object = $entry->{object};
 169
 170   # Check whether or not business ID is valid.
 171   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 172     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 173     return 0;
 174   }
 175
 176   # Map name to ID if given.
 177   if (!$object->business_id && $entry->{raw_data}->{business}) {
 178     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 179
 180     if (!$business) {
 181       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 182       return 0;
 183     }
 184
 185     $object->business_id($business->id);
 186
 187     # register business_id for method copying later
 188     $self->clone_methods->{business_id} = 1;
 189   }
 190
 191   return 1;
 192 }
 193
 194 sub save_objects {
 195   my ($self, %params) = @_;
 196
 197   my $numbercolumn   = $self->table . 'number';
 198   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 199   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 200
 201   foreach my $entry (@{$with_number}, @{$without_number}) {
 202     my $object = $entry->{object};
 203
 204     my $number = SL::TransNumber->new(type        => $self->table(),
 205                                       number      => $object->$numbercolumn(),
 206                                       business_id => $object->business_id(),
 207                                       save        => 1);
 208
 209     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 210       $object->$numbercolumn($number->create_unique());
 211     }
 212   }
 213
 214   $self->SUPER::save_objects(data => $with_number);
 215   $self->SUPER::save_objects(data => $without_number);
 216 }
 217
 218 sub init_profile {
 219   my ($self) = @_;
 220
 221   my $profile = $self->SUPER::init_profile;
 222   delete @{$profile}{qw(business datevexport language payment delivery_term salesman salesman_id taxincluded terms)};
 223
 224   return $profile;
 225 }
 226
 227 sub setup_displayable_columns {
 228   my ($self) = @_;
 229
 230   $self->SUPER::setup_displayable_columns;
 231   $self->add_cvar_columns_to_displayable_columns;
 232
 233   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 234                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 235                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 236                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 237                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 238                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 239                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 240                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 241                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 242                                  { name => 'city',              description => $::locale->text('City')                            },
 243                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 244                                  { name => 'country',           description => $::locale->text('Country')                         },
 245                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 246                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 247                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 248                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 249                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 250                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 251                                  { name => 'delivery_term_id',  description => $::locale->text('Delivery terms (database ID)')    },
 252                                  { name => 'delivery_term',     description => $::locale->text('Delivery terms (name)')           },
 253                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 254                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 255                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 256                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 257                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 258                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 259                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 260                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 261                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 262                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 263                                  { name => 'name',              description => $::locale->text('Name')                            },
 264                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 265                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 266                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 267                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 268                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 269                                  { name => 'street',            description => $::locale->text('Street')                          },
 270                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 271                                  { name => 'taxzone',           description => $::locale->text('Tax zone (description)')          },
 272                                  { name => 'taxzone_id',        description => $::locale->text('Tax zone (database ID)')          },
 273                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 274                                  { name => 'username',          description => $::locale->text('Username')                        },
 275                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 276                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 277                                 );
 278 }
 279
 280 # TODO:
 281 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 282
 283 1;