SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::DB::Business;
   7 use SL::DB::CustomVariable;
   8 use SL::DB::CustomVariableConfig;
   9 use SL::DB::PaymentTerm;
  10 use SL::TransNumber;
  11
  12 use parent qw(SL::Controller::CsvImport::Base);
  13
  14 use Rose::Object::MakeMethods::Generic
  15 (
  16  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  17 );
  18
  19 sub init_table {
  20   my ($self) = @_;
  21   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  22 }
  23
  24 sub init_class {
  25   my ($self) = @_;
  26   $self->class('SL::DB::' . ucfirst($self->table));
  27 }
  28
  29 sub init_all_cvar_configs {
  30   my ($self) = @_;
  31
  32   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  33 }
  34
  35 sub init_businesses_by {
  36   my ($self) = @_;
  37
  38   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  39 }
  40
  41 sub init_languages_by {
  42   my ($self) = @_;
  43
  44   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  45 }
  46
  47 sub check_objects {
  48   my ($self) = @_;
  49
  50   $self->controller->track_progress(phase => 'building data', progress => 0);
  51
  52   my $vc            = $self->controller->profile->get('table');
  53   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  54   my $numbercolumn  = "${vc}number";
  55   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  56   my $methods       = $self->controller->headers->{methods};
  57
  58   my $i;
  59   my $num_data = scalar @{ $self->controller->data };
  60   foreach my $entry (@{ $self->controller->data }) {
  61     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  62     my $object = $entry->{object};
  63
  64     $self->check_name($entry);
  65     $self->check_language($entry);
  66     $self->check_business($entry);
  67     $self->check_payment($entry);
  68     $self->handle_cvars($entry);
  69
  70     next if @{ $entry->{errors} };
  71
  72     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country contact phone fax homepage email cc bcc
  73                                                                      taxnumber account_number bank_code bank username greeting));
  74
  75     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  76       if @cleaned_fields;
  77
  78     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  79     if (!$existing_vc) {
  80       $vcs_by_number{ $object->$numbercolumn } = $object;
  81
  82     } elsif ($update_policy eq 'skip') {
  83       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
  84
  85     } elsif ($update_policy eq 'update_existing') {
  86       # Update existing customer/vendor records.
  87       $entry->{object_to_save} = $existing_vc;
  88
  89       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods };
  90
  91       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
  92
  93     } else {
  94       $object->$numbercolumn('####');
  95     }
  96   } continue {
  97     $i++;
  98   }
  99
 100   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
 101   $self->add_cvar_raw_data_columns;
 102 }
 103
 104 sub get_duplicate_check_fields {
 105   return {
 106     name => {
 107       label     => $::locale->text('Customer Name'),
 108       default   => 1,
 109       maker     => sub {
 110         my $name = shift->name;
 111         $name =~ s/[\s,\.\-]//g;
 112         return $name;
 113       }
 114     },
 115   };
 116 }
 117
 118 sub check_name {
 119   my ($self, $entry) = @_;
 120
 121   my $name =  $entry->{object}->name;
 122   $name    =~ s/^\s+//;
 123   $name    =~ s/\s+$//;
 124
 125   return 1 if $name;
 126
 127   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 128   return 0;
 129 }
 130
 131 sub check_language {
 132   my ($self, $entry) = @_;
 133
 134   my $object = $entry->{object};
 135
 136   # Check whether or not language ID is valid.
 137   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 138     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 139     return 0;
 140   }
 141
 142   # Map name to ID if given.
 143   if (!$object->language_id && $entry->{raw_data}->{language}) {
 144     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 145                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 146
 147     if (!$language) {
 148       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 149       return 0;
 150     }
 151
 152     $object->language_id($language->id);
 153   }
 154
 155   return 1;
 156 }
 157
 158 sub check_business {
 159   my ($self, $entry) = @_;
 160
 161   my $object = $entry->{object};
 162
 163   # Check whether or not business ID is valid.
 164   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 165     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 166     return 0;
 167   }
 168
 169   # Map name to ID if given.
 170   if (!$object->business_id && $entry->{raw_data}->{business}) {
 171     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 172
 173     if (!$business) {
 174       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 175       return 0;
 176     }
 177
 178     $object->business_id($business->id);
 179   }
 180
 181   return 1;
 182 }
 183
 184 sub save_objects {
 185   my ($self, %params) = @_;
 186
 187   my $numbercolumn   = $self->table . 'number';
 188   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 189   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 190
 191   foreach my $entry (@{$with_number}, @{$without_number}) {
 192     my $object = $entry->{object};
 193
 194     my $number = SL::TransNumber->new(type        => $self->table(),
 195                                       number      => $object->$numbercolumn(),
 196                                       business_id => $object->business_id(),
 197                                       save        => 1);
 198
 199     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 200       $object->$numbercolumn($number->create_unique());
 201     }
 202   }
 203
 204   $self->SUPER::save_objects(data => $with_number);
 205   $self->SUPER::save_objects(data => $without_number);
 206 }
 207
 208 sub field_lengths {
 209   return ( name           => 75,
 210            department_1   => 75,
 211            department_2   => 75,
 212            street         => 75,
 213            zipcode        => 10,
 214            city           => 75,
 215            country        => 75,
 216            contact        => 75,
 217            fax            => 30,
 218            account_number => 15,
 219            bank_code      => 10,
 220            language       => 5,
 221            username       => 50,
 222            ustid          => 14,
 223            iban           => 100,
 224            bic            => 100,
 225          );
 226 }
 227
 228 sub init_profile {
 229   my ($self) = @_;
 230
 231   my $profile = $self->SUPER::init_profile;
 232   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 233
 234   return $profile;
 235 }
 236
 237 sub setup_displayable_columns {
 238   my ($self) = @_;
 239
 240   $self->SUPER::setup_displayable_columns;
 241   $self->add_cvar_columns_to_displayable_columns;
 242
 243   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 244                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 245                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 246                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 247                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 248                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 249                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 250                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 251                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 252                                  { name => 'city',              description => $::locale->text('City')                            },
 253                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 254                                  { name => 'country',           description => $::locale->text('Country')                         },
 255                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 256                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 257                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 258                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 259                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 260                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 261                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 262                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 263                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 264                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 265                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 266                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 267                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 268                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 269                                  { name => 'name',              description => $::locale->text('Name')                            },
 270                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 271                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 272                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 273                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 274                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 275                                  { name => 'street',            description => $::locale->text('Street')                          },
 276                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 277                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 278                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 279                                  { name => 'username',          description => $::locale->text('Username')                        },
 280                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 281                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 282                                 );
 283 }
 284
 285 # TODO:
 286 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 287
 288 1;