SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Helper::Csv::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PaymentTerm;
  11 use SL::TransNumber;
  12
  13 use parent qw(SL::Controller::CsvImport::Base);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  18 );
  19
  20 sub init_table {
  21   my ($self) = @_;
  22   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  23 }
  24
  25 sub init_class {
  26   my ($self) = @_;
  27   $self->class('SL::DB::' . ucfirst($self->table));
  28 }
  29
  30 sub init_all_cvar_configs {
  31   my ($self) = @_;
  32
  33   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  34 }
  35
  36 sub init_businesses_by {
  37   my ($self) = @_;
  38
  39   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  40 }
  41
  42 sub init_languages_by {
  43   my ($self) = @_;
  44
  45   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  46 }
  47
  48 sub check_objects {
  49   my ($self) = @_;
  50
  51   $self->controller->track_progress(phase => 'building data', progress => 0);
  52
  53   my $vc            = $self->controller->profile->get('table');
  54   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  55   my $numbercolumn  = "${vc}number";
  56   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  57   my $methods       = $self->controller->headers->{methods};
  58
  59   my $i;
  60   my $num_data = scalar @{ $self->controller->data };
  61   foreach my $entry (@{ $self->controller->data }) {
  62     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  63     my $object = $entry->{object};
  64
  65     $self->check_name($entry);
  66     $self->check_language($entry);
  67     $self->check_business($entry);
  68     $self->check_payment($entry);
  69     SL::Helper::Csv::Consistency->check_currency($entry, take_default => 1);
  70     $self->handle_cvars($entry);
  71
  72     next if @{ $entry->{errors} };
  73
  74     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country contact phone fax homepage email cc bcc
  75                                                                      taxnumber account_number bank_code bank username greeting));
  76
  77     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  78       if @cleaned_fields;
  79
  80     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  81     if (!$existing_vc) {
  82       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  83
  84     } elsif ($update_policy eq 'skip') {
  85       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
  86
  87     } elsif ($update_policy eq 'update_existing') {
  88       # Update existing customer/vendor records.
  89       $entry->{object_to_save} = $existing_vc;
  90
  91       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods };
  92
  93       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
  94
  95     } else {
  96       $object->$numbercolumn('####');
  97     }
  98   } continue {
  99     $i++;
 100   }
 101
 102   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
 103   $self->add_cvar_raw_data_columns;
 104 }
 105
 106 sub get_duplicate_check_fields {
 107   return {
 108     name => {
 109       label     => $::locale->text('Customer Name'),
 110       default   => 1,
 111       maker     => sub {
 112         my $name = shift->name;
 113         $name =~ s/[\s,\.\-]//g;
 114         return $name;
 115       }
 116     },
 117   };
 118 }
 119
 120 sub check_name {
 121   my ($self, $entry) = @_;
 122
 123   my $name =  $entry->{object}->name;
 124   $name    =~ s/^\s+//;
 125   $name    =~ s/\s+$//;
 126
 127   return 1 if $name;
 128
 129   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 130   return 0;
 131 }
 132
 133 sub check_language {
 134   my ($self, $entry) = @_;
 135
 136   my $object = $entry->{object};
 137
 138   # Check whether or not language ID is valid.
 139   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 140     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 141     return 0;
 142   }
 143
 144   # Map name to ID if given.
 145   if (!$object->language_id && $entry->{raw_data}->{language}) {
 146     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 147                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 148
 149     if (!$language) {
 150       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 151       return 0;
 152     }
 153
 154     $object->language_id($language->id);
 155   }
 156
 157   return 1;
 158 }
 159
 160 sub check_business {
 161   my ($self, $entry) = @_;
 162
 163   my $object = $entry->{object};
 164
 165   # Check whether or not business ID is valid.
 166   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 167     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 168     return 0;
 169   }
 170
 171   # Map name to ID if given.
 172   if (!$object->business_id && $entry->{raw_data}->{business}) {
 173     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 174
 175     if (!$business) {
 176       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 177       return 0;
 178     }
 179
 180     $object->business_id($business->id);
 181   }
 182
 183   return 1;
 184 }
 185
 186 sub save_objects {
 187   my ($self, %params) = @_;
 188
 189   my $numbercolumn   = $self->table . 'number';
 190   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 191   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 192
 193   foreach my $entry (@{$with_number}, @{$without_number}) {
 194     my $object = $entry->{object};
 195
 196     my $number = SL::TransNumber->new(type        => $self->table(),
 197                                       number      => $object->$numbercolumn(),
 198                                       business_id => $object->business_id(),
 199                                       save        => 1);
 200
 201     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 202       $object->$numbercolumn($number->create_unique());
 203     }
 204   }
 205
 206   $self->SUPER::save_objects(data => $with_number);
 207   $self->SUPER::save_objects(data => $without_number);
 208 }
 209
 210 sub field_lengths {
 211   return ( name           => 75,
 212            department_1   => 75,
 213            department_2   => 75,
 214            street         => 75,
 215            zipcode        => 10,
 216            city           => 75,
 217            country        => 75,
 218            contact        => 75,
 219            fax            => 30,
 220            account_number => 15,
 221            bank_code      => 10,
 222            language       => 5,
 223            username       => 50,
 224            ustid          => 14,
 225            iban           => 100,
 226            bic            => 100,
 227          );
 228 }
 229
 230 sub init_profile {
 231   my ($self) = @_;
 232
 233   my $profile = $self->SUPER::init_profile;
 234   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 235
 236   return $profile;
 237 }
 238
 239 sub setup_displayable_columns {
 240   my ($self) = @_;
 241
 242   $self->SUPER::setup_displayable_columns;
 243   $self->add_cvar_columns_to_displayable_columns;
 244
 245   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 246                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 247                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 248                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 249                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 250                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 251                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 252                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 253                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 254                                  { name => 'city',              description => $::locale->text('City')                            },
 255                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 256                                  { name => 'country',           description => $::locale->text('Country')                         },
 257                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 258                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 259                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 260                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 261                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 262                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 263                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 264                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 265                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 266                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 267                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 268                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 269                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 270                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 271                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 272                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 273                                  { name => 'name',              description => $::locale->text('Name')                            },
 274                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 275                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 276                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 277                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 278                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 279                                  { name => 'street',            description => $::locale->text('Street')                          },
 280                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 281                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 282                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 283                                  { name => 'username',          description => $::locale->text('Username')                        },
 284                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 285                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 286                                 );
 287 }
 288
 289 # TODO:
 290 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 291
 292 1;