SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Controller::CsvImport::Helper::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::Employee;
  11 use SL::DB::PaymentTerm;
  12 use SL::TransNumber;
  13
  14 use parent qw(SL::Controller::CsvImport::Base);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  'scalar --get_set_init' => [ qw(table languages_by businesses_by salesmen_by) ],
  19 );
  20
  21 sub set_profile_defaults {
  22   my ($self) = @_;
  23   $self->controller->profile->_set_defaults(table => 'customer');
  24 };
  25
  26 sub init_table {
  27   my ($self) = @_;
  28   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  29 }
  30
  31 sub init_class {
  32   my ($self) = @_;
  33   $self->class('SL::DB::' . ucfirst($self->table));
  34 }
  35
  36 sub init_all_cvar_configs {
  37   my ($self) = @_;
  38
  39   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  40 }
  41
  42 sub init_businesses_by {
  43   my ($self) = @_;
  44
  45   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  46 }
  47
  48 sub init_languages_by {
  49   my ($self) = @_;
  50
  51   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  52 }
  53
  54 sub init_salesmen_by {
  55   my ($self) = @_;
  56
  57   return { map { my $col = $_; ( $col => { map { ( lc($_->$col) => $_ ) } @{ SL::DB::Manager::Employee->get_all } } ) } qw(id name login) };
  58 }
  59
  60 sub check_objects {
  61   my ($self) = @_;
  62
  63   $self->controller->track_progress(phase => 'building data', progress => 0);
  64
  65   my $vc            = $self->controller->profile->get('table');
  66   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  67   my $numbercolumn  = "${vc}number";
  68   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  69   my $methods       = $self->controller->headers->{methods};
  70
  71   my $i;
  72   my $num_data = scalar @{ $self->controller->data };
  73   foreach my $entry (@{ $self->controller->data }) {
  74     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  75     my $object = $entry->{object};
  76
  77     $self->check_name($entry);
  78     $self->check_language($entry);
  79     $self->check_business($entry);
  80     $self->check_payment($entry);
  81     $self->check_delivery_term($entry);
  82     $self->check_taxzone($entry,  take_default => 1);
  83     $self->check_currency($entry, take_default => 1);
  84     $self->check_salesman($entry);
  85     $self->handle_cvars($entry);
  86
  87     next if @{ $entry->{errors} };
  88
  89     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country gln contact phone fax homepage email cc bcc
  90                                                                      taxnumber account_number bank_code bank username greeting taxzone));
  91
  92     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  93       if @cleaned_fields;
  94
  95     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  96     if (!$existing_vc) {
  97       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  98
  99     } elsif ($update_policy eq 'skip') {
 100       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
 101
 102     } elsif ($update_policy eq 'update_existing') {
 103       # Update existing customer/vendor records.
 104       $entry->{object_to_save} = $existing_vc;
 105
 106       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
 107
 108       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
 109
 110     } else {
 111       $object->$numbercolumn('####');
 112     }
 113   } continue {
 114     $i++;
 115   }
 116
 117   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment delivery_term taxzone));
 118   $self->add_cvar_raw_data_columns;
 119 }
 120
 121 sub get_duplicate_check_fields {
 122   return {
 123     name => {
 124       label     => $::locale->text('Customer Name'),
 125       default   => 1,
 126       maker     => sub {
 127         my $name = shift->name;
 128         $name =~ s/[\s,\.\-]//g;
 129         return $name;
 130       }
 131     },
 132   };
 133 }
 134
 135 sub check_name {
 136   my ($self, $entry) = @_;
 137
 138   my $name =  $entry->{object}->name;
 139   $name    =~ s/^\s+//;
 140   $name    =~ s/\s+$//;
 141
 142   return 1 if $name;
 143
 144   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 145   return 0;
 146 }
 147
 148 sub check_language {
 149   my ($self, $entry) = @_;
 150
 151   my $object = $entry->{object};
 152
 153   # Check whether or not language ID is valid.
 154   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 155     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 156     return 0;
 157   }
 158
 159   # Map name to ID if given.
 160   if (!$object->language_id && $entry->{raw_data}->{language}) {
 161     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 162                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 163
 164     if (!$language) {
 165       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 166       return 0;
 167     }
 168
 169     $object->language_id($language->id);
 170
 171     # register language_id for method copying later
 172     $self->clone_methods->{language_id} = 1;
 173   }
 174
 175   return 1;
 176 }
 177
 178 sub check_business {
 179   my ($self, $entry) = @_;
 180
 181   my $object = $entry->{object};
 182
 183   # Check whether or not business ID is valid.
 184   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 185     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 186     return 0;
 187   }
 188
 189   # Map name to ID if given.
 190   if (!$object->business_id && $entry->{raw_data}->{business}) {
 191     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 192
 193     if (!$business) {
 194       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 195       return 0;
 196     }
 197
 198     $object->business_id($business->id);
 199
 200     # register business_id for method copying later
 201     $self->clone_methods->{business_id} = 1;
 202   }
 203
 204   return 1;
 205 }
 206
 207 sub check_salesman {
 208   my ($self, $entry) = @_;
 209
 210   my $object = $entry->{object};
 211
 212   # Check whether or not salesman ID is valid.
 213   if ($object->salesman_id && !$self->salesmen_by->{id}->{ $object->salesman_id }) {
 214     push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 215     return 0;
 216   }
 217
 218   # Map name to ID if given.
 219   if (!$object->salesman_id && ($entry->{raw_data}->{salesman} || $entry->{raw_data}->{salesman_login})) {
 220     my $salesman = $self->salesmen_by->{name} ->{ lc($entry->{raw_data}->{salesman}) }
 221                 // $self->salesmen_by->{login}->{ lc($entry->{raw_data}->{salesman_login}) };
 222
 223     if (!$salesman) {
 224       push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 225       return 0;
 226     }
 227
 228     $object->salesman_id($salesman->id);
 229
 230     # register salesman_id for method copying later
 231     $self->clone_methods->{salesman_id} = 1;
 232   }
 233
 234   return 1;
 235 }
 236
 237 sub save_objects {
 238   my ($self, %params) = @_;
 239
 240   my $numbercolumn   = $self->table . 'number';
 241   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 242   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 243
 244   $_->{object}->$numbercolumn('') for @{ $without_number };
 245
 246   $self->SUPER::save_objects(data => $with_number);
 247   $self->SUPER::save_objects(data => $without_number);
 248 }
 249
 250 sub init_profile {
 251   my ($self) = @_;
 252
 253   my $profile = $self->SUPER::init_profile;
 254   delete @{$profile}{qw(business datevexport language payment delivery_term taxincluded terms)};
 255   delete @{$profile}{qw(salesman salesman_id salesman_login)} if $::instance_conf->get_vertreter;
 256
 257   return $profile;
 258 }
 259
 260 sub setup_displayable_columns {
 261   my ($self) = @_;
 262
 263   $self->SUPER::setup_displayable_columns;
 264   $self->add_cvar_columns_to_displayable_columns;
 265
 266   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 267                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 268                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 269                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 270                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 271                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 272                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 273                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 274                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 275                                  { name => 'city',              description => $::locale->text('City')                            },
 276                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 277                                  { name => 'country',           description => $::locale->text('Country')                         },
 278                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 279                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 280                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 281                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 282                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 283                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 284                                  { name => 'delivery_term_id',  description => $::locale->text('Delivery terms (database ID)')    },
 285                                  { name => 'delivery_term',     description => $::locale->text('Delivery terms (name)')           },
 286                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 287                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 288                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 289                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 290                                  { name => 'gln',               description => $::locale->text('GLN')                             },
 291                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 292                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 293                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 294                                  { name => 'pricegroup_id',     description => $::locale->text('Price group (database ID)')       },
 295                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 296                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 297                                  { name => 'name',              description => $::locale->text('Name')                            },
 298                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 299                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 300                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 301                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 302                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 303                                  { name => 'street',            description => $::locale->text('Street')                          },
 304                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 305                                  { name => 'taxzone',           description => $::locale->text('Tax zone (description)')          },
 306                                  { name => 'taxzone_id',        description => $::locale->text('Tax zone (database ID)')          },
 307                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 308                                  { name => 'username',          description => $::locale->text('Username')                        },
 309                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 310                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 311                                 );
 312
 313   if (!$::instance_conf->get_vertreter) {
 314     $self->add_displayable_columns({ name => 'salesman',       description => $::locale->text('Salesman') },
 315                                    { name => 'salesman_id',    description => $::locale->text('Salesman (database ID)') },
 316                                    { name => 'salesman_login', description => $::locale->text('Salesman (login)') });
 317   }
 318 }
 319
 320 # TODO:
 321 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 322
 323 1;