SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Controller::CsvImport::Helper::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PaymentTerm;
  11 use SL::TransNumber;
  12
  13 use parent qw(SL::Controller::CsvImport::Base);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  'scalar --get_set_init' => [ qw(table languages_by businesses_by salesmen_by) ],
  18 );
  19
  20 sub set_profile_defaults {
  21   my ($self) = @_;
  22   $self->controller->profile->_set_defaults(table => 'customer');
  23 };
  24
  25 sub init_table {
  26   my ($self) = @_;
  27   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  28 }
  29
  30 sub init_class {
  31   my ($self) = @_;
  32   $self->class('SL::DB::' . ucfirst($self->table));
  33 }
  34
  35 sub init_all_cvar_configs {
  36   my ($self) = @_;
  37
  38   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  39 }
  40
  41 sub init_businesses_by {
  42   my ($self) = @_;
  43
  44   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  45 }
  46
  47 sub init_languages_by {
  48   my ($self) = @_;
  49
  50   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  51 }
  52
  53 sub init_salesmen_by {
  54   my ($self) = @_;
  55
  56   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Employee->get_all } } ) } qw(id name) };
  57 }
  58
  59 sub check_objects {
  60   my ($self) = @_;
  61
  62   $self->controller->track_progress(phase => 'building data', progress => 0);
  63
  64   my $vc            = $self->controller->profile->get('table');
  65   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  66   my $numbercolumn  = "${vc}number";
  67   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  68   my $methods       = $self->controller->headers->{methods};
  69
  70   my $i;
  71   my $num_data = scalar @{ $self->controller->data };
  72   foreach my $entry (@{ $self->controller->data }) {
  73     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  74     my $object = $entry->{object};
  75
  76     $self->check_name($entry);
  77     $self->check_language($entry);
  78     $self->check_business($entry);
  79     $self->check_payment($entry);
  80     $self->check_delivery_term($entry);
  81     $self->check_taxzone($entry,  take_default => 1);
  82     $self->check_currency($entry, take_default => 1);
  83     $self->check_salesman($entry);
  84     $self->handle_cvars($entry);
  85
  86     next if @{ $entry->{errors} };
  87
  88     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country gln contact phone fax homepage email cc bcc
  89                                                                      taxnumber account_number bank_code bank username greeting taxzone));
  90
  91     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  92       if @cleaned_fields;
  93
  94     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  95     if (!$existing_vc) {
  96       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  97
  98     } elsif ($update_policy eq 'skip') {
  99       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
 100
 101     } elsif ($update_policy eq 'update_existing') {
 102       # Update existing customer/vendor records.
 103       $entry->{object_to_save} = $existing_vc;
 104
 105       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
 106
 107       $self->handle_cvars($entry);
 108       $existing_vc->custom_variables($entry->{object}->custom_variables);
 109
 110       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
 111
 112     } else {
 113       $object->$numbercolumn('####');
 114     }
 115   } continue {
 116     $i++;
 117   }
 118
 119   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment delivery_term taxzone));
 120   $self->add_cvar_raw_data_columns;
 121 }
 122
 123 sub get_duplicate_check_fields {
 124   return {
 125     name => {
 126       label     => $::locale->text('Customer Name'),
 127       default   => 1,
 128       maker     => sub {
 129         my $name = shift->name;
 130         $name =~ s/[\s,\.\-]//g;
 131         return $name;
 132       }
 133     },
 134   };
 135 }
 136
 137 sub check_name {
 138   my ($self, $entry) = @_;
 139
 140   my $name =  $entry->{object}->name;
 141   $name    =~ s/^\s+//;
 142   $name    =~ s/\s+$//;
 143
 144   return 1 if $name;
 145
 146   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 147   return 0;
 148 }
 149
 150 sub check_language {
 151   my ($self, $entry) = @_;
 152
 153   my $object = $entry->{object};
 154
 155   # Check whether or not language ID is valid.
 156   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 157     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 158     return 0;
 159   }
 160
 161   # Map name to ID if given.
 162   if (!$object->language_id && $entry->{raw_data}->{language}) {
 163     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 164                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 165
 166     if (!$language) {
 167       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 168       return 0;
 169     }
 170
 171     $object->language_id($language->id);
 172
 173     # register language_id for method copying later
 174     $self->clone_methods->{language_id} = 1;
 175   }
 176
 177   return 1;
 178 }
 179
 180 sub check_business {
 181   my ($self, $entry) = @_;
 182
 183   my $object = $entry->{object};
 184
 185   # Check whether or not business ID is valid.
 186   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 187     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 188     return 0;
 189   }
 190
 191   # Map name to ID if given.
 192   if (!$object->business_id && $entry->{raw_data}->{business}) {
 193     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 194
 195     if (!$business) {
 196       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 197       return 0;
 198     }
 199
 200     $object->business_id($business->id);
 201
 202     # register business_id for method copying later
 203     $self->clone_methods->{business_id} = 1;
 204   }
 205
 206   return 1;
 207 }
 208
 209 sub check_salesman {
 210   my ($self, $entry) = @_;
 211
 212   my $object = $entry->{object};
 213
 214   # Check whether or not salesman ID is valid.
 215   if ($object->salesman_id && !$self->salesmen_by->{id}->{ $object->salesman_id }) {
 216     push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 217     return 0;
 218   }
 219
 220   # Map name to ID if given.
 221   if (!$object->salesman_id && $entry->{raw_data}->{salesman}) {
 222     my $salesman = $self->salesmen_by->{name}->{ $entry->{raw_data}->{salesman} };
 223
 224     if (!$salesman) {
 225       push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 226       return 0;
 227     }
 228
 229     $object->salesman_id($salesman->id);
 230
 231     # register salesman_id for method copying later
 232     $self->clone_methods->{salesman_id} = 1;
 233   }
 234
 235   return 1;
 236 }
 237
 238 sub save_objects {
 239   my ($self, %params) = @_;
 240
 241   my $numbercolumn   = $self->table . 'number';
 242   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 243   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 244
 245   foreach my $entry (@{$with_number}, @{$without_number}) {
 246     my $object = $entry->{object};
 247
 248     my $number = SL::TransNumber->new(type        => $self->table(),
 249                                       number      => $object->$numbercolumn(),
 250                                       business_id => $object->business_id(),
 251                                       save        => 1);
 252
 253     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 254       $object->$numbercolumn($number->create_unique());
 255     }
 256   }
 257
 258   $self->SUPER::save_objects(data => $with_number);
 259   $self->SUPER::save_objects(data => $without_number);
 260 }
 261
 262 sub init_profile {
 263   my ($self) = @_;
 264
 265   my $profile = $self->SUPER::init_profile;
 266   delete @{$profile}{qw(business datevexport language payment delivery_term taxincluded terms)};
 267   delete @{$profile}{qw(salesman salesman_id)}    if $::instance_conf->get_vertreter;
 268
 269   return $profile;
 270 }
 271
 272 sub setup_displayable_columns {
 273   my ($self) = @_;
 274
 275   $self->SUPER::setup_displayable_columns;
 276   $self->add_cvar_columns_to_displayable_columns;
 277
 278   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 279                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 280                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 281                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 282                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 283                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 284                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 285                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 286                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 287                                  { name => 'city',              description => $::locale->text('City')                            },
 288                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 289                                  { name => 'country',           description => $::locale->text('Country')                         },
 290                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 291                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 292                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 293                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 294                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 295                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 296                                  { name => 'delivery_term_id',  description => $::locale->text('Delivery terms (database ID)')    },
 297                                  { name => 'delivery_term',     description => $::locale->text('Delivery terms (name)')           },
 298                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 299                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 300                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 301                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 302                                  { name => 'gln',               description => $::locale->text('GLN')                             },
 303                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 304                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 305                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 306                                  { name => 'pricegroup_id',     description => $::locale->text('Price group (database ID)')       },
 307                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 308                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 309                                  { name => 'name',              description => $::locale->text('Name')                            },
 310                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 311                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 312                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 313                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 314                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 315                                  { name => 'street',            description => $::locale->text('Street')                          },
 316                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 317                                  { name => 'taxzone',           description => $::locale->text('Tax zone (description)')          },
 318                                  { name => 'taxzone_id',        description => $::locale->text('Tax zone (database ID)')          },
 319                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 320                                  { name => 'username',          description => $::locale->text('Username')                        },
 321                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 322                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 323                                 );
 324
 325   if (!$::instance_conf->get_vertreter) {
 326     $self->add_displayable_columns({ name => 'salesman_id', description => $::locale->text('Salesman (database ID)') });
 327     $self->add_displayable_columns({ name => 'salesman',    description => $::locale->text('Salesman') });
 328   }
 329
 330 }
 331
 332 # TODO:
 333 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 334
 335 1;