SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::Helper::Csv;
   9 use SL::DB::Order;
  10 use SL::DB::OrderItem;
  11 use SL::DB::Part;
  12 use SL::DB::PaymentTerm;
  13 use SL::DB::Contact;
  14 use SL::DB::Department;
  15 use SL::DB::PriceFactor;
  16 use SL::DB::Pricegroup;
  17 use SL::DB::Project;
  18 use SL::DB::Shipto;
  19 use SL::DB::TaxZone;
  20 use SL::TransNumber;
  21
  22 use parent qw(SL::Controller::CsvImport::BaseMulti);
  23
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by departments_by projects_by ct_shiptos_by taxzones_by price_factors_by pricegroups_by) ],
  28 );
  29
  30
  31 sub init_class {
  32   my ($self) = @_;
  33   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  34 }
  35
  36
  37 sub init_settings {
  38   my ($self) = @_;
  39
  40   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  41 }
  42
  43
  44 sub init_cvar_configs_by {
  45   my ($self) = @_;
  46
  47   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  48   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  49
  50   my $ccb;
  51   $ccb->{class}->{'SL::DB::Order'}          = [];
  52   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  53   $ccb->{row_ident}->{$self->_order_column} = [];
  54   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  55
  56   return $ccb;
  57 }
  58
  59
  60 sub init_profile {
  61   my ($self) = @_;
  62
  63   my $profile = $self->SUPER::init_profile;
  64
  65   # SUPER::init_profile sets row_ident to the translated class name
  66   # overwrite it with the user specified settings
  67   foreach my $p (@{ $profile }) {
  68     if ($p->{class} eq 'SL::DB::Order') {
  69       $p->{row_ident} = $self->_order_column;
  70     }
  71     if ($p->{class} eq 'SL::DB::OrderItem') {
  72       $p->{row_ident} = $self->_item_column;
  73     }
  74   }
  75
  76   foreach my $p (@{ $profile }) {
  77     my $prof = $p->{profile};
  78     if ($p->{row_ident} eq $self->_order_column) {
  79       # no need to handle
  80       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  81     }
  82     if ($p->{row_ident} eq $self->_item_column) {
  83       # no need to handle
  84       delete @{$prof}{qw(trans_id)};
  85     }
  86   }
  87
  88   return $profile;
  89 }
  90
  91
  92 sub setup_displayable_columns {
  93   my ($self) = @_;
  94
  95   $self->SUPER::setup_displayable_columns;
  96
  97   $self->add_displayable_columns($self->_order_column,
  98                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
  99                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 100                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 101                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 102                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 103                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 104                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 105                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 106                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 107                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 108                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 109                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 110                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 111                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 112                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 113                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 114                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 115                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 116                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 117                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 118                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 119                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 120                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 121                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 122                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 123                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 124                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 125                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 126                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 127                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 128                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 129                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 130                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 131                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 132                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 133                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 134                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 135                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 136                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 137                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 138                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 139                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 140                                 );
 141
 142   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 143
 144   $self->add_displayable_columns($self->_item_column,
 145                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 146                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 147                                  { name => 'description',     description => $::locale->text('Description')                },
 148                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 149                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 150                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 151                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 152                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 153                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 154                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 155                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 156                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 157                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 158                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 159                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 160                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 161                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 162                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 163                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 164                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 165                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 166                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 167                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 168                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 169                                 );
 170 }
 171
 172
 173 sub init_languages_by {
 174   my ($self) = @_;
 175
 176   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 177 }
 178
 179 sub init_parts_by {
 180   my ($self) = @_;
 181
 182   my $all_parts = SL::DB::Manager::Part->get_all;
 183   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 184 }
 185
 186 sub init_contacts_by {
 187   my ($self) = @_;
 188
 189   my $all_contacts = SL::DB::Manager::Contact->get_all;
 190
 191   my $cby;
 192   # by customer/vendor id  _and_  contact person id
 193   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 194   # by customer/vendor id  _and_  contact person name
 195   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 196
 197   return $cby;
 198 }
 199
 200 sub init_departments_by {
 201   my ($self) = @_;
 202
 203   my $all_departments = SL::DB::Manager::Department->get_all;
 204   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_departments } } ) } qw(id description) };
 205 }
 206
 207 sub init_projects_by {
 208   my ($self) = @_;
 209
 210   my $all_projects = SL::DB::Manager::Project->get_all;
 211   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_projects } } ) } qw(id projectnumber description) };
 212 }
 213
 214 sub init_ct_shiptos_by {
 215   my ($self) = @_;
 216
 217   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 218
 219   my $sby;
 220   # by trans_id  _and_  shipto_id
 221   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 222
 223   return $sby;
 224 }
 225
 226 sub init_taxzones_by {
 227   my ($self) = @_;
 228
 229   my $all_taxzones = SL::DB::Manager::TaxZone->get_all;
 230   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_taxzones } } ) } qw(id description) };
 231 }
 232
 233 sub init_price_factors_by {
 234   my ($self) = @_;
 235
 236   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 237   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 238 }
 239
 240 sub init_pricegroups_by {
 241   my ($self) = @_;
 242
 243   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 244   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 245 }
 246
 247 sub check_objects {
 248   my ($self) = @_;
 249
 250   $self->controller->track_progress(phase => 'building data', progress => 0);
 251
 252   my $i = 0;
 253   my $num_data = scalar @{ $self->controller->data };
 254   foreach my $entry (@{ $self->controller->data }) {
 255     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 256
 257     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 258       $self->handle_order($entry);
 259     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 260       $self->handle_item($entry);
 261     }
 262     $self->handle_cvars($entry, sub_module => 'orderitems');
 263
 264   } continue {
 265     $i++;
 266   }
 267
 268   $self->add_info_columns($self->_order_column,
 269                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 270   # Todo: access via ->[0] ok? Better: search first order column and use this
 271   $self->add_columns($self->_order_column,
 272                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment language department globalproject taxzone cp currency));
 273   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 274   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 275
 276   $self->add_info_columns($self->_item_column,
 277                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 278   # Todo: access via ->[1] ok? Better: search first item column and use this
 279   $self->add_columns($self->_item_column,
 280                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 281   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 282
 283   $self->add_cvar_raw_data_columns();
 284
 285   $self->add_items_to_order();
 286   $self->handle_prices_and_taxes();
 287
 288
 289   # If order has errors set error for orderitems as well
 290   my $order_entry;
 291   foreach my $entry (@{ $self->controller->data }) {
 292     # Search first order
 293     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 294       $order_entry = $entry;
 295     } elsif ( defined $order_entry
 296               && $entry->{raw_data}->{datatype} eq $self->_item_column
 297               && scalar @{ $order_entry->{errors} } > 0 ) {
 298       push @{ $entry->{errors} }, $::locale->text('Error: Invalid order for this order item');
 299     }
 300   }
 301
 302 }
 303
 304 sub handle_order {
 305   my ($self, $entry) = @_;
 306
 307   my $object = $entry->{object};
 308
 309   my $vc_obj;
 310   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 311     $self->check_vc($entry, 'customer_id');
 312     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 313   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 314     $self->check_vc($entry, 'vendor_id');
 315     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 316   } else {
 317     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 318   }
 319
 320   $self->check_contact($entry);
 321   $self->check_language($entry);
 322   $self->check_payment($entry);
 323   $self->check_department($entry);
 324   $self->check_project($entry, global => 1);
 325   $self->check_ct_shipto($entry);
 326   $self->check_taxzone($entry);
 327   SL::Helper::Csv::Consistency->check_currency($entry, take_default => 0);
 328
 329   if ($vc_obj) {
 330     # copy from customer if not given
 331     foreach (qw(payment_id language_id taxzone_id currency_id)) {
 332       $object->$_($vc_obj->$_) unless $object->$_;
 333     }
 334   }
 335
 336   $self->handle_salesman($entry);
 337   $self->handle_employee($entry);
 338 }
 339
 340 # ToDo: salesman by name
 341 sub handle_salesman {
 342   my ($self, $entry) = @_;
 343
 344   my $object = $entry->{object};
 345   my $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 346   $vc_obj    = SL::DB::Vendor->new(id   => $object->vendor_id)->load   if (!$vc_obj && $object->vendor_id);
 347
 348   # salesman from customer/vendor or login if not given
 349   if (!$object->salesman) {
 350     if ($vc_obj && $vc_obj->salesman_id) {
 351       $object->salesman(SL::DB::Manager::Employee->find_by(id => $vc_obj->salesman_id));
 352     } else {
 353       $object->salesman(SL::DB::Manager::Employee->find_by(login => $::myconfig{login}));
 354     }
 355   }
 356 }
 357
 358 # ToDo: employee by name
 359 sub handle_employee {
 360   my ($self, $entry) = @_;
 361
 362   my $object = $entry->{object};
 363
 364   # employee from login if not given
 365   if (!$object->employee_id) {
 366     $object->employee_id(SL::DB::Manager::Employee->find_by(login => $::myconfig{login})->id);
 367   }
 368 }
 369
 370 sub check_language {
 371   my ($self, $entry) = @_;
 372
 373   my $object = $entry->{object};
 374
 375   # Check whether or not language ID is valid.
 376   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 377     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 378     return 0;
 379   }
 380
 381   # Map name to ID if given.
 382   if (!$object->language_id && $entry->{raw_data}->{language}) {
 383     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 384                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 385
 386     if (!$language) {
 387       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 388       return 0;
 389     }
 390
 391     $object->language_id($language->id);
 392   }
 393
 394   if ($object->language_id) {
 395     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 396   }
 397
 398   return 1;
 399 }
 400
 401 sub handle_item {
 402   my ($self, $entry) = @_;
 403
 404   my $object = $entry->{object};
 405   return unless $self->check_part($entry);
 406
 407   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 408
 409   # copy from part if not given
 410   $object->description($part_obj->description) unless $object->description;
 411   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 412   $object->unit($part_obj->unit)               unless $object->unit;
 413   $object->sellprice($part_obj->sellprice)     unless defined $object->sellprice;
 414   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 415
 416   # set to 0 if not given
 417   $object->discount(0) unless $object->discount;
 418   $object->ship(0)     unless $object->ship;
 419
 420   $self->check_project($entry, global => 0);
 421   $self->check_price_factor($entry);
 422   $self->check_pricegroup($entry);
 423 }
 424
 425 sub check_part {
 426   my ($self, $entry) = @_;
 427
 428   my $object = $entry->{object};
 429
 430   # Check wether or non part ID is valid.
 431   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 432     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 433     return 0;
 434   }
 435
 436   # Map number to ID if given.
 437   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 438     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 439     if (!$part) {
 440       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 441       return 0;
 442     }
 443
 444     $object->parts_id($part->id);
 445   }
 446
 447   if ($object->parts_id) {
 448     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 449   } else {
 450     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 451     return 0;
 452   }
 453
 454   return 1;
 455 }
 456
 457 sub check_contact {
 458   my ($self, $entry) = @_;
 459
 460   my $object = $entry->{object};
 461
 462   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 463   return 0 unless $cp_cv_id;
 464
 465   # Check wether or not contact ID is valid.
 466   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 467     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 468     return 0;
 469   }
 470
 471   # Map name to ID if given.
 472   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 473     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 474     if (!$cp) {
 475       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 476       return 0;
 477     }
 478
 479     $object->cp_id($cp->cp_id);
 480   }
 481
 482   if ($object->cp_id) {
 483     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 484   }
 485
 486   return 1;
 487 }
 488
 489 sub check_department {
 490   my ($self, $entry) = @_;
 491
 492   my $object = $entry->{object};
 493
 494   # Check wether or not department ID is valid.
 495   if ($object->department_id && !$self->departments_by->{id}->{ $object->department_id }) {
 496     push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 497     return 0;
 498   }
 499
 500   # Map description to ID if given.
 501   if (!$object->department_id && $entry->{raw_data}->{department}) {
 502     my $dep = $self->departments_by->{description}->{ $entry->{raw_data}->{department} };
 503     if (!$dep) {
 504       push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 505       return 0;
 506     }
 507
 508     $object->department_id($dep->id);
 509   }
 510
 511   return 1;
 512 }
 513
 514 sub check_project {
 515   my ($self, $entry, %params) = @_;
 516
 517   my $id_column          = ($params{global} ? 'global' : '') . 'project_id';
 518   my $number_column      = ($params{global} ? 'global' : '') . 'projectnumber';
 519   my $description_column = ($params{global} ? 'global' : '') . 'project';
 520
 521   my $object = $entry->{object};
 522
 523   # Check wether or not projetc ID is valid.
 524   if ($object->$id_column && !$self->projects_by->{id}->{ $object->$id_column }) {
 525     push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 526     return 0;
 527   }
 528
 529   # Map number to ID if given.
 530   if (!$object->$id_column && $entry->{raw_data}->{$number_column}) {
 531     my $proj = $self->projects_by->{projectnumber}->{ $entry->{raw_data}->{$number_column} };
 532     if (!$proj) {
 533       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 534       return 0;
 535     }
 536
 537     $object->$id_column($proj->id);
 538   }
 539
 540   # Map description to ID if given.
 541   if (!$object->$id_column && $entry->{raw_data}->{$description_column}) {
 542     my $proj = $self->projects_by->{description}->{ $entry->{raw_data}->{$description_column} };
 543     if (!$proj) {
 544       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 545       return 0;
 546     }
 547
 548     $object->$id_column($proj->id);
 549   }
 550
 551   return 1;
 552 }
 553
 554 sub check_ct_shipto {
 555   my ($self, $entry) = @_;
 556
 557   my $object = $entry->{object};
 558
 559   my $trans_id = $object->customer_id || $object->vendor_id;
 560   return 0 unless $trans_id;
 561
 562   # Check wether or not shipto ID is valid.
 563   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 564     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 565     return 0;
 566   }
 567
 568   return 1;
 569 }
 570
 571 sub check_taxzone {
 572   my ($self, $entry) = @_;
 573
 574   my $object = $entry->{object};
 575
 576   # Check wether or not taxzone ID is valid.
 577   if ($object->taxzone_id && !$self->taxzones_by->{id}->{ $object->taxzone_id }) {
 578     push @{ $entry->{errors} }, $::locale->text('Error: Invalid tax zone');
 579     return 0;
 580   }
 581
 582   # Map description to ID if given.
 583   if (!$object->taxzone_id && $entry->{raw_data}->{taxzone}) {
 584     my $taxzone = $self->taxzones_by->{description}->{ $entry->{raw_data}->{taxzone} };
 585     if (!$taxzone) {
 586       push @{ $entry->{errors} }, $::locale->text('Error: Invalid tax zone');
 587       return 0;
 588     }
 589
 590     $object->taxzone_id($taxzone->id);
 591   }
 592
 593   return 1;
 594 }
 595
 596 sub check_price_factor {
 597   my ($self, $entry) = @_;
 598
 599   my $object = $entry->{object};
 600
 601   # Check wether or not price_factor ID is valid.
 602   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 603     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 604     return 0;
 605   }
 606
 607   # Map description to ID if given.
 608   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 609     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 610     if (!$price_factor) {
 611       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 612       return 0;
 613     }
 614
 615     $object->price_factor_id($price_factor->id);
 616   }
 617
 618   return 1;
 619 }
 620
 621 sub check_pricegroup {
 622   my ($self, $entry) = @_;
 623
 624   my $object = $entry->{object};
 625
 626   # Check wether or not pricegroup ID is valid.
 627   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 628     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 629     return 0;
 630   }
 631
 632   # Map pricegroup to ID if given.
 633   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 634     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 635     if (!$pricegroup) {
 636       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 637       return 0;
 638     }
 639
 640     $object->pricegroup_id($pricegroup->id);
 641   }
 642
 643   return 1;
 644 }
 645
 646 sub add_items_to_order {
 647   my ($self) = @_;
 648
 649   # add orderitems to order
 650   my $order_entry;
 651   my @orderitems;
 652   foreach my $entry (@{ $self->controller->data }) {
 653     # search first order
 654     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 655
 656       # new order entry: add collected orderitems to the previous one
 657       if (defined $order_entry) {
 658         $order_entry->{object}->orderitems(@orderitems);
 659         @orderitems = ();
 660       }
 661
 662       $order_entry = $entry;
 663
 664     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 665       # collect orderitems to add to order (if they have no errors)
 666       # ( add_orderitems does not work here if we want to call
 667       #   calculate_prices_and_taxes afterwards ...
 668       #   so collect orderitems and add them at once )
 669       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 670     }
 671   }
 672   # add last collected orderitems to last order
 673   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 674 }
 675
 676 sub handle_prices_and_taxes() {
 677   my ($self) = @_;
 678
 679   # calculate prices and taxes
 680   foreach my $entry (@{ $self->controller->data }) {
 681     next if @{ $entry->{errors} };
 682
 683     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 684
 685       $entry->{object}->calculate_prices_and_taxes;
 686
 687       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 688       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 689     }
 690   }
 691
 692   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 693   # And throw an error if the differences are too big.
 694   my @to_verify = ( { column      => 'amount',
 695                       raw_column  => 'verify_amount',
 696                       info_header => 'Calc. Amount',
 697                       info_method => 'calc_amount',
 698                       err_msg     => 'Amounts differ too much',
 699                     },
 700                     { column      => 'netamount',
 701                       raw_column  => 'verify_netamount',
 702                       info_header => 'Calc. Net amount',
 703                       info_method => 'calc_netamount',
 704                       err_msg     => 'Net amounts differ too much',
 705                     } );
 706
 707   foreach my $tv (@to_verify) {
 708     # Todo: access via ->[0] ok? Better: search first order column and use this
 709     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 710       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 711       $self->add_info_columns($self->_order_column,
 712                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 713     }
 714
 715     # check differences
 716     foreach my $entry (@{ $self->controller->data }) {
 717       next if @{ $entry->{errors} };
 718       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 719         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 720         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 721         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 722           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 723         }
 724       }
 725     }
 726   }
 727
 728 }
 729
 730 sub save_objects {
 731   my ($self, %params) = @_;
 732
 733   # set order number and collect to save
 734   my $objects_to_save;
 735   foreach my $entry (@{ $self->controller->data }) {
 736     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 737     next if @{ $entry->{errors} };
 738
 739     if (!$entry->{object}->ordnumber) {
 740       my $number = SL::TransNumber->new(type => 'sales_order',
 741                                         save => 1);
 742       $entry->{object}->ordnumber($number->create_unique());
 743     }
 744
 745     push @{ $objects_to_save }, $entry;
 746   }
 747
 748   $self->SUPER::save_objects(data => $objects_to_save);
 749 }
 750
 751 sub _order_column {
 752   $_[0]->settings->{'order_column'}
 753 }
 754
 755 sub _item_column {
 756   $_[0]->settings->{'item_column'}
 757 }
 758
 759 1;