SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::Helper::Csv;
   9 use SL::DB::Order;
  10 use SL::DB::OrderItem;
  11 use SL::DB::Part;
  12 use SL::DB::PaymentTerm;
  13 use SL::DB::Contact;
  14 use SL::DB::Department;
  15 use SL::DB::PriceFactor;
  16 use SL::DB::Pricegroup;
  17 use SL::DB::Project;
  18 use SL::DB::Shipto;
  19 use SL::DB::TaxZone;
  20 use SL::TransNumber;
  21
  22 use parent qw(SL::Controller::CsvImport::BaseMulti);
  23
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by departments_by projects_by ct_shiptos_by taxzones_by price_factors_by pricegroups_by currencies_by) ],
  28 );
  29
  30
  31 sub init_class {
  32   my ($self) = @_;
  33   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  34 }
  35
  36
  37 sub init_settings {
  38   my ($self) = @_;
  39
  40   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  41 }
  42
  43
  44 sub init_profile {
  45   my ($self) = @_;
  46
  47   my $profile = $self->SUPER::init_profile;
  48
  49   # SUPER::init_profile sets row_ident to the translated class name
  50   # overwrite it with the user specified settings
  51   foreach my $p (@{ $profile }) {
  52     if ($p->{class} eq 'SL::DB::Order') {
  53       $p->{row_ident} = $self->_order_column;
  54     }
  55     if ($p->{class} eq 'SL::DB::OrderItem') {
  56       $p->{row_ident} = $self->_item_column;
  57     }
  58   }
  59
  60   foreach my $p (@{ $profile }) {
  61     my $prof = $p->{profile};
  62     if ($p->{row_ident} eq $self->_order_column) {
  63       # no need to handle
  64       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  65     }
  66     if ($p->{row_ident} eq $self->_item_column) {
  67       # no need to handle
  68       delete @{$prof}{qw(trans_id)};
  69     }
  70   }
  71
  72   return $profile;
  73 }
  74
  75
  76 sub setup_displayable_columns {
  77   my ($self) = @_;
  78
  79   $self->SUPER::setup_displayable_columns;
  80
  81   $self->add_displayable_columns($self->_order_column,
  82                                  { name => 'datatype',         description => $self->_order_column                              },
  83                                  { name => 'closed',           description => $::locale->text('Closed')                         },
  84                                  { name => 'currency',         description => $::locale->text('Currency')                       },
  85                                  { name => 'currency_id',      description => $::locale->text('Currency (database ID)')         },
  86                                  { name => 'cusordnumber',     description => $::locale->text('Customer Order Number')          },
  87                                  { name => 'delivered',        description => $::locale->text('Delivered')                      },
  88                                  { name => 'employee_id',      description => $::locale->text('Employee (database ID)')         },
  89                                  { name => 'intnotes',         description => $::locale->text('Internal Notes')                 },
  90                                  { name => 'marge_percent',    description => $::locale->text('Margepercent')                   },
  91                                  { name => 'marge_total',      description => $::locale->text('Margetotal')                     },
  92                                  { name => 'notes',            description => $::locale->text('Notes')                          },
  93                                  { name => 'ordnumber',        description => $::locale->text('Order Number')                   },
  94                                  { name => 'quonumber',        description => $::locale->text('Quotation Number')               },
  95                                  { name => 'reqdate',          description => $::locale->text('Reqdate')                        },
  96                                  { name => 'salesman_id',      description => $::locale->text('Salesman (database ID)')         },
  97                                  { name => 'shippingpoint',    description => $::locale->text('Shipping Point')                 },
  98                                  { name => 'shipvia',          description => $::locale->text('Ship via')                       },
  99                                  { name => 'transaction_description', description => $::locale->text('Transaction description') },
 100                                  { name => 'transdate',        description => $::locale->text('Order Date')                     },
 101                                  { name => 'verify_amount',    description => $::locale->text('Amount (for verification)')      },
 102                                  { name => 'verify_netamount', description => $::locale->text('Net amount (for verification)')  },
 103                                  { name => 'taxincluded',      description => $::locale->text('Tax Included')                   },
 104                                  { name => 'customer',         description => $::locale->text('Customer (name)')                },
 105                                  { name => 'customernumber',   description => $::locale->text('Customer Number')                },
 106                                  { name => 'customer_id',      description => $::locale->text('Customer (database ID)')         },
 107                                  { name => 'vendor',           description => $::locale->text('Vendor (name)')                  },
 108                                  { name => 'vendornumber',     description => $::locale->text('Vendor Number')                  },
 109                                  { name => 'vendor_id',        description => $::locale->text('Vendor (database ID)')           },
 110                                  { name => 'language_id',      description => $::locale->text('Language (database ID)')         },
 111                                  { name => 'language',         description => $::locale->text('Language (name)')                },
 112                                  { name => 'payment_id',       description => $::locale->text('Payment terms (database ID)')    },
 113                                  { name => 'payment',          description => $::locale->text('Payment terms (name)')           },
 114                                  { name => 'taxzone_id',       description => $::locale->text('Steuersatz (database ID')        },
 115                                  { name => 'taxzone',          description => $::locale->text('Steuersatz (description)')       },
 116                                  { name => 'cp_id',            description => $::locale->text('Contact Person (database ID)')   },
 117                                  { name => 'contact',          description => $::locale->text('Contact Person (name)')          },
 118                                  { name => 'department_id',    description => $::locale->text('Department (database ID)')       },
 119                                  { name => 'department',       description => $::locale->text('Department (description)')       },
 120                                  { name => 'globalproject_id', description => $::locale->text('Document Project (database ID)') },
 121                                  { name => 'globalprojectnumber', description => $::locale->text('Document Project (number)')   },
 122                                  { name => 'globalproject',    description => $::locale->text('Document Project (description)') },
 123                                  { name => 'shipto_id',        description => $::locale->text('Ship to (database ID)')          },
 124                                 );
 125
 126   $self->add_displayable_columns($self->_item_column,
 127                                  { name => 'datatype',        description => $self->_item_column                           },
 128                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 129                                  { name => 'description',     description => $::locale->text('Description')                },
 130                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 131                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 132                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 133                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 134                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 135                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 136                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 137                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 138                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 139                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 140                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 141                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 142                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 143                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 144                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 145                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 146                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 147                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 148                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 149                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 150                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 151                                 );
 152 }
 153
 154
 155 sub init_languages_by {
 156   my ($self) = @_;
 157
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 159 }
 160
 161 sub init_parts_by {
 162   my ($self) = @_;
 163
 164   my $all_parts = SL::DB::Manager::Part->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 166 }
 167
 168 sub init_contacts_by {
 169   my ($self) = @_;
 170
 171   my $all_contacts = SL::DB::Manager::Contact->get_all;
 172
 173   my $cby;
 174   # by customer/vendor id  _and_  contact person id
 175   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 176   # by customer/vendor id  _and_  contact person name
 177   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 178
 179   return $cby;
 180 }
 181
 182 sub init_departments_by {
 183   my ($self) = @_;
 184
 185   my $all_departments = SL::DB::Manager::Department->get_all;
 186   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_departments } } ) } qw(id description) };
 187 }
 188
 189 sub init_projects_by {
 190   my ($self) = @_;
 191
 192   my $all_projects = SL::DB::Manager::Project->get_all;
 193   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_projects } } ) } qw(id projectnumber description) };
 194 }
 195
 196 sub init_ct_shiptos_by {
 197   my ($self) = @_;
 198
 199   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 200
 201   my $sby;
 202   # by trans_id  _and_  shipto_id
 203   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 204
 205   return $sby;
 206 }
 207
 208 sub init_taxzones_by {
 209   my ($self) = @_;
 210
 211   my $all_taxzones = SL::DB::Manager::TaxZone->get_all;
 212   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_taxzones } } ) } qw(id description) };
 213 }
 214
 215 sub init_price_factors_by {
 216   my ($self) = @_;
 217
 218   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 219   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 220 }
 221
 222 sub init_pricegroups_by {
 223   my ($self) = @_;
 224
 225   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 226   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 227 }
 228
 229 sub init_currencies_by {
 230   my ($self) = @_;
 231
 232   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_currencies } } ) } qw(id name) };
 233 }
 234
 235 sub check_objects {
 236   my ($self) = @_;
 237
 238   $self->controller->track_progress(phase => 'building data', progress => 0);
 239
 240   my $i;
 241   my $num_data = scalar @{ $self->controller->data };
 242   foreach my $entry (@{ $self->controller->data }) {
 243     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 244
 245     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 246
 247       my $vc_obj;
 248       if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 249         $self->check_vc($entry, 'customer_id');
 250         $vc_obj = SL::DB::Customer->new(id => $entry->{object}->customer_id)->load if $entry->{object}->customer_id;
 251       } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 252         $self->check_vc($entry, 'vendor_id');
 253         $vc_obj = SL::DB::Vendor->new(id => $entry->{object}->vendor_id)->load if $entry->{object}->vendor_id;
 254       } else {
 255         push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 256       }
 257
 258       $self->check_contact($entry);
 259       $self->check_language($entry);
 260       $self->check_payment($entry);
 261       $self->check_department($entry);
 262       $self->check_project($entry, global => 1);
 263       $self->check_ct_shipto($entry);
 264       $self->check_taxzone($entry);
 265       $self->check_currency($entry);
 266
 267       if ($vc_obj) {
 268         # copy from customer if not given
 269         foreach (qw(payment_id language_id taxzone_id currency_id)) {
 270           $entry->{object}->$_($vc_obj->$_) unless $entry->{object}->$_;
 271         }
 272       }
 273
 274       # ToDo: salesman and emloyee by name
 275       # salesman from customer or login if not given
 276       if (!$entry->{object}->salesman) {
 277         if ($vc_obj && $vc_obj->salesman_id) {
 278           $entry->{object}->salesman(SL::DB::Manager::Employee->find_by(id => $vc_obj->salesman_id));
 279         } else {
 280           $entry->{object}->salesman(SL::DB::Manager::Employee->find_by(login => $::myconfig{login}));
 281         }
 282       }
 283
 284       # employee from login if not given
 285       if (!$entry->{object}->employee_id) {
 286         $entry->{object}->employee_id(SL::DB::Manager::Employee->find_by(login => $::myconfig{login})->id);
 287       }
 288
 289     }
 290   } continue {
 291     $i++;
 292   }
 293
 294   $self->add_info_columns($self->_order_column,
 295                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 296   # Todo: access via ->[0] ok? Better: search first order column and use this
 297   $self->add_columns($self->_order_column,
 298                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment language department globalproject taxzone cp currency));
 299   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 300   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 301
 302   foreach my $entry (@{ $self->controller->data }) {
 303     if ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 304
 305       next if !$self->check_part($entry);
 306
 307       my $part_obj = SL::DB::Part->new(id => $entry->{object}->parts_id)->load;
 308
 309       # copy from part if not given
 310       $entry->{object}->description($part_obj->description) unless $entry->{object}->description;
 311       $entry->{object}->longdescription($part_obj->notes)   unless $entry->{object}->longdescription;
 312       $entry->{object}->unit($part_obj->unit)               unless $entry->{object}->unit;
 313
 314       # set to 0 if not given
 315       $entry->{object}->discount(0)      unless $entry->{object}->discount;
 316       $entry->{object}->ship(0)          unless $entry->{object}->ship;
 317
 318       $self->check_project($entry, global => 0);
 319       $self->check_price_factor($entry);
 320       $self->check_pricegroup($entry);
 321     }
 322   }
 323
 324   $self->add_info_columns($self->_item_column,
 325                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 326   # Todo: access via ->[1] ok? Better: search first item column and use this
 327   $self->add_columns($self->_item_column,
 328                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 329   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 330
 331   # add orderitems to order
 332   my $order_entry;
 333   my @orderitems;
 334   foreach my $entry (@{ $self->controller->data }) {
 335     # search first Order
 336     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 337
 338       # new order entry: add collected orderitems to the last one
 339       if (defined $order_entry) {
 340         $order_entry->{object}->orderitems(@orderitems);
 341         @orderitems = ();
 342       }
 343
 344       $order_entry = $entry;
 345
 346     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 347       # collect orderitems to add to order (if they have no errors)
 348       # ( add_orderitems does not work here if we want to call
 349       #   calculate_prices_and_taxes afterwards ...
 350       #   so collect orderitems and add them at once)
 351       if (scalar @{ $entry->{errors} } == 0) {
 352         push @orderitems, $entry->{object};
 353       }
 354     }
 355   }
 356   # add last collected orderitems to last order
 357   if ($order_entry) {
 358     $order_entry->{object}->orderitems(@orderitems);
 359   }
 360
 361   # calculate prices and taxes
 362   foreach my $entry (@{ $self->controller->data }) {
 363     next if @{ $entry->{errors} };
 364
 365     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 366
 367       $entry->{object}->calculate_prices_and_taxes;
 368
 369       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 370       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 371     }
 372   }
 373
 374   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 375   # And throw an error if the differences are too big.
 376   my @to_verify = ( { column      => 'amount',
 377                       raw_column  => 'verify_amount',
 378                       info_header => 'Calc. Amount',
 379                       info_method => 'calc_amount',
 380                       err_msg     => 'Amounts differ too much',
 381                     },
 382                     { column      => 'netamount',
 383                       raw_column  => 'verify_netamount',
 384                       info_header => 'Calc. Net amount',
 385                       info_method => 'calc_netamount',
 386                       err_msg     => 'Net amounts differ too much',
 387                     } );
 388
 389   foreach my $tv (@to_verify) {
 390     # Todo: access via ->[0] ok? Better: search first order column and use this
 391     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 392       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 393       $self->add_info_columns($self->_order_column,
 394                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 395     }
 396
 397     # check differences
 398     foreach my $entry (@{ $self->controller->data }) {
 399       next if @{ $entry->{errors} };
 400       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 401         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 402         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 403         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 404           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 405         }
 406       }
 407     }
 408   }
 409
 410   # If order has errors set error for orderitems as well
 411   $order_entry = undef;
 412   foreach my $entry (@{ $self->controller->data }) {
 413     # Search first order
 414     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 415       $order_entry = $entry;
 416     } elsif ( defined $order_entry
 417               && $entry->{raw_data}->{datatype} eq $self->_item_column
 418               && scalar @{ $order_entry->{errors} } > 0 ) {
 419       push @{ $entry->{errors} }, $::locale->text('order not valid for this orderitem!');
 420     }
 421   }
 422
 423 }
 424
 425
 426 sub check_language {
 427   my ($self, $entry) = @_;
 428
 429   my $object = $entry->{object};
 430
 431   # Check whether or not language ID is valid.
 432   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 433     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 434     return 0;
 435   }
 436
 437   # Map name to ID if given.
 438   if (!$object->language_id && $entry->{raw_data}->{language}) {
 439     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 440                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 441
 442     if (!$language) {
 443       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 444       return 0;
 445     }
 446
 447     $object->language_id($language->id);
 448   }
 449
 450   if ($object->language_id) {
 451     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 452   }
 453
 454   return 1;
 455 }
 456
 457 sub check_part {
 458   my ($self, $entry) = @_;
 459
 460   my $object = $entry->{object};
 461
 462   # Check wether or non part ID is valid.
 463   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 464     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 465     return 0;
 466   }
 467
 468   # Map number to ID if given.
 469   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 470     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 471     if (!$part) {
 472       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 473       return 0;
 474     }
 475
 476     $object->parts_id($part->id);
 477   }
 478
 479   if ($object->parts_id) {
 480     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 481   } else {
 482     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 483     return 0;
 484   }
 485
 486   return 1;
 487 }
 488
 489 sub check_contact {
 490   my ($self, $entry) = @_;
 491
 492   my $object = $entry->{object};
 493
 494   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 495   return 0 unless $cp_cv_id;
 496
 497   # Check wether or not contact ID is valid.
 498   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 499     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 500     return 0;
 501   }
 502
 503   # Map name to ID if given.
 504   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 505     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 506     if (!$cp) {
 507       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 508       return 0;
 509     }
 510
 511     $object->cp_id($cp->cp_id);
 512   }
 513
 514   if ($object->cp_id) {
 515     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 516   }
 517
 518   return 1;
 519 }
 520
 521 sub check_department {
 522   my ($self, $entry) = @_;
 523
 524   my $object = $entry->{object};
 525
 526   # Check wether or not department ID is valid.
 527   if ($object->department_id && !$self->departments_by->{id}->{ $object->department_id }) {
 528     push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 529     return 0;
 530   }
 531
 532   # Map description to ID if given.
 533   if (!$object->department_id && $entry->{raw_data}->{department}) {
 534     my $dep = $self->departments_by->{description}->{ $entry->{raw_data}->{department} };
 535     if (!$dep) {
 536       push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 537       return 0;
 538     }
 539
 540     $object->department_id($dep->id);
 541   }
 542
 543   return 1;
 544 }
 545
 546 sub check_project {
 547   my ($self, $entry, %params) = @_;
 548
 549   my $id_column          = ($params{global} ? 'global' : '') . 'project_id';
 550   my $number_column      = ($params{global} ? 'global' : '') . 'projectnumber';
 551   my $description_column = ($params{global} ? 'global' : '') . 'project';
 552
 553   my $object = $entry->{object};
 554
 555   # Check wether or not projetc ID is valid.
 556   if ($object->$id_column && !$self->projects_by->{id}->{ $object->$id_column }) {
 557     push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 558     return 0;
 559   }
 560
 561   # Map number to ID if given.
 562   if (!$object->$id_column && $entry->{raw_data}->{$number_column}) {
 563     my $proj = $self->projects_by->{projectnumber}->{ $entry->{raw_data}->{$number_column} };
 564     if (!$proj) {
 565       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 566       return 0;
 567     }
 568
 569     $object->$id_column($proj->id);
 570   }
 571
 572   # Map description to ID if given.
 573   if (!$object->$id_column && $entry->{raw_data}->{$description_column}) {
 574     my $proj = $self->projects_by->{description}->{ $entry->{raw_data}->{$description_column} };
 575     if (!$proj) {
 576       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 577       return 0;
 578     }
 579
 580     $object->$id_column($proj->id);
 581   }
 582
 583   return 1;
 584 }
 585
 586 sub check_ct_shipto {
 587   my ($self, $entry) = @_;
 588
 589   my $object = $entry->{object};
 590
 591   my $trans_id = $object->customer_id || $object->vendor_id;
 592   return 0 unless $trans_id;
 593
 594   # Check wether or not shipto ID is valid.
 595   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 596     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 597     return 0;
 598   }
 599
 600   return 1;
 601 }
 602
 603 sub check_taxzone {
 604   my ($self, $entry) = @_;
 605
 606   my $object = $entry->{object};
 607
 608   # Check wether or not taxzone ID is valid.
 609   if ($object->taxzone_id && !$self->taxzones_by->{id}->{ $object->taxzone_id }) {
 610     push @{ $entry->{errors} }, $::locale->text('Error: Invalid taxzone');
 611     return 0;
 612   }
 613
 614   # Map description to ID if given.
 615   if (!$object->taxzone_id && $entry->{raw_data}->{taxzone}) {
 616     my $taxzone = $self->taxzones_by->{description}->{ $entry->{raw_data}->{taxzone} };
 617     if (!$taxzone) {
 618       push @{ $entry->{errors} }, $::locale->text('Error: Invalid taxzone');
 619       return 0;
 620     }
 621
 622     $object->taxzone_id($taxzone->id);
 623   }
 624
 625   return 1;
 626 }
 627
 628 sub check_price_factor {
 629   my ($self, $entry) = @_;
 630
 631   my $object = $entry->{object};
 632
 633   # Check wether or not price_factor ID is valid.
 634   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 635     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 636     return 0;
 637   }
 638
 639   # Map description to ID if given.
 640   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 641     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 642     if (!$price_factor) {
 643       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 644       return 0;
 645     }
 646
 647     $object->price_factor_id($price_factor->id);
 648   }
 649
 650   return 1;
 651 }
 652
 653 sub check_pricegroup {
 654   my ($self, $entry) = @_;
 655
 656   my $object = $entry->{object};
 657
 658   # Check wether or not pricegroup ID is valid.
 659   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 660     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 661     return 0;
 662   }
 663
 664   # Map pricegroup to ID if given.
 665   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 666     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 667     if (!$pricegroup) {
 668       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 669       return 0;
 670     }
 671
 672     $object->pricegroup_id($pricegroup->id);
 673   }
 674
 675   return 1;
 676 }
 677
 678 sub check_currency {
 679   my ($self, $entry) = @_;
 680
 681   my $object = $entry->{object};
 682
 683   # Check whether or not currency ID is valid.
 684   if ($object->currency_id && !$self->currencies_by->{id}->{ $object->currency_id }) {
 685     push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 686     return 0;
 687   }
 688
 689   # Map name to ID if given.
 690   if (!$object->currency_id && $entry->{raw_data}->{currency}) {
 691     my $currency = $self->currencies_by->{name}->{  $entry->{raw_data}->{currency} };
 692     if (!$currency) {
 693       push @{ $entry->{errors} }, $::locale->text('Error: Invalid currency');
 694       return 0;
 695     }
 696
 697     $object->currency_id($currency->id);
 698   }
 699
 700   return 1;
 701 }
 702
 703
 704 sub save_objects {
 705   my ($self, %params) = @_;
 706
 707   # set order number and collect to save
 708   my $objects_to_save;
 709   foreach my $entry (@{ $self->controller->data }) {
 710     next if @{ $entry->{errors} };
 711
 712     if ($entry->{raw_data}->{datatype} eq $self->_order_column && !$entry->{object}->ordnumber) {
 713       my $number = SL::TransNumber->new(type        => 'sales_order',
 714                                         save        => 1);
 715       $entry->{object}->ordnumber($number->create_unique());
 716     }
 717
 718     push @{ $objects_to_save }, $entry;
 719   }
 720
 721   $self->SUPER::save_objects(data => $objects_to_save);
 722 }
 723
 724 sub _order_column {
 725   $_[0]->settings->{'order_column'}
 726 }
 727
 728 sub _item_column {
 729   $_[0]->settings->{'item_column'}
 730 }
 731
 732 1;