SL/Controller/CsvImport/DeliveryOrder.pm

   1 package SL::Controller::CsvImport::DeliveryOrder;
   2
   3
   4 use strict;
   5
   6 use List::Util qw(first);
   7 use List::MoreUtils qw(any none uniq);
   8 use DateTime;
   9
  10 use SL::Controller::CsvImport::Helper::Consistency;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::DeliveryOrderItem;
  13 use SL::DB::DeliveryOrderItemsStock;
  14 use SL::DB::Part;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::Contact;
  17 use SL::DB::PriceFactor;
  18 use SL::DB::Pricegroup;
  19 use SL::DB::Shipto;
  20 use SL::DB::Unit;
  21 use SL::DB::Inventory;
  22 use SL::DB::TransferType;
  23 use SL::DBUtils;
  24 use SL::Helper::ShippedQty;
  25 use SL::PriceSource;
  26 use SL::TransNumber;
  27 use SL::Util qw(trim);
  28
  29 use parent qw(SL::Controller::CsvImport::BaseMulti);
  30
  31
  32 use Rose::Object::MakeMethods::Generic
  33 (
  34  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by
  35                                  contacts_by ct_shiptos_by
  36                                  price_factors_by pricegroups_by units_by
  37                                  warehouses_by bins_by transfer_types_by) ],
  38 );
  39
  40
  41 sub init_class {
  42   my ($self) = @_;
  43   $self->class(['SL::DB::DeliveryOrder', 'SL::DB::DeliveryOrderItem', 'SL::DB::DeliveryOrderItemsStock']);
  44 }
  45
  46 sub set_profile_defaults {
  47   my ($self) = @_;
  48
  49   $self->controller->profile->_set_defaults(
  50     order_column         => $::locale->text('DeliveryOrder'),
  51     item_column          => $::locale->text('OrderItem'),
  52     stock_column         => $::locale->text('StockInfo'),
  53     ignore_faulty_positions => 0,
  54   );
  55 };
  56
  57 sub init_settings {
  58   my ($self) = @_;
  59
  60   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column stock_column ignore_faulty_positions) };
  61 }
  62
  63 sub init_cvar_configs_by {
  64   my ($self) = @_;
  65
  66   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  67   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  68
  69   my $ccb;
  70   $ccb->{class}->{$self->class->[0]}        = [];
  71   $ccb->{class}->{$self->class->[1]}        = $item_cvar_configs;
  72   $ccb->{class}->{$self->class->[2]}        = [];
  73   $ccb->{row_ident}->{$self->_order_column} = [];
  74   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  75   $ccb->{row_ident}->{$self->_stock_column} = [];
  76
  77   return $ccb;
  78 }
  79
  80 sub init_profile {
  81   my ($self) = @_;
  82
  83   my $profile = $self->SUPER::init_profile;
  84
  85   # SUPER::init_profile sets row_ident to the translated class name
  86   # overwrite it with the user specified settings
  87   foreach my $p (@{ $profile }) {
  88     $p->{row_ident} = $self->_order_column if $p->{class} eq $self->class->[0];
  89     $p->{row_ident} = $self->_item_column  if $p->{class} eq $self->class->[1];
  90     $p->{row_ident} = $self->_stock_column if $p->{class} eq $self->class->[2];
  91   }
  92
  93   foreach my $p (@{ $profile }) {
  94     my $prof = $p->{profile};
  95     if ($p->{row_ident} eq $self->_order_column) {
  96       # no need to handle
  97       delete @{$prof}{qw(oreqnumber)};
  98     }
  99     if ($p->{row_ident} eq $self->_item_column) {
 100       # no need to handle
 101       delete @{$prof}{qw(delivery_order_id)};
 102     }
 103     if ($p->{row_ident} eq $self->_stock_column) {
 104       # no need to handle
 105       delete @{$prof}{qw(delivery_order_item_id)};
 106       delete @{$prof}{qw(bestbefore)} if !$::instance_conf->get_show_bestbefore;
 107     }
 108   }
 109
 110   return $profile;
 111 }
 112
 113 sub init_existing_objects {
 114   my ($self) = @_;
 115
 116   # only use objects of main class (the first one)
 117   eval "require " . $self->class->[0];
 118   $self->existing_objects($self->manager_class->[0]->get_all);
 119 }
 120
 121 sub get_duplicate_check_fields {
 122   return {
 123     donumber => {
 124       label     => $::locale->text('Delivery Order Number'),
 125       default   => 1,
 126       std_check => 1,
 127       maker     => sub {
 128         my ($object, $worker) = @_;
 129         return if ref $object ne $worker->class->[0];
 130         return $object->donumber;
 131       },
 132     },
 133   };
 134 }
 135
 136 sub check_std_duplicates {
 137   my $self = shift;
 138
 139   my $duplicates = {};
 140
 141   my $all_fields = $self->get_duplicate_check_fields();
 142
 143   foreach my $key (keys(%{ $all_fields })) {
 144     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 145       $duplicates->{$key} = {};
 146     }
 147   }
 148
 149   my @duplicates_keys = keys(%{ $duplicates });
 150
 151   if ( !scalar(@duplicates_keys) ) {
 152     return;
 153   }
 154
 155   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 156     foreach my $object (@{ $self->existing_objects }) {
 157       foreach my $key (@duplicates_keys) {
 158         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 159         $duplicates->{$key}->{$value} = 'db';
 160       }
 161     }
 162   }
 163
 164   # only check order rows
 165   foreach my $entry (@{ $self->controller->data }) {
 166     if ($entry->{raw_data}->{datatype} ne $self->_order_column) {
 167       next;
 168     }
 169     if ( @{ $entry->{errors} } ) {
 170       next;
 171     }
 172
 173     my $object = $entry->{object};
 174
 175     foreach my $key (@duplicates_keys) {
 176       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 177
 178       if ( exists($duplicates->{$key}->{$value}) ) {
 179         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 180         last;
 181       } else {
 182         $duplicates->{$key}->{$value} = 'csv';
 183       }
 184
 185     }
 186   }
 187 }
 188
 189 sub setup_displayable_columns {
 190   my ($self) = @_;
 191
 192   $self->SUPER::setup_displayable_columns;
 193
 194   $self->add_cvar_columns_to_displayable_columns($self->_order_column);
 195
 196   $self->add_displayable_columns($self->_order_column,
 197                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 198                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 199                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 200                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 201                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 202                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 203                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 204                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 205                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 206                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 207                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 208                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 209                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 210                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 211                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 212                                  { name => 'donumber',                description => $::locale->text('Delivery Order Number')                 },
 213                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 214                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 215                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 216                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 217                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 218                                  { name => 'is_sales',                description => $::locale->text('Is sales')                              },
 219                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 220                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 221                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 222                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 223                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 224                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 225                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 226                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 227                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 228                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 229                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 230                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 231                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 232                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 233                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 234                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 235                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 236                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 237                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 238                                 );
 239
 240   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 241
 242   $self->add_displayable_columns($self->_item_column,
 243                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 244                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 245                                  { name => 'description',     description => $::locale->text('Description')                },
 246                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 247                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 248                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 249                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 250                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 251                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 252                                  { name => 'position',        description => $::locale->text('position')                   },
 253                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 254                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 255                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 256                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 257                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 258                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 259                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 260                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 261                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 262                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 263                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 264                                  { name => 'transdate',       description => $::locale->text('Order Date')                 },
 265                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 266                                 );
 267
 268   $self->add_cvar_columns_to_displayable_columns($self->_stock_column);
 269
 270   $self->add_displayable_columns($self->_stock_column,
 271                                  { name => 'datatype',     description => $self->_stock_column . ' [1]'              },
 272                                  { name => 'warehouse',    description => $::locale->text('Warehouse')               },
 273                                  { name => 'warehouse_id', description => $::locale->text('Warehouse (database ID)') },
 274                                  { name => 'bin',          description => $::locale->text('Bin')                     },
 275                                  { name => 'bin_id',       description => $::locale->text('Bin (database ID)')       },
 276                                  { name => 'chargenumber', description => $::locale->text('Charge number')           },
 277                                  { name => 'qty',          description => $::locale->text('Quantity')                },
 278                                  { name => 'unit',         description => $::locale->text('Unit')                    },
 279                                 );
 280   if ($::instance_conf->get_show_bestbefore) {
 281     $self->add_displayable_columns($self->_stock_column,
 282                                    { name => 'bestbefore', description => $::locale->text('Best Before') });
 283   }
 284 }
 285
 286
 287 sub init_languages_by {
 288   my ($self) = @_;
 289
 290   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 291 }
 292
 293 sub init_all_parts {
 294   my ($self) = @_;
 295
 296   return SL::DB::Manager::Part->get_all(where => [or => [ obsolete => 0, obsolete => undef ]]);
 297 }
 298
 299 sub init_parts_by {
 300   my ($self) = @_;
 301
 302   return { map { my $col = $_; ( $col => { map { ( trim($_->$col) => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 303 }
 304
 305 sub init_part_counts_by {
 306   my ($self) = @_;
 307
 308   my $part_counts_by;
 309
 310   $part_counts_by->{ean}->        {trim($_->ean)}++         for @{ $self->all_parts };
 311   $part_counts_by->{description}->{trim($_->description)}++ for @{ $self->all_parts };
 312
 313   return $part_counts_by;
 314 }
 315
 316 sub init_contacts_by {
 317   my ($self) = @_;
 318
 319   my $all_contacts = SL::DB::Manager::Contact->get_all;
 320
 321   my $cby;
 322   # by customer/vendor id  _and_  contact person id
 323   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 324   # by customer/vendor id  _and_  contact person name
 325   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 326
 327   return $cby;
 328 }
 329
 330 sub init_ct_shiptos_by {
 331   my ($self) = @_;
 332
 333   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 334
 335   my $sby;
 336   # by trans_id  _and_  shipto_id
 337   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 338
 339   return $sby;
 340 }
 341
 342 sub init_price_factors_by {
 343   my ($self) = @_;
 344
 345   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 346   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 347 }
 348
 349 sub init_pricegroups_by {
 350   my ($self) = @_;
 351
 352   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 353   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 354 }
 355
 356 sub init_units_by {
 357   my ($self) = @_;
 358
 359   my $all_units = SL::DB::Manager::Unit->get_all;
 360   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 361 }
 362
 363 sub init_warehouses_by {
 364   my ($self) = @_;
 365
 366   my $all_warehouses = SL::DB::Manager::Warehouse->get_all(query => [ or => [ invalid => 0, invalid => undef ]]);
 367   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_warehouses } } ) } qw(id description) };
 368 }
 369
 370 sub init_bins_by {
 371   my ($self) = @_;
 372
 373   my $all_bins = SL::DB::Manager::Bin->get_all();
 374   my $bins_by;
 375   $bins_by->{_wh_id_and_id_ident()}          = { map { ( _wh_id_and_id_maker($_->warehouse_id, $_->id)                   => $_ ) } @{ $all_bins } };
 376   $bins_by->{_wh_id_and_description_ident()} = { map { ( _wh_id_and_description_maker($_->warehouse_id, $_->description) => $_ ) } @{ $all_bins } };
 377
 378   return $bins_by;
 379 }
 380
 381 sub init_transfer_types_by {
 382   my ($self) = @_;
 383
 384   my $all_transfer_types = SL::DB::Manager::TransferType->get_all();
 385   my $transfer_types_by;
 386   $transfer_types_by->{_transfer_type_dir_and_description_ident()} = {
 387     map { ( _transfer_type_dir_and_description_maker($_->direction, $_->description) => $_ ) } @{ $all_transfer_types }
 388   };
 389
 390   return $transfer_types_by;
 391 }
 392
 393 sub check_objects {
 394   my ($self) = @_;
 395
 396   $self->controller->track_progress(phase => 'building data', progress => 0);
 397
 398   my $i = 0;
 399   my $num_data = scalar @{ $self->controller->data };
 400   my $order_entry;
 401   my $item_entry;
 402   foreach my $entry (@{ $self->controller->data }) {
 403     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 404
 405     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 406
 407     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 408       $self->handle_order($entry);
 409       $order_entry = $entry;
 410     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 411       $self->handle_item($entry, $order_entry);
 412       $item_entry = $entry;
 413     } elsif ($entry->{raw_data}->{datatype} eq $self->_stock_column) {
 414       $self->handle_stock($entry, $item_entry, $order_entry);
 415       push @{ $order_entry->{errors} }, $::locale->text('Error: Stock problem') if scalar(@{$entry->{errors}}) > 0;
 416     } else {
 417       $order_entry = undef;
 418       $item_entry  = undef;
 419     }
 420
 421     $self->handle_cvars($entry, sub_module => 'delivery_order_items');
 422
 423   } continue {
 424     $i++;
 425   }
 426
 427   $self->add_info_columns($self->_order_column,
 428                           { header => $::locale->text('Data type'), method => 'datatype' });
 429   $self->add_info_columns($self->_item_column,
 430                           { header => $::locale->text('Data type'), method => 'datatype' });
 431   $self->add_info_columns($self->_stock_column,
 432                           { header => $::locale->text('Data type'), method => 'datatype' });
 433
 434   $self->add_info_columns($self->_order_column,
 435                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 436   # Todo: access via ->[0] ok? Better: search first order column and use this
 437   $self->add_columns($self->_order_column,
 438                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 439   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 440   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 441
 442   $self->add_info_columns($self->_item_column,
 443                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 444   # Todo: access via ->[1] ok? Better: search first item column and use this
 445   $self->add_columns($self->_item_column,
 446                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 447   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 448
 449   $self->add_cvar_raw_data_columns();
 450
 451
 452   # Check overall qtys for sales delivery orders, because they are
 453   # stocked out in the end and a stock underrun can occure.
 454   # Todo: let it work even with bestbefore turned off.
 455   $order_entry = undef;
 456   $item_entry  = undef;
 457   my %wanted_qtys_by_part_wh_bin_charge_bestbefore;
 458   my %stock_entries_with_part_wh_bin_charge_bestbefore;
 459   my %order_entries_with_part_wh_bin_charge_bestbefore;
 460   foreach my $entry (@{ $self->controller->data }) {
 461     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 462       if (scalar(@{ $entry->{errors} }) || !$entry->{object}->is_sales) {
 463         $order_entry = undef;
 464         $item_entry  = undef;
 465         next;
 466       }
 467       $order_entry = $entry;
 468
 469     } elsif (defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column) {
 470       if (scalar(@{ $entry->{errors} })) {
 471         $item_entry = undef;
 472         next;
 473       }
 474       $item_entry = $entry;
 475
 476     } elsif (defined $item_entry && $entry->{raw_data}->{datatype} eq $self->_stock_column) {
 477       my $object = $entry->{object};
 478       my $key = join('+',
 479                      $item_entry->{object}->parts_id,
 480                      $object->warehouse_id,
 481                      $object->bin_id,
 482                      $object->chargenumber,
 483                      $object->bestbefore);
 484       $wanted_qtys_by_part_wh_bin_charge_bestbefore{$key} += $object->qty;
 485       push @{$order_entries_with_part_wh_bin_charge_bestbefore{$key}}, $order_entry;
 486       push @{$stock_entries_with_part_wh_bin_charge_bestbefore{$key}}, $entry;
 487     }
 488   }
 489
 490   foreach my $key (keys %wanted_qtys_by_part_wh_bin_charge_bestbefore) {
 491     my ($parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore) = split '\+', $key;
 492     my $qty = $self->get_stocked_qty($parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore);
 493     if ($wanted_qtys_by_part_wh_bin_charge_bestbefore{$key} > $qty) {
 494
 495       foreach my $stock_entry (@{ $stock_entries_with_part_wh_bin_charge_bestbefore{$key} }) {
 496         push @{ $stock_entry->{errors} }, $::locale->text('Error: Stocking out would result in stock underrun');
 497       }
 498
 499       foreach my $order_entry (uniq @{ $order_entries_with_part_wh_bin_charge_bestbefore{$key} }) {
 500         my $part            = $self->parts_by->{id}->{$parts_id}->displayable_name;
 501         my $stock           = $self->bins_by->{_wh_id_and_id_ident()}->{_wh_id_and_id_maker($wh_id, $bin_id)}->full_description;
 502         my $bestbefore_obj  = $::locale->parse_date_to_object($bestbefore, dateformat=>'yyyy-mm-dd');
 503         my $bestbefore_text = $bestbefore_obj? $::locale->parse_date_to_object($bestbefore_obj, dateformat=>'yyyy-mm-dd')->to_kivitendo: '-';
 504         my $wanted_qty      = $wanted_qtys_by_part_wh_bin_charge_bestbefore{$key};
 505         my $details_text    = sprintf('%s (%s / %s / %s): %s > %s',
 506                                       $part,
 507                                       $stock,
 508                                       $chargenumber,
 509                                       $bestbefore_text,
 510                                       $::form->format_amount(\%::myconfig, $wanted_qty,  2),
 511                                       $::form->format_amount(\%::myconfig, $qty, 2));
 512         push @{ $order_entry->{errors} }, $::locale->text('Error: Stocking out would result in stock underrun: #1', $details_text);
 513       }
 514
 515     }
 516   }
 517
 518 }
 519
 520 sub handle_order {
 521   my ($self, $entry) = @_;
 522
 523   my $object = $entry->{object};
 524
 525   $object->orderitems([]);
 526
 527   $self->handle_order_sources($entry);
 528   my $first_source_order = $object->{source_orders}->[0];
 529
 530   my $vc_obj;
 531   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 532     $self->check_vc($entry, 'customer_id');
 533     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 534
 535   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 536     $self->check_vc($entry, 'vendor_id');
 537     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 538
 539   } else {
 540     # customer / vendor from (first) source order if not given
 541     if ($first_source_order) {
 542       if ($first_source_order->customer) {
 543         $vc_obj = $first_source_order->customer;
 544         $object->customer($first_source_order->customer);
 545       } elsif ($first_source_order->vendor) {
 546         $vc_obj = $first_source_order->vendor;
 547         $object->vendor($first_source_order->vendor);
 548       }
 549     }
 550   }
 551
 552   if (!$vc_obj) {
 553     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 554   }
 555
 556   $self->handle_is_sales($entry);
 557   $self->check_contact($entry);
 558   $self->check_language($entry);
 559   $self->check_payment($entry);
 560   $self->check_delivery_term($entry);
 561   $self->check_department($entry);
 562   $self->check_project($entry, global => 1);
 563   $self->check_ct_shipto($entry);
 564   $self->check_taxzone($entry);
 565   $self->check_currency($entry, take_default => 0);
 566
 567   # copy from (first) source order if not given
 568   # if no source order, then copy some values from customer/vendor
 569   if ($first_source_order) {
 570     foreach (qw(cusordnumber notes intnotes shippingpoint shipvia
 571                 transaction_description currency_id delivery_term_id
 572                 department_id language_id payment_id globalproject_id shipto_id
 573                 taxzone_id)) {
 574       $object->$_($first_source_order->$_) unless $object->$_;
 575     }
 576   } elsif ($vc_obj) {
 577     foreach (qw(currency_id delivery_term_id language_id payment_id taxzone_id)) {
 578       $object->$_($vc_obj->$_) unless $object->$_;
 579     }
 580     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 581   }
 582
 583   $self->handle_salesman($entry);
 584   $self->handle_employee($entry);
 585 }
 586
 587 sub handle_item {
 588   my ($self, $entry, $order_entry) = @_;
 589
 590   return unless $order_entry;
 591
 592   my $order_obj = $order_entry->{object};
 593   my $object    = $entry->{object};
 594   $object->delivery_order_stock_entries([]);
 595
 596   if (!$self->check_part($entry)) {
 597     if ($self->controller->profile->get('ignore_faulty_positions')) {
 598       push @{ $order_entry->{information} }, $::locale->text('Warning: Faulty position ignored');
 599     } else {
 600       push @{ $order_entry->{errors} }, $::locale->text('Error: Faulty position in this delivery order');
 601     }
 602     return;
 603   }
 604
 605   $order_obj->add_items($object);
 606
 607   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 608
 609   $self->handle_item_source($entry, $order_entry);
 610   $object->position($object->{source_item}->position) if $object->{source_item};
 611
 612   $self->handle_unit($entry);
 613
 614   # copy from part if not given
 615   $object->description($part_obj->description) unless $object->description;
 616   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 617   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 618
 619   $self->check_project($entry, global => 0);
 620   $self->check_price_factor($entry);
 621   $self->check_pricegroup($entry);
 622
 623   $self->handle_sellprice($entry, $order_entry);
 624   $self->handle_discount($entry, $order_entry);
 625
 626   push @{ $order_entry->{errors} }, $::locale->text('Error: Faulty position in this delivery order') if scalar(@{$entry->{errors}}) > 0;
 627 }
 628
 629 sub handle_stock {
 630   my ($self, $entry, $item_entry, $order_entry) = @_;
 631
 632   return unless $item_entry;
 633
 634   my $item_obj  = $item_entry->{object};
 635   return unless $item_obj->part;
 636
 637   my $order_obj = $order_entry->{object};
 638   my $object    = $entry->{object};
 639
 640   $item_obj->add_delivery_order_stock_entries($object);
 641
 642   $self->check_warehouse($entry);
 643   $self->check_bin($entry);
 644
 645   $self->handle_unit($entry, $item_obj->part);
 646
 647   # check if enough is stocked
 648   # not necessary, because overall stock underrun is checked later
 649   # if ($order_obj->is_sales) {
 650   #   my $stocked_qty = $self->get_stocked_qty($item_obj->parts_id,
 651   #                                            $object->warehouse_id,
 652   #                                            $object->bin_id,
 653   #                                            $object->chargenumber,
 654   #                                            $object->bestbefore);
 655   #   if ($stocked_qty < $object->qty) {
 656   #     push @{ $entry->{errors} }, $::locale->text('Error: Not enough parts in stock');
 657   #   }
 658   # }
 659
 660   my ($stock_info_entry, $part) = @_;
 661
 662   # Todo: option: should stock?
 663   if (1) {
 664     my $tt_key = $order_obj->is_sales
 665                ? _transfer_type_dir_and_description_maker('out', 'shipped')
 666                : _transfer_type_dir_and_description_maker('in', 'stock');
 667     my $trans_type_id = $self->transfer_types_by->{_transfer_type_dir_and_description_ident()}{$tt_key}->id;
 668
 669     my $qty = $order_obj->is_sales ? -1*($object->qty) : $object->qty;
 670     my $inventory = SL::DB::Inventory->new(
 671       parts_id      => $item_obj->parts_id,
 672       warehouse_id  => $object->warehouse_id,
 673       bin_id        => $object->bin_id,
 674       trans_type_id => $trans_type_id,
 675       qty           => $qty,
 676       chargenumber  => $object->chargenumber,
 677       employee_id   => $order_obj->employee_id,
 678       shippingdate  => ($order_obj->reqdate || DateTime->today_local),
 679       comment       => $order_obj->transaction_description,
 680       project_id    => ($order_obj->globalproject_id || $item_obj->project_id),
 681     );
 682     $inventory->bestbefore($object->bestbefore) if $::instance_conf->get_show_bestbefore;
 683     $object->{inventory_obj} = $inventory;
 684     $order_obj->delivered(1);
 685   }
 686 }
 687
 688 sub handle_is_sales {
 689   my ($self, $entry) = @_;
 690
 691   if (!exists $entry->{raw_data}->{is_sales}) {
 692     $entry->{object}->is_sales(!!$entry->{object}->customer_id);
 693   }
 694 }
 695
 696 sub handle_order_sources {
 697   my ($self, $entry) = @_;
 698
 699   my $record = $entry->{object};
 700
 701   $record->{source_orders} = [];
 702   return $record->{source_orders} if !$record->ordnumber;
 703
 704   my @order_numbers = split ' ', $record->ordnumber;
 705
 706   my $orders = SL::DB::Manager::Order->get_all(where => [ordnumber => \@order_numbers]);
 707
 708   if (scalar @$orders == 0) {
 709     push @{ $entry->{errors} }, $::locale->text('Error: Source order not found');
 710   } elsif (scalar @$orders > 1) {
 711     push @{ $entry->{errors} }, $::locale->text('Error: More than one source order found');
 712   }
 713
 714   $record->{source_orders} = $orders;
 715 }
 716
 717 sub handle_item_source {
 718   my ($self, $entry, $record_entry) = @_;
 719
 720   my $item   = $entry->{object};
 721   my $record = $record_entry->{object};
 722
 723   return if !@{ $record->{source_orders} };
 724
 725   foreach my $order (@{ $record->{source_orders} }) {
 726     $item->{source_item} = first { $item->parts_id == $_->parts_id && $item->qty == $_->qty} @{ $order->items_sorted };
 727     last if $item->{source_item};
 728   }
 729 }
 730
 731 sub handle_unit {
 732   my ($self, $entry, $part) = @_;
 733
 734   my $object = $entry->{object};
 735
 736   $part ||= $object->part;
 737
 738   # Set unit from part if not given.
 739   if (!$object->unit) {
 740     $object->unit($part->unit);
 741     return 1;
 742   }
 743
 744   # Check whether or not unit is valid.
 745   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 746     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 747     return 0;
 748   }
 749
 750   # Check whether unit is convertible to parts unit
 751   if (none { $object->unit eq $_ } map { $_->name } @{ $part->unit_obj->convertible_units }) {
 752     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 753     return 0;
 754   }
 755
 756   return 1;
 757 }
 758
 759 sub handle_sellprice {
 760   my ($self, $entry, $record_entry) = @_;
 761
 762   my $item   = $entry->{object};
 763   my $record = $record_entry->{object};
 764
 765   return if !$record->customervendor;
 766
 767   # If sellprice is given, set price source to pricegroup if given or to none.
 768   if (exists $entry->{raw_data}->{sellprice}) {
 769     my $price_source      = SL::PriceSource->new(record_item => $item, record => $record);
 770     my $price_source_spec = $item->pricegroup_id ? 'pricegroup' . '/' . $item->pricegroup_id : '';
 771     my $price             = $price_source->price_from_source($price_source_spec);
 772     $item->active_price_source($price->source);
 773
 774   } else {
 775
 776     if ($item->{source_item}) {
 777       # Set sellprice from source order item if not given. Convert with respect to unit.
 778       my $sellprice = $item->{source_item}->sellprice;
 779       if ($item->unit ne $item->{source_item}->unit) {
 780         $sellprice = $item->unit_obj->convert_to($sellprice, $item->{source_item}->unit_obj);
 781       }
 782       $item->sellprice($sellprice);
 783       $item->active_price_source($item->{source_item}->active_price_source);
 784
 785     } else {
 786       # Set sellprice the best price of price source
 787       my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 788       my $price        = $price_source->best_price;
 789       if ($price) {
 790         $item->sellprice($price->price);
 791         $item->active_price_source($price->source);
 792       } else {
 793         $item->sellprice(0);
 794         $item->active_price_source($price_source->price_from_source('')->source);
 795       }
 796     }
 797   }
 798 }
 799
 800 sub handle_discount {
 801   my ($self, $entry, $record_entry) = @_;
 802
 803   my $item   = $entry->{object};
 804   my $record = $record_entry->{object};
 805
 806   return if !$record->customervendor;
 807
 808   # If discount is given, set discount to none.
 809   if (exists $entry->{raw_data}->{discount}) {
 810     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 811     my $discount     = $price_source->price_from_source('');
 812     $item->active_discount_source($discount->source);
 813
 814   } else {
 815
 816     if ($item->{source_item}) {
 817       # Set discount from source order item if not given.
 818       $item->discount($item->{source_item}->discount);
 819       $item->active_discount_source($item->{source_item}->active_discount_source);
 820
 821     } else {
 822       # Set discount the best discount of price source
 823       my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 824       my $discount     = $price_source->best_discount;
 825       if ($discount) {
 826         $item->discount($discount->discount);
 827         $item->active_discount_source($discount->source);
 828       } else {
 829         $item->discount(0);
 830         $item->active_discount_source($price_source->discount_from_source('')->source);
 831       }
 832     }
 833   }
 834 }
 835
 836 sub check_contact {
 837   my ($self, $entry) = @_;
 838
 839   my $object = $entry->{object};
 840
 841   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 842   return 0 unless $cp_cv_id;
 843
 844   # Check whether or not contact ID is valid.
 845   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 846     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 847     return 0;
 848   }
 849
 850   # Map name to ID if given.
 851   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 852     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 853     if (!$cp) {
 854       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 855       return 0;
 856     }
 857
 858     $object->cp_id($cp->cp_id);
 859   }
 860
 861   if ($object->cp_id) {
 862     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 863   }
 864
 865   return 1;
 866 }
 867
 868 sub check_language {
 869   my ($self, $entry) = @_;
 870
 871   my $object = $entry->{object};
 872
 873   # Check whether or not language ID is valid.
 874   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 875     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 876     return 0;
 877   }
 878
 879   # Map name to ID if given.
 880   if (!$object->language_id && $entry->{raw_data}->{language}) {
 881     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 882                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 883
 884     if (!$language) {
 885       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 886       return 0;
 887     }
 888
 889     $object->language_id($language->id);
 890   }
 891
 892   if ($object->language_id) {
 893     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 894   }
 895
 896   return 1;
 897 }
 898
 899 sub check_ct_shipto {
 900   my ($self, $entry) = @_;
 901
 902   my $object = $entry->{object};
 903
 904   my $trans_id = $object->customer_id || $object->vendor_id;
 905   return 0 unless $trans_id;
 906
 907   # Check whether or not shipto ID is valid.
 908   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 909     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 910     return 0;
 911   }
 912
 913   return 1;
 914 }
 915
 916 sub check_part {
 917   my ($self, $entry) = @_;
 918
 919   my $object = $entry->{object};
 920   my $is_ambiguous;
 921
 922   # Check whether or not part ID is valid.
 923   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 924     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 925     return 0;
 926   }
 927
 928   # Map number to ID if given.
 929   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 930     my $part = $self->parts_by->{partnumber}->{ trim($entry->{raw_data}->{partnumber}) };
 931     if (!$part) {
 932       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 933       return 0;
 934     }
 935
 936     $object->parts_id($part->id);
 937   }
 938
 939   # Map description to ID if given.
 940   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 941     my $part = $self->parts_by->{description}->{ trim($entry->{raw_data}->{description}) };
 942     if (!$part) {
 943       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 944       return 0;
 945     }
 946
 947     if ($self->part_counts_by->{description}->{ trim($entry->{raw_data}->{description}) } > 1) {
 948       $is_ambiguous = 1;
 949     } else {
 950       $object->parts_id($part->id);
 951     }
 952   }
 953
 954   # Map ean to ID if given.
 955   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 956     my $part = $self->parts_by->{ean}->{ trim($entry->{raw_data}->{ean}) };
 957     if (!$part) {
 958       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 959       return 0;
 960     }
 961
 962     if ($self->part_counts_by->{ean}->{ trim($entry->{raw_data}->{ean}) } > 1) {
 963       $is_ambiguous = 1;
 964     } else {
 965       $object->parts_id($part->id);
 966     }
 967   }
 968
 969   if ($object->parts_id) {
 970     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 971   } else {
 972     if ($is_ambiguous) {
 973       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
 974     } else {
 975       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 976     }
 977     return 0;
 978   }
 979
 980   return 1;
 981 }
 982
 983 sub check_price_factor {
 984   my ($self, $entry) = @_;
 985
 986   my $object = $entry->{object};
 987
 988   # Check whether or not price_factor ID is valid.
 989   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 990     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 991     return 0;
 992   }
 993
 994   # Map description to ID if given.
 995   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 996     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 997     if (!$price_factor) {
 998       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 999       return 0;
1000     }
1001
1002     $object->price_factor_id($price_factor->id);
1003   }
1004
1005   return 1;
1006 }
1007
1008 sub check_pricegroup {
1009   my ($self, $entry) = @_;
1010
1011   my $object = $entry->{object};
1012
1013   # Check whether or not pricegroup ID is valid.
1014   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
1015     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
1016     return 0;
1017   }
1018
1019   # Map pricegroup to ID if given.
1020   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
1021     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
1022     if (!$pricegroup) {
1023       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
1024       return 0;
1025     }
1026
1027     $object->pricegroup_id($pricegroup->id);
1028   }
1029
1030   return 1;
1031 }
1032
1033 sub check_warehouse {
1034   my ($self, $entry) = @_;
1035
1036   my $object = $entry->{object};
1037
1038   # Check whether or not warehouse ID is valid.
1039   if ($object->warehouse_id && !$self->warehouses_by->{id}->{ $object->warehouse_id }) {
1040     push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse');
1041     return 0;
1042   }
1043
1044   # Map description to ID if given.
1045   if (!$object->warehouse_id && $entry->{raw_data}->{warehouse}) {
1046     my $wh = $self->warehouses_by->{description}->{ $entry->{raw_data}->{warehouse} };
1047     if (!$wh) {
1048       push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse');
1049       return 0;
1050     }
1051
1052     $object->warehouse_id($wh->id);
1053   }
1054
1055   if ($object->warehouse_id) {
1056     $entry->{info_data}->{warehouse} = $self->warehouses_by->{id}->{ $object->warehouse_id }->description;
1057   } else {
1058     push @{ $entry->{errors} }, $::locale->text('Error: Warehouse not found');
1059     return 0;
1060   }
1061
1062   return 1;
1063 }
1064
1065 # Check bin for given warehouse, so check_warehouse must be called first.
1066 sub check_bin {
1067   my ($self, $entry) = @_;
1068
1069   my $object = $entry->{object};
1070
1071   # Check whether or not bin ID is valid.
1072   if ($object->bin_id && !$self->bins_by->{_wh_id_and_id_ident()}->{ _wh_id_and_id_maker($object->warehouse_id, $object->bin_id) }) {
1073     push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin');
1074     return 0;
1075   }
1076
1077   # Map description to ID if given.
1078   if (!$object->bin_id && $entry->{raw_data}->{bin}) {
1079     my $bin = $self->bins_by->{_wh_id_and_description_ident()}->{ _wh_id_and_description_maker($object->warehouse_id, $entry->{raw_data}->{bin}) };
1080     if (!$bin) {
1081       push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin');
1082       return 0;
1083     }
1084
1085     $object->bin_id($bin->id);
1086   }
1087
1088   if ($object->bin_id) {
1089     $entry->{info_data}->{bin} = $self->bins_by->{_wh_id_and_id_ident()}->{ _wh_id_and_id_maker($object->warehouse_id, $object->bin_id) }->description;
1090   } else {
1091     push @{ $entry->{errors} }, $::locale->text('Error: Bin not found');
1092     return 0;
1093   }
1094
1095   return 1;
1096 }
1097
1098 sub save_additions {
1099   my ($self, $object) = @_;
1100
1101   # record links
1102   my $orders = delete $object->{source_orders};
1103
1104   if (scalar(@$orders)) {
1105
1106     $_->link_to_record($object) for @$orders;
1107
1108     foreach my $item (@{ $object->items }) {
1109       my $orderitem = delete $item->{source_item};
1110       $orderitem->link_to_record($item) if $orderitem;
1111     }
1112   }
1113
1114   # delivery order for all positions created?
1115   if (scalar(@$orders)) {
1116     SL::Helper::ShippedQty->new->calculate($orders)->write_to_objects;
1117     $_->update_attributes(delivered => $_->delivered) for @{ $orders };
1118   }
1119
1120   # inventory (or use WH->transfer?)
1121   foreach my $item (@{ $object->items }) {
1122     foreach my $stock_info (@{ $item->delivery_order_stock_entries }) {
1123       my $inventory  = delete $stock_info->{inventory_obj};
1124       next if !$inventory;
1125       my ($trans_id) = selectrow_query($::form, $object->db->dbh, qq|SELECT nextval('id')|);
1126       $inventory->trans_id($trans_id);
1127       $inventory->oe_id($object->id);
1128       $inventory->delivery_order_items_stock_id($stock_info->id);
1129       $inventory->save;
1130     }
1131   }
1132 }
1133
1134 sub save_objects {
1135   my ($self, %params) = @_;
1136
1137   # Collect orders without errors to save.
1138   my $entries_to_save = [];
1139   foreach my $entry (@{ $self->controller->data }) {
1140     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
1141     next if @{ $entry->{errors} };
1142
1143     push @{ $entries_to_save }, $entry;
1144   }
1145
1146   $self->SUPER::save_objects(data => $entries_to_save);
1147 }
1148
1149 sub get_stocked_qty {
1150   my ($self, $parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore) = @_;
1151
1152   my $key = join '+', $parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore;
1153   return $self->{stocked_qty}->{$key} if exists $self->{stocked_qty}->{$key};
1154
1155   my $bestbefore_filter  = '';
1156   my $bestbefore_val_cnt = 0;
1157   if ($::instance_conf->get_show_bestbefore) {
1158     $bestbefore_filter  = ($bestbefore) ? 'AND bestbefore = ?' : 'AND bestbefore IS NULL';
1159     $bestbefore_val_cnt = ($bestbefore) ? 1                    : 0;
1160   }
1161
1162   my $query = <<SQL;
1163     SELECT sum(qty) FROM inventory
1164       WHERE parts_id = ? AND warehouse_id = ? AND bin_id = ? AND chargenumber = ? $bestbefore_filter
1165       GROUP BY warehouse_id, bin_id, chargenumber
1166 SQL
1167
1168   my @values = ($parts_id,
1169                 $wh_id,
1170                 $bin_id,
1171                 $chargenumber);
1172   push @values, $bestbefore if $bestbefore_val_cnt;
1173
1174   my $dbh = $self->controller->data->[0]{object}->db->dbh;
1175   my ($stocked_qty) = selectrow_query($::form, $dbh, $query, @values);
1176
1177   $self->{stocked_qty}->{$key} = $stocked_qty;
1178   return $stocked_qty;
1179 }
1180
1181 sub _wh_id_and_description_ident {
1182   return 'wh_id+description';
1183 }
1184
1185 sub _wh_id_and_description_maker {
1186   return join '+', $_[0], $_[1]
1187 }
1188
1189 sub _wh_id_and_id_ident {
1190   return 'wh_id+id';
1191 }
1192
1193 sub _wh_id_and_id_maker {
1194   return join '+', $_[0], $_[1]
1195 }
1196
1197 sub _transfer_type_dir_and_description_ident {
1198   return 'dir+description';
1199 }
1200
1201 sub _transfer_type_dir_and_description_maker {
1202   return join '+', $_[0], $_[1]
1203 }
1204
1205 sub _order_column {
1206   $_[0]->settings->{'order_column'}
1207 }
1208
1209 sub _item_column {
1210   $_[0]->settings->{'item_column'}
1211 }
1212
1213 sub _stock_column {
1214   $_[0]->settings->{'stock_column'}
1215 }
1216
1217 1;