SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::DB::Business;
   7 use SL::DB::CustomVariable;
   8 use SL::DB::CustomVariableConfig;
   9 use SL::DB::PaymentTerm;
  10 use SL::TransNumber;
  11
  12 use parent qw(SL::Controller::CsvImport::Base);
  13
  14 use Rose::Object::MakeMethods::Generic
  15 (
  16  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  17 );
  18
  19 sub init_table {
  20   my ($self) = @_;
  21   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  22 }
  23
  24 sub init_class {
  25   my ($self) = @_;
  26   $self->class('SL::DB::' . ucfirst($self->table));
  27 }
  28
  29 sub init_all_cvar_configs {
  30   my ($self) = @_;
  31
  32   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  33 }
  34
  35 sub init_businesses_by {
  36   my ($self) = @_;
  37
  38   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  39 }
  40
  41 sub init_languages_by {
  42   my ($self) = @_;
  43
  44   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  45 }
  46
  47 sub check_objects {
  48   my ($self) = @_;
  49
  50   my $numbercolumn  = $self->controller->profile->get('table') . "number";
  51   my %vcs_by_number = map { ( $_->$numbercolumn => 1 ) } @{ $self->existing_objects };
  52
  53   foreach my $entry (@{ $self->controller->data }) {
  54     my $object = $entry->{object};
  55
  56     $self->check_name($entry);
  57     $self->check_language($entry);
  58     $self->check_business($entry);
  59     $self->check_payment($entry);
  60     $self->handle_cvars($entry);
  61
  62     next if @{ $entry->{errors} };
  63
  64     if ($vcs_by_number{ $object->$numbercolumn }) {
  65       $entry->{object}->$numbercolumn('####');
  66     } else {
  67       $vcs_by_number{ $object->$numbercolumn } = $object;
  68     }
  69   }
  70
  71   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
  72   $self->add_cvar_raw_data_columns;
  73 }
  74
  75 sub check_duplicates {
  76   my ($self, %params) = @_;
  77
  78   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
  79
  80   my %by_name;
  81   if ('check_db' eq $self->controller->profile->get('duplicates')) {
  82     %by_name = map { ( $normalizer->($_->name) => 'db' ) } @{ $self->existing_objects };
  83   }
  84
  85   foreach my $entry (@{ $self->controller->data }) {
  86     next if @{ $entry->{errors} };
  87
  88     my $name = $normalizer->($entry->{object}->name);
  89     if (!$by_name{$name}) {
  90       $by_name{$name} = 'csv';
  91
  92     } else {
  93       push @{ $entry->{errors} }, $by_name{$name} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
  94     }
  95   }
  96 }
  97
  98 sub check_name {
  99   my ($self, $entry) = @_;
 100
 101   my $name =  $entry->{object}->name;
 102   $name    =~ s/^\s+//;
 103   $name    =~ s/\s+$//;
 104
 105   return 1 if $name;
 106
 107   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 108   return 0;
 109 }
 110
 111 sub check_language {
 112   my ($self, $entry) = @_;
 113
 114   my $object = $entry->{object};
 115
 116   # Check whether or not language ID is valid.
 117   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 118     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 119     return 0;
 120   }
 121
 122   # Map name to ID if given.
 123   if (!$object->language_id && $entry->{raw_data}->{language}) {
 124     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 125                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 126
 127     if (!$language) {
 128       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 129       return 0;
 130     }
 131
 132     $object->language_id($language->id);
 133   }
 134
 135   return 1;
 136 }
 137
 138 sub check_business {
 139   my ($self, $entry) = @_;
 140
 141   my $object = $entry->{object};
 142
 143   # Check whether or not business ID is valid.
 144   if ($object->business_id && !$self->businesss_by->{id}->{ $object->business_id }) {
 145     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 146     return 0;
 147   }
 148
 149   # Map name to ID if given.
 150   if (!$object->business_id && $entry->{raw_data}->{business}) {
 151     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 152
 153     if (!$business) {
 154       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 155       return 0;
 156     }
 157
 158     $object->business_id($business->id);
 159   }
 160
 161   return 1;
 162 }
 163
 164 sub save_objects {
 165   my ($self, %params) = @_;
 166
 167   my $numbercolumn   = $self->table . 'number';
 168   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 169   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 170
 171   foreach my $entry (@{$with_number}, @{$without_number}) {
 172     my $object = $entry->{object};
 173
 174     my $number = SL::TransNumber->new(type        => $self->table(),
 175                                       number      => $object->$numbercolumn(),
 176                                       business_id => $object->business_id(),
 177                                       save        => 1);
 178
 179     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 180       $object->$numbercolumn($number->create_unique());
 181     }
 182   }
 183
 184   $self->SUPER::save_objects(data => $with_number);
 185   $self->SUPER::save_objects(data => $without_number);
 186 }
 187
 188 sub field_lengths {
 189   return ( name           => 75,
 190            department_1   => 75,
 191            department_2   => 75,
 192            street         => 75,
 193            zipcode        => 10,
 194            city           => 75,
 195            country        => 75,
 196            contact        => 75,
 197            fax            => 30,
 198            account_number => 15,
 199            bank_code      => 10,
 200            language       => 5,
 201            username       => 50,
 202            ustid          => 14,
 203            iban           => 100,
 204            bic            => 100,
 205          );
 206 }
 207
 208 sub init_profile {
 209   my ($self) = @_;
 210
 211   my $profile = $self->SUPER::init_profile;
 212   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 213
 214   return $profile;
 215 }
 216
 217 sub setup_displayable_columns {
 218   my ($self) = @_;
 219
 220   $self->SUPER::setup_displayable_columns;
 221   $self->add_cvar_columns_to_displayable_columns;
 222
 223   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 224                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 225                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 226                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 227                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 228                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 229                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 230                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 231                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 232                                  { name => 'city',              description => $::locale->text('City')                            },
 233                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 234                                  { name => 'country',           description => $::locale->text('Country')                         },
 235                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 236                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 237                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 238                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 239                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 240                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 241                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 242                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 243                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 244                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 245                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 246                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 247                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 248                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 249                                  { name => 'name',              description => $::locale->text('Name')                            },
 250                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 251                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 252                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 253                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 254                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 255                                  { name => 'street',            description => $::locale->text('Street')                          },
 256                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 257                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 258                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 259                                  { name => 'username',          description => $::locale->text('Username')                        },
 260                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 261                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 262                                 );
 263 }
 264
 265 # TODO:
 266 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 267
 268 1;