SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::TransNumber;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_gln',            description => $::locale->text('Customer GLN')                          },
 137                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 138                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 139                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 140                                  { name => 'vendor_gln',              description => $::locale->text('Vendor GLN')                            },
 141                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 142                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 143                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 144                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 145                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 146                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 147                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 148                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 149                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 150                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 151                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 152                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 153                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 154                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 155                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 156                                 );
 157
 158   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 159
 160   $self->add_displayable_columns($self->_item_column,
 161                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 162                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 163                                  { name => 'description',     description => $::locale->text('Description')                },
 164                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 165                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 166                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 167                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 168                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 169                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 170                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 171                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 172                                  { name => 'position',        description => $::locale->text('position')                   },
 173                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 174                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 175                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 176                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 177                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 178                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 179                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 180                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 181                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 182                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 183                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 184                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 185                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 186                                 );
 187 }
 188
 189
 190 sub init_languages_by {
 191   my ($self) = @_;
 192
 193   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 194 }
 195
 196 sub init_parts_by {
 197   my ($self) = @_;
 198
 199   my $all_parts = SL::DB::Manager::Part->get_all;
 200   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 201 }
 202
 203 sub init_contacts_by {
 204   my ($self) = @_;
 205
 206   my $all_contacts = SL::DB::Manager::Contact->get_all;
 207
 208   my $cby;
 209   # by customer/vendor id  _and_  contact person id
 210   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 211   # by customer/vendor id  _and_  contact person name
 212   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 213
 214   return $cby;
 215 }
 216
 217 sub init_ct_shiptos_by {
 218   my ($self) = @_;
 219
 220   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 221
 222   my $sby;
 223   # by trans_id  _and_  shipto_id
 224   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 225
 226   return $sby;
 227 }
 228
 229 sub init_price_factors_by {
 230   my ($self) = @_;
 231
 232   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 233   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 234 }
 235
 236 sub init_pricegroups_by {
 237   my ($self) = @_;
 238
 239   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 240   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 241 }
 242
 243 sub init_units_by {
 244   my ($self) = @_;
 245
 246   my $all_units = SL::DB::Manager::Unit->get_all;
 247   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 248 }
 249
 250 sub check_objects {
 251   my ($self) = @_;
 252
 253   $self->controller->track_progress(phase => 'building data', progress => 0);
 254
 255   my $i = 0;
 256   my $num_data = scalar @{ $self->controller->data };
 257   foreach my $entry (@{ $self->controller->data }) {
 258     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 259
 260     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 261
 262     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 263       $self->handle_order($entry);
 264     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 265       $self->handle_item($entry);
 266     }
 267     $self->handle_cvars($entry, sub_module => 'orderitems');
 268
 269   } continue {
 270     $i++;
 271   }
 272
 273   $self->add_info_columns($self->_order_column,
 274                           { header => $::locale->text('Data type'), method => 'datatype' });
 275   $self->add_info_columns($self->_item_column,
 276                           { header => $::locale->text('Data type'), method => 'datatype' });
 277
 278   $self->add_info_columns($self->_order_column,
 279                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 280   # Todo: access via ->[0] ok? Better: search first order column and use this
 281   $self->add_columns($self->_order_column,
 282                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 283   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 284   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 285
 286   $self->add_info_columns($self->_item_column,
 287                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 288   # Todo: access via ->[1] ok? Better: search first item column and use this
 289   $self->add_columns($self->_item_column,
 290                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 291   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 292
 293   $self->add_cvar_raw_data_columns();
 294
 295   $self->add_items_to_order();
 296   $self->handle_prices_and_taxes();
 297 }
 298
 299 sub handle_order {
 300   my ($self, $entry) = @_;
 301
 302   my $object = $entry->{object};
 303
 304   my $vc_obj;
 305   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_gln customer_id)) {
 306     $self->check_vc($entry, 'customer_id');
 307     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 308   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_gln vendor_id)) {
 309     $self->check_vc($entry, 'vendor_id');
 310     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 311   } else {
 312     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 313   }
 314
 315   $self->check_contact($entry);
 316   $self->check_language($entry);
 317   $self->check_payment($entry);
 318   $self->check_delivery_term($entry);
 319   $self->check_department($entry);
 320   $self->check_project($entry, global => 1);
 321   $self->check_ct_shipto($entry);
 322   $self->check_taxzone($entry);
 323   $self->check_currency($entry, take_default => 0);
 324
 325   if ($vc_obj) {
 326     # copy from customer if not given
 327     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 328       $object->$_($vc_obj->$_) unless $object->$_;
 329     }
 330   }
 331
 332   $self->handle_salesman($entry);
 333   $self->handle_employee($entry);
 334 }
 335
 336 sub check_language {
 337   my ($self, $entry) = @_;
 338
 339   my $object = $entry->{object};
 340
 341   # Check whether or not language ID is valid.
 342   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 343     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 344     return 0;
 345   }
 346
 347   # Map name to ID if given.
 348   if (!$object->language_id && $entry->{raw_data}->{language}) {
 349     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 350                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 351
 352     if (!$language) {
 353       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 354       return 0;
 355     }
 356
 357     $object->language_id($language->id);
 358   }
 359
 360   if ($object->language_id) {
 361     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 362   }
 363
 364   return 1;
 365 }
 366
 367 sub handle_item {
 368   my ($self, $entry) = @_;
 369
 370   my $object = $entry->{object};
 371   return unless $self->check_part($entry);
 372
 373   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 374
 375   $self->handle_unit($entry);
 376   $self->handle_sellprice($entry);
 377
 378   # copy from part if not given
 379   $object->description($part_obj->description) unless $object->description;
 380   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 381   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 382
 383   # set to 0 if not given
 384   $object->discount(0) unless $object->discount;
 385   $object->ship(0)     unless $object->ship;
 386
 387   $self->check_project($entry, global => 0);
 388   $self->check_price_factor($entry);
 389   $self->check_pricegroup($entry);
 390 }
 391
 392 sub handle_unit {
 393   my ($self, $entry) = @_;
 394
 395   my $object = $entry->{object};
 396
 397   # Set unit from part if not given.
 398   if (!$object->unit) {
 399     $object->unit($object->part->unit);
 400     return 1;
 401   }
 402
 403   # Check whether or not unit is valid.
 404   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 405     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 406     return 0;
 407   }
 408
 409   # Check whether unit is convertible to parts unit
 410   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 411     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 412     return 0;
 413   }
 414
 415   return 1;
 416 }
 417
 418 sub handle_sellprice {
 419   my ($self, $entry) = @_;
 420
 421   my $object = $entry->{object};
 422
 423   # Set sellprice from part if not given. Convert with respect to unit.
 424   if (!defined $object->sellprice) {
 425     my $sellprice = $object->part->sellprice;
 426
 427     if ($object->unit ne $object->part->unit) {
 428       $sellprice = $object->unit_obj->convert_to($sellprice, $object->part->unit_obj);
 429     }
 430     $object->sellprice($sellprice);
 431   }
 432 }
 433
 434 sub check_part {
 435   my ($self, $entry) = @_;
 436
 437   my $object = $entry->{object};
 438
 439   # Check whether or not part ID is valid.
 440   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 441     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 442     return 0;
 443   }
 444
 445   # Map number to ID if given.
 446   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 447     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 448     if (!$part) {
 449       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 450       return 0;
 451     }
 452
 453     $object->parts_id($part->id);
 454   }
 455
 456   # Map description to ID if given.
 457   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 458     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 459     if (!$part) {
 460       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 461       return 0;
 462     }
 463
 464     $object->parts_id($part->id);
 465   }
 466
 467   if ($object->parts_id) {
 468     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 469   } else {
 470     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 471     return 0;
 472   }
 473
 474   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 475     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 476     return 0;
 477   }
 478
 479   return 1;
 480 }
 481
 482 sub check_contact {
 483   my ($self, $entry) = @_;
 484
 485   my $object = $entry->{object};
 486
 487   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 488   return 0 unless $cp_cv_id;
 489
 490   # Check whether or not contact ID is valid.
 491   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 492     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 493     return 0;
 494   }
 495
 496   # Map name to ID if given.
 497   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 498     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 499     if (!$cp) {
 500       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 501       return 0;
 502     }
 503
 504     $object->cp_id($cp->cp_id);
 505   }
 506
 507   if ($object->cp_id) {
 508     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 509   }
 510
 511   return 1;
 512 }
 513
 514 sub check_ct_shipto {
 515   my ($self, $entry) = @_;
 516
 517   my $object = $entry->{object};
 518
 519   my $trans_id = $object->customer_id || $object->vendor_id;
 520   return 0 unless $trans_id;
 521
 522   # Check whether or not shipto ID is valid.
 523   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 524     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 525     return 0;
 526   }
 527
 528   return 1;
 529 }
 530
 531 sub check_price_factor {
 532   my ($self, $entry) = @_;
 533
 534   my $object = $entry->{object};
 535
 536   # Check whether or not price_factor ID is valid.
 537   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 538     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 539     return 0;
 540   }
 541
 542   # Map description to ID if given.
 543   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 544     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 545     if (!$price_factor) {
 546       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 547       return 0;
 548     }
 549
 550     $object->price_factor_id($price_factor->id);
 551   }
 552
 553   return 1;
 554 }
 555
 556 sub check_pricegroup {
 557   my ($self, $entry) = @_;
 558
 559   my $object = $entry->{object};
 560
 561   # Check whether or not pricegroup ID is valid.
 562   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 563     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 564     return 0;
 565   }
 566
 567   # Map pricegroup to ID if given.
 568   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 569     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 570     if (!$pricegroup) {
 571       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 572       return 0;
 573     }
 574
 575     $object->pricegroup_id($pricegroup->id);
 576   }
 577
 578   return 1;
 579 }
 580
 581 sub add_items_to_order {
 582   my ($self) = @_;
 583
 584   # add orderitems to order
 585   my $order_entry;
 586   my @orderitems;
 587   foreach my $entry (@{ $self->controller->data }) {
 588     # search first/next order
 589     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 590
 591       # next order entry: add collected orderitems to the previous one
 592       if (defined $order_entry) {
 593         $order_entry->{object}->orderitems(@orderitems);
 594         @orderitems = ();
 595       }
 596
 597       $order_entry = $entry;
 598
 599     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 600       # collect orderitems to add to order (if they have no errors)
 601       # ( add_orderitems does not work here if we want to call
 602       #   calculate_prices_and_taxes afterwards ...
 603       #   so collect orderitems and add them at once )
 604       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 605     }
 606   }
 607   # add last collected orderitems to last order
 608   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 609 }
 610
 611 sub handle_prices_and_taxes() {
 612   my ($self) = @_;
 613
 614   # calculate prices and taxes
 615   foreach my $entry (@{ $self->controller->data }) {
 616     next if @{ $entry->{errors} };
 617
 618     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 619
 620       $entry->{object}->calculate_prices_and_taxes;
 621
 622       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 623       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 624     }
 625   }
 626
 627   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 628   # And throw an error if the differences are too big.
 629   my @to_verify = ( { column      => 'amount',
 630                       raw_column  => 'verify_amount',
 631                       info_header => 'Calc. Amount',
 632                       info_method => 'calc_amount',
 633                       err_msg     => 'Amounts differ too much',
 634                     },
 635                     { column      => 'netamount',
 636                       raw_column  => 'verify_netamount',
 637                       info_header => 'Calc. Net amount',
 638                       info_method => 'calc_netamount',
 639                       err_msg     => 'Net amounts differ too much',
 640                     } );
 641
 642   foreach my $tv (@to_verify) {
 643     # Todo: access via ->[0] ok? Better: search first order column and use this
 644     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 645       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 646       $self->add_info_columns($self->_order_column,
 647                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 648     }
 649
 650     # check differences
 651     foreach my $entry (@{ $self->controller->data }) {
 652       next if @{ $entry->{errors} };
 653       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 654         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 655         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 656         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 657           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 658         }
 659       }
 660     }
 661   }
 662
 663 }
 664
 665 sub save_objects {
 666   my ($self, %params) = @_;
 667
 668   # Collect orders without errors to save.
 669   my $entries_to_save = [];
 670   foreach my $entry (@{ $self->controller->data }) {
 671     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 672     next if @{ $entry->{errors} };
 673
 674     push @{ $entries_to_save }, $entry;
 675   }
 676
 677   $self->SUPER::save_objects(data => $entries_to_save);
 678 }
 679
 680 sub _order_column {
 681   $_[0]->settings->{'order_column'}
 682 }
 683
 684 sub _item_column {
 685   $_[0]->settings->{'item_column'}
 686 }
 687
 688 1;