SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::TransNumber;
  22
  23 use parent qw(SL::Controller::CsvImport::BaseMulti);
  24
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by departments_by projects_by ct_shiptos_by taxzones_by price_factors_by pricegroups_by) ],
  29 );
  30
  31
  32 sub init_class {
  33   my ($self) = @_;
  34   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  35 }
  36
  37
  38 sub init_settings {
  39   my ($self) = @_;
  40
  41   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  42 }
  43
  44
  45 sub init_cvar_configs_by {
  46   my ($self) = @_;
  47
  48   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  49   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  50
  51   my $ccb;
  52   $ccb->{class}->{'SL::DB::Order'}          = [];
  53   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  54   $ccb->{row_ident}->{$self->_order_column} = [];
  55   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  56
  57   return $ccb;
  58 }
  59
  60
  61 sub init_profile {
  62   my ($self) = @_;
  63
  64   my $profile = $self->SUPER::init_profile;
  65
  66   # SUPER::init_profile sets row_ident to the translated class name
  67   # overwrite it with the user specified settings
  68   foreach my $p (@{ $profile }) {
  69     if ($p->{class} eq 'SL::DB::Order') {
  70       $p->{row_ident} = $self->_order_column;
  71     }
  72     if ($p->{class} eq 'SL::DB::OrderItem') {
  73       $p->{row_ident} = $self->_item_column;
  74     }
  75   }
  76
  77   foreach my $p (@{ $profile }) {
  78     my $prof = $p->{profile};
  79     if ($p->{row_ident} eq $self->_order_column) {
  80       # no need to handle
  81       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  82     }
  83     if ($p->{row_ident} eq $self->_item_column) {
  84       # no need to handle
  85       delete @{$prof}{qw(trans_id)};
  86     }
  87   }
  88
  89   return $profile;
  90 }
  91
  92
  93 sub setup_displayable_columns {
  94   my ($self) = @_;
  95
  96   $self->SUPER::setup_displayable_columns;
  97
  98   $self->add_displayable_columns($self->_order_column,
  99                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 100                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 101                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 102                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 103                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 104                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 105                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 106                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 107                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 108                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 109                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 110                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 111                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 112                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 113                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 114                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 115                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 116                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 117                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 118                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 119                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 120                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 121                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 122                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 123                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 124                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 125                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 126                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 127                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 128                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 129                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 130                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 131                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 132                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 133                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 134                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 135                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 136                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 137                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 138                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 139                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 140                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 141                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 142                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 143                                 );
 144
 145   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 146
 147   $self->add_displayable_columns($self->_item_column,
 148                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 149                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 150                                  { name => 'description',     description => $::locale->text('Description')                },
 151                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 152                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 153                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 154                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 155                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 156                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 157                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 158                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 159                                  { name => 'position',        description => $::locale->text('position')                   },
 160                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 161                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 162                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 163                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 164                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 165                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 166                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 167                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 168                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 169                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 170                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 171                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 172                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 173                                 );
 174 }
 175
 176
 177 sub init_languages_by {
 178   my ($self) = @_;
 179
 180   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 181 }
 182
 183 sub init_parts_by {
 184   my ($self) = @_;
 185
 186   my $all_parts = SL::DB::Manager::Part->get_all;
 187   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 188 }
 189
 190 sub init_contacts_by {
 191   my ($self) = @_;
 192
 193   my $all_contacts = SL::DB::Manager::Contact->get_all;
 194
 195   my $cby;
 196   # by customer/vendor id  _and_  contact person id
 197   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 198   # by customer/vendor id  _and_  contact person name
 199   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 200
 201   return $cby;
 202 }
 203
 204 sub init_departments_by {
 205   my ($self) = @_;
 206
 207   my $all_departments = SL::DB::Manager::Department->get_all;
 208   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_departments } } ) } qw(id description) };
 209 }
 210
 211 sub init_projects_by {
 212   my ($self) = @_;
 213
 214   my $all_projects = SL::DB::Manager::Project->get_all;
 215   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_projects } } ) } qw(id projectnumber description) };
 216 }
 217
 218 sub init_ct_shiptos_by {
 219   my ($self) = @_;
 220
 221   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 222
 223   my $sby;
 224   # by trans_id  _and_  shipto_id
 225   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 226
 227   return $sby;
 228 }
 229
 230 sub init_taxzones_by {
 231   my ($self) = @_;
 232
 233   my $all_taxzones = SL::DB::Manager::TaxZone->get_all;
 234   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_taxzones } } ) } qw(id description) };
 235 }
 236
 237 sub init_price_factors_by {
 238   my ($self) = @_;
 239
 240   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 241   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 242 }
 243
 244 sub init_pricegroups_by {
 245   my ($self) = @_;
 246
 247   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 248   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 249 }
 250
 251 sub check_objects {
 252   my ($self) = @_;
 253
 254   $self->controller->track_progress(phase => 'building data', progress => 0);
 255
 256   my $i = 0;
 257   my $num_data = scalar @{ $self->controller->data };
 258   foreach my $entry (@{ $self->controller->data }) {
 259     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 260
 261     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 262       $self->handle_order($entry);
 263     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 264       $self->handle_item($entry);
 265     }
 266     $self->handle_cvars($entry, sub_module => 'orderitems');
 267
 268   } continue {
 269     $i++;
 270   }
 271
 272   $self->add_info_columns($self->_order_column,
 273                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 274   # Todo: access via ->[0] ok? Better: search first order column and use this
 275   $self->add_columns($self->_order_column,
 276                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 277   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 278   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 279
 280   $self->add_info_columns($self->_item_column,
 281                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 282   # Todo: access via ->[1] ok? Better: search first item column and use this
 283   $self->add_columns($self->_item_column,
 284                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 285   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 286
 287   $self->add_cvar_raw_data_columns();
 288
 289   $self->add_items_to_order();
 290   $self->handle_prices_and_taxes();
 291
 292
 293   # If order has errors set error for orderitems as well
 294   my $order_entry;
 295   foreach my $entry (@{ $self->controller->data }) {
 296     # Search first order
 297     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 298       $order_entry = $entry;
 299     } elsif ( defined $order_entry
 300               && $entry->{raw_data}->{datatype} eq $self->_item_column
 301               && scalar @{ $order_entry->{errors} } > 0 ) {
 302       push @{ $entry->{errors} }, $::locale->text('Error: Invalid order for this order item');
 303     }
 304   }
 305
 306 }
 307
 308 sub handle_order {
 309   my ($self, $entry) = @_;
 310
 311   my $object = $entry->{object};
 312
 313   my $vc_obj;
 314   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 315     $self->check_vc($entry, 'customer_id');
 316     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 317   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 318     $self->check_vc($entry, 'vendor_id');
 319     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 320   } else {
 321     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 322   }
 323
 324   $self->check_contact($entry);
 325   $self->check_language($entry);
 326   $self->check_payment($entry);
 327   $self->check_delivery_term($entry);
 328   $self->check_department($entry);
 329   $self->check_project($entry, global => 1);
 330   $self->check_ct_shipto($entry);
 331   $self->check_taxzone($entry);
 332   $self->check_currency($entry, take_default => 0);
 333
 334   if ($vc_obj) {
 335     # copy from customer if not given
 336     foreach (qw(payment_id language_id taxzone_id currency_id)) {
 337       $object->$_($vc_obj->$_) unless $object->$_;
 338     }
 339   }
 340
 341   $self->handle_salesman($entry);
 342   $self->handle_employee($entry);
 343 }
 344
 345 # ToDo: salesman by name
 346 sub handle_salesman {
 347   my ($self, $entry) = @_;
 348
 349   my $object = $entry->{object};
 350   my $vc_obj;
 351   $vc_obj    = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 352   $vc_obj    = SL::DB::Vendor->new(id   => $object->vendor_id)->load   if (!$vc_obj && $object->vendor_id);
 353
 354   # salesman from customer/vendor or login if not given
 355   if (!$object->salesman) {
 356     if ($vc_obj && $vc_obj->salesman_id) {
 357       $object->salesman(SL::DB::Manager::Employee->find_by(id => $vc_obj->salesman_id));
 358     } else {
 359       $object->salesman(SL::DB::Manager::Employee->find_by(login => $::myconfig{login}));
 360     }
 361   }
 362 }
 363
 364 # ToDo: employee by name
 365 sub handle_employee {
 366   my ($self, $entry) = @_;
 367
 368   my $object = $entry->{object};
 369
 370   # employee from login if not given
 371   if (!$object->employee_id) {
 372     $object->employee_id(SL::DB::Manager::Employee->find_by(login => $::myconfig{login})->id);
 373   }
 374 }
 375
 376 sub check_language {
 377   my ($self, $entry) = @_;
 378
 379   my $object = $entry->{object};
 380
 381   # Check whether or not language ID is valid.
 382   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 383     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 384     return 0;
 385   }
 386
 387   # Map name to ID if given.
 388   if (!$object->language_id && $entry->{raw_data}->{language}) {
 389     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 390                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 391
 392     if (!$language) {
 393       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 394       return 0;
 395     }
 396
 397     $object->language_id($language->id);
 398   }
 399
 400   if ($object->language_id) {
 401     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 402   }
 403
 404   return 1;
 405 }
 406
 407 sub handle_item {
 408   my ($self, $entry) = @_;
 409
 410   my $object = $entry->{object};
 411   return unless $self->check_part($entry);
 412
 413   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 414
 415   # copy from part if not given
 416   $object->description($part_obj->description) unless $object->description;
 417   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 418   $object->unit($part_obj->unit)               unless $object->unit;
 419   $object->sellprice($part_obj->sellprice)     unless defined $object->sellprice;
 420   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 421
 422   # set to 0 if not given
 423   $object->discount(0) unless $object->discount;
 424   $object->ship(0)     unless $object->ship;
 425
 426   $self->check_project($entry, global => 0);
 427   $self->check_price_factor($entry);
 428   $self->check_pricegroup($entry);
 429 }
 430
 431 sub check_part {
 432   my ($self, $entry) = @_;
 433
 434   my $object = $entry->{object};
 435
 436   # Check wether or non part ID is valid.
 437   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 438     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 439     return 0;
 440   }
 441
 442   # Map number to ID if given.
 443   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 444     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 445     if (!$part) {
 446       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 447       return 0;
 448     }
 449
 450     $object->parts_id($part->id);
 451   }
 452
 453   if ($object->parts_id) {
 454     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 455   } else {
 456     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 457     return 0;
 458   }
 459
 460   return 1;
 461 }
 462
 463 sub check_contact {
 464   my ($self, $entry) = @_;
 465
 466   my $object = $entry->{object};
 467
 468   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 469   return 0 unless $cp_cv_id;
 470
 471   # Check wether or not contact ID is valid.
 472   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 473     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 474     return 0;
 475   }
 476
 477   # Map name to ID if given.
 478   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 479     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 480     if (!$cp) {
 481       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 482       return 0;
 483     }
 484
 485     $object->cp_id($cp->cp_id);
 486   }
 487
 488   if ($object->cp_id) {
 489     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 490   }
 491
 492   return 1;
 493 }
 494
 495 sub check_department {
 496   my ($self, $entry) = @_;
 497
 498   my $object = $entry->{object};
 499
 500   # Check wether or not department ID is valid.
 501   if ($object->department_id && !$self->departments_by->{id}->{ $object->department_id }) {
 502     push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 503     return 0;
 504   }
 505
 506   # Map description to ID if given.
 507   if (!$object->department_id && $entry->{raw_data}->{department}) {
 508     my $dep = $self->departments_by->{description}->{ $entry->{raw_data}->{department} };
 509     if (!$dep) {
 510       push @{ $entry->{errors} }, $::locale->text('Error: Invalid department');
 511       return 0;
 512     }
 513
 514     $object->department_id($dep->id);
 515   }
 516
 517   return 1;
 518 }
 519
 520 sub check_project {
 521   my ($self, $entry, %params) = @_;
 522
 523   my $id_column          = ($params{global} ? 'global' : '') . 'project_id';
 524   my $number_column      = ($params{global} ? 'global' : '') . 'projectnumber';
 525   my $description_column = ($params{global} ? 'global' : '') . 'project';
 526
 527   my $object = $entry->{object};
 528
 529   # Check wether or not projetc ID is valid.
 530   if ($object->$id_column && !$self->projects_by->{id}->{ $object->$id_column }) {
 531     push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 532     return 0;
 533   }
 534
 535   # Map number to ID if given.
 536   if (!$object->$id_column && $entry->{raw_data}->{$number_column}) {
 537     my $proj = $self->projects_by->{projectnumber}->{ $entry->{raw_data}->{$number_column} };
 538     if (!$proj) {
 539       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 540       return 0;
 541     }
 542
 543     $object->$id_column($proj->id);
 544   }
 545
 546   # Map description to ID if given.
 547   if (!$object->$id_column && $entry->{raw_data}->{$description_column}) {
 548     my $proj = $self->projects_by->{description}->{ $entry->{raw_data}->{$description_column} };
 549     if (!$proj) {
 550       push @{ $entry->{errors} }, $::locale->text('Error: Invalid project');
 551       return 0;
 552     }
 553
 554     $object->$id_column($proj->id);
 555   }
 556
 557   return 1;
 558 }
 559
 560 sub check_ct_shipto {
 561   my ($self, $entry) = @_;
 562
 563   my $object = $entry->{object};
 564
 565   my $trans_id = $object->customer_id || $object->vendor_id;
 566   return 0 unless $trans_id;
 567
 568   # Check wether or not shipto ID is valid.
 569   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 570     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 571     return 0;
 572   }
 573
 574   return 1;
 575 }
 576
 577 sub check_taxzone {
 578   my ($self, $entry) = @_;
 579
 580   my $object = $entry->{object};
 581
 582   # Check wether or not taxzone ID is valid.
 583   if ($object->taxzone_id && !$self->taxzones_by->{id}->{ $object->taxzone_id }) {
 584     push @{ $entry->{errors} }, $::locale->text('Error: Invalid tax zone');
 585     return 0;
 586   }
 587
 588   # Map description to ID if given.
 589   if (!$object->taxzone_id && $entry->{raw_data}->{taxzone}) {
 590     my $taxzone = $self->taxzones_by->{description}->{ $entry->{raw_data}->{taxzone} };
 591     if (!$taxzone) {
 592       push @{ $entry->{errors} }, $::locale->text('Error: Invalid tax zone');
 593       return 0;
 594     }
 595
 596     $object->taxzone_id($taxzone->id);
 597   }
 598
 599   return 1;
 600 }
 601
 602 sub check_price_factor {
 603   my ($self, $entry) = @_;
 604
 605   my $object = $entry->{object};
 606
 607   # Check wether or not price_factor ID is valid.
 608   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 609     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 610     return 0;
 611   }
 612
 613   # Map description to ID if given.
 614   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 615     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 616     if (!$price_factor) {
 617       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 618       return 0;
 619     }
 620
 621     $object->price_factor_id($price_factor->id);
 622   }
 623
 624   return 1;
 625 }
 626
 627 sub check_pricegroup {
 628   my ($self, $entry) = @_;
 629
 630   my $object = $entry->{object};
 631
 632   # Check wether or not pricegroup ID is valid.
 633   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 634     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 635     return 0;
 636   }
 637
 638   # Map pricegroup to ID if given.
 639   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 640     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 641     if (!$pricegroup) {
 642       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 643       return 0;
 644     }
 645
 646     $object->pricegroup_id($pricegroup->id);
 647   }
 648
 649   return 1;
 650 }
 651
 652 sub add_items_to_order {
 653   my ($self) = @_;
 654
 655   # add orderitems to order
 656   my $order_entry;
 657   my @orderitems;
 658   foreach my $entry (@{ $self->controller->data }) {
 659     # search first order
 660     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 661
 662       # new order entry: add collected orderitems to the previous one
 663       if (defined $order_entry) {
 664         $order_entry->{object}->orderitems(@orderitems);
 665         @orderitems = ();
 666       }
 667
 668       $order_entry = $entry;
 669
 670     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 671       # collect orderitems to add to order (if they have no errors)
 672       # ( add_orderitems does not work here if we want to call
 673       #   calculate_prices_and_taxes afterwards ...
 674       #   so collect orderitems and add them at once )
 675       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 676     }
 677   }
 678   # add last collected orderitems to last order
 679   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 680 }
 681
 682 sub handle_prices_and_taxes() {
 683   my ($self) = @_;
 684
 685   # calculate prices and taxes
 686   foreach my $entry (@{ $self->controller->data }) {
 687     next if @{ $entry->{errors} };
 688
 689     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 690
 691       $entry->{object}->calculate_prices_and_taxes;
 692
 693       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 694       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 695     }
 696   }
 697
 698   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 699   # And throw an error if the differences are too big.
 700   my @to_verify = ( { column      => 'amount',
 701                       raw_column  => 'verify_amount',
 702                       info_header => 'Calc. Amount',
 703                       info_method => 'calc_amount',
 704                       err_msg     => 'Amounts differ too much',
 705                     },
 706                     { column      => 'netamount',
 707                       raw_column  => 'verify_netamount',
 708                       info_header => 'Calc. Net amount',
 709                       info_method => 'calc_netamount',
 710                       err_msg     => 'Net amounts differ too much',
 711                     } );
 712
 713   foreach my $tv (@to_verify) {
 714     # Todo: access via ->[0] ok? Better: search first order column and use this
 715     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 716       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 717       $self->add_info_columns($self->_order_column,
 718                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 719     }
 720
 721     # check differences
 722     foreach my $entry (@{ $self->controller->data }) {
 723       next if @{ $entry->{errors} };
 724       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 725         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 726         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 727         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 728           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 729         }
 730       }
 731     }
 732   }
 733
 734 }
 735
 736 sub save_objects {
 737   my ($self, %params) = @_;
 738
 739   # set order number and collect to save
 740   my $objects_to_save;
 741   foreach my $entry (@{ $self->controller->data }) {
 742     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 743     next if @{ $entry->{errors} };
 744
 745     if (!$entry->{object}->ordnumber) {
 746       my $number = SL::TransNumber->new(type => 'sales_order',
 747                                         save => 1);
 748       $entry->{object}->ordnumber($number->create_unique());
 749     }
 750
 751     push @{ $objects_to_save }, $entry;
 752   }
 753
 754   $self->SUPER::save_objects(data => $objects_to_save);
 755 }
 756
 757 sub _order_column {
 758   $_[0]->settings->{'order_column'}
 759 }
 760
 761 sub _item_column {
 762   $_[0]->settings->{'item_column'}
 763 }
 764
 765 1;