SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::DB::Business;
   7 use SL::DB::CustomVariable;
   8 use SL::DB::CustomVariableConfig;
   9 use SL::DB::PaymentTerm;
  10
  11 use parent qw(SL::Controller::CsvImport::Base);
  12
  13 use Rose::Object::MakeMethods::Generic
  14 (
  15  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  16 );
  17
  18 sub init_table {
  19   my ($self) = @_;
  20   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  21 }
  22
  23 sub init_class {
  24   my ($self) = @_;
  25   $self->class('SL::DB::' . ucfirst($self->table));
  26 }
  27
  28 sub init_all_cvar_configs {
  29   my ($self) = @_;
  30
  31   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  32 }
  33
  34 sub init_businesses_by {
  35   my ($self) = @_;
  36
  37   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  38 }
  39
  40 sub init_languages_by {
  41   my ($self) = @_;
  42
  43   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  44 }
  45
  46 sub check_objects {
  47   my ($self) = @_;
  48
  49   my $numbercolumn  = $self->controller->profile->get('table') . "number";
  50   my %vcs_by_number = map { ( $_->$numbercolumn => 1 ) } @{ $self->existing_objects };
  51
  52   foreach my $entry (@{ $self->controller->data }) {
  53     my $object = $entry->{object};
  54
  55     next unless $self->check_name($entry);
  56     next unless $self->check_language($entry);
  57     next unless $self->check_business($entry);
  58     next unless $self->check_payment($entry);
  59     $self->handle_cvars($entry);
  60
  61     if ($vcs_by_number{ $object->$numbercolumn }) {
  62       $entry->{object}->$numbercolumn('####');
  63     } else {
  64       $vcs_by_number{ $object->$numbercolumn } = $object;
  65     }
  66   }
  67
  68   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
  69   $self->add_cvar_raw_data_columns;
  70 }
  71
  72 sub check_duplicates {
  73   my ($self, %params) = @_;
  74
  75   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
  76
  77   my %by_name;
  78   if ('check_db' eq $self->controller->profile->get('duplicates')) {
  79     %by_name = map { ( $normalizer->($_->name) => 'db' ) } @{ $self->existing_objects };
  80   }
  81
  82   foreach my $entry (@{ $self->controller->data }) {
  83     next if @{ $entry->{errors} };
  84
  85     my $name = $normalizer->($entry->{object}->name);
  86     if (!$by_name{$name}) {
  87       $by_name{$name} = 'csv';
  88
  89     } else {
  90       push @{ $entry->{errors} }, $by_name{$name} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
  91     }
  92   }
  93 }
  94
  95 sub check_name {
  96   my ($self, $entry) = @_;
  97
  98   my $name =  $entry->{object}->name;
  99   $name    =~ s/^\s+//;
 100   $name    =~ s/\s+$//;
 101
 102   return 1 if $name;
 103
 104   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 105   return 0;
 106 }
 107
 108 sub check_language {
 109   my ($self, $entry) = @_;
 110
 111   my $object = $entry->{object};
 112
 113   # Check whether or not language ID is valid.
 114   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 115     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 116     return 0;
 117   }
 118
 119   # Map name to ID if given.
 120   if (!$object->language_id && $entry->{raw_data}->{language}) {
 121     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 122                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 123
 124     if (!$language) {
 125       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 126       return 0;
 127     }
 128
 129     $object->language_id($language->id);
 130   }
 131
 132   return 1;
 133 }
 134
 135 sub check_business {
 136   my ($self, $entry) = @_;
 137
 138   my $object = $entry->{object};
 139
 140   # Check whether or not business ID is valid.
 141   if ($object->business_id && !$self->businesss_by->{id}->{ $object->business_id }) {
 142     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 143     return 0;
 144   }
 145
 146   # Map name to ID if given.
 147   if (!$object->business_id && $entry->{raw_data}->{business}) {
 148     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 149
 150     if (!$business) {
 151       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 152       return 0;
 153     }
 154
 155     $object->business_id($business->id);
 156   }
 157
 158   return 1;
 159 }
 160
 161 sub save_objects {
 162   my ($self, %params) = @_;
 163
 164   my $numbercolumn   = $self->table . 'number';
 165   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 166   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 167
 168   map { $_->{object}->$numbercolumn('') } @{ $without_number };
 169
 170   $self->SUPER::save_objects(data => $with_number);
 171   $self->SUPER::save_objects(data => $without_number);
 172 }
 173
 174 sub field_lengths {
 175   return ( name           => 75,
 176            department_1   => 75,
 177            department_2   => 75,
 178            street         => 75,
 179            zipcode        => 10,
 180            city           => 75,
 181            country        => 75,
 182            contact        => 75,
 183            phone          => 30,
 184            fax            => 30,
 185            account_number => 15,
 186            bank_code      => 10,
 187            language       => 5,
 188            username       => 50,
 189            ustid          => 14,
 190            iban           => 100,
 191            bic            => 100,
 192          );
 193 }
 194
 195 sub init_profile {
 196   my ($self) = @_;
 197
 198   my $profile = $self->SUPER::init_profile;
 199   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 200
 201   return $profile;
 202 }
 203
 204 sub setup_displayable_columns {
 205   my ($self) = @_;
 206
 207   $self->SUPER::setup_displayable_columns;
 208   $self->add_cvar_columns_to_displayable_columns;
 209
 210   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 211                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 212                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 213                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 214                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 215                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 216                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 217                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 218                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 219                                  { name => 'city',              description => $::locale->text('City')                            },
 220                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 221                                  { name => 'country',           description => $::locale->text('Country')                         },
 222                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 223                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 224                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 225                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 226                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 227                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 228                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 229                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 230                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 231                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 232                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 233                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 234                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 235                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 236                                  { name => 'name',              description => $::locale->text('Name')                            },
 237                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 238                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 239                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 240                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 241                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 242                                  { name => 'pricing_agreement', description => $::locale->text('Pricing agreement')               },
 243                                  { name => 'street',            description => $::locale->text('Street')                          },
 244                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 245                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 246                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 247                                  { name => 'username',          description => $::locale->text('Username')                        },
 248                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 249                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 250                                 );
 251 }
 252
 253 # TODO:
 254 # salesman_id -- Kunden mit Typ 'Verkäufer', falls $::vertreter an ist, ansonsten Employees
 255
 256 1;