SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::PriceSource;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_gln',            description => $::locale->text('Customer GLN')                          },
 137                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 138                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 139                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 140                                  { name => 'vendor_gln',              description => $::locale->text('Vendor GLN')                            },
 141                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 142                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 143                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 144                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 145                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 146                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 147                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 148                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 149                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 150                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 151                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 152                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 153                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 154                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 155                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 156                                 );
 157
 158   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 159
 160   $self->add_displayable_columns($self->_item_column,
 161                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 162                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 163                                  { name => 'description',     description => $::locale->text('Description')                },
 164                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 165                                  { name => 'ean',             description => $::locale->text('EAN')                        },
 166                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 167                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 168                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 169                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 170                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 171                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 172                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 173                                  { name => 'position',        description => $::locale->text('position')                   },
 174                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 175                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 176                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 177                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 178                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 179                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 180                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 181                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 182                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 183                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 184                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 185                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 186                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 187                                 );
 188 }
 189
 190
 191 sub init_languages_by {
 192   my ($self) = @_;
 193
 194   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 195 }
 196
 197 sub init_all_parts {
 198   my ($self) = @_;
 199
 200   return SL::DB::Manager::Part->get_all;
 201 }
 202
 203 sub init_parts_by {
 204   my ($self) = @_;
 205
 206   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 207 }
 208
 209 sub init_part_counts_by {
 210   my ($self) = @_;
 211
 212   my $part_counts_by;
 213
 214   $part_counts_by->{ean}->        {$_->ean}++         for @{ $self->all_parts };
 215   $part_counts_by->{description}->{$_->description}++ for @{ $self->all_parts };
 216
 217   return $part_counts_by;
 218 }
 219
 220 sub init_contacts_by {
 221   my ($self) = @_;
 222
 223   my $all_contacts = SL::DB::Manager::Contact->get_all;
 224
 225   my $cby;
 226   # by customer/vendor id  _and_  contact person id
 227   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 228   # by customer/vendor id  _and_  contact person name
 229   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 230
 231   return $cby;
 232 }
 233
 234 sub init_ct_shiptos_by {
 235   my ($self) = @_;
 236
 237   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 238
 239   my $sby;
 240   # by trans_id  _and_  shipto_id
 241   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 242
 243   return $sby;
 244 }
 245
 246 sub init_price_factors_by {
 247   my ($self) = @_;
 248
 249   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 250   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 251 }
 252
 253 sub init_pricegroups_by {
 254   my ($self) = @_;
 255
 256   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 257   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 258 }
 259
 260 sub init_units_by {
 261   my ($self) = @_;
 262
 263   my $all_units = SL::DB::Manager::Unit->get_all;
 264   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 265 }
 266
 267 sub check_objects {
 268   my ($self) = @_;
 269
 270   $self->controller->track_progress(phase => 'building data', progress => 0);
 271
 272   my $i = 0;
 273   my $num_data = scalar @{ $self->controller->data };
 274   my $order_entry;
 275   foreach my $entry (@{ $self->controller->data }) {
 276     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 277
 278     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 279
 280     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 281       $self->handle_order($entry);
 282       $order_entry = $entry;
 283     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 284       $self->handle_item($entry, $order_entry);
 285     } else {
 286       $order_entry = undef;
 287     }
 288
 289     $self->handle_cvars($entry, sub_module => 'orderitems');
 290
 291   } continue {
 292     $i++;
 293   }
 294
 295   $self->add_info_columns($self->_order_column,
 296                           { header => $::locale->text('Data type'), method => 'datatype' });
 297   $self->add_info_columns($self->_item_column,
 298                           { header => $::locale->text('Data type'), method => 'datatype' });
 299
 300   $self->add_info_columns($self->_order_column,
 301                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 302   # Todo: access via ->[0] ok? Better: search first order column and use this
 303   $self->add_columns($self->_order_column,
 304                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 305   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 306   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 307
 308   $self->add_info_columns($self->_item_column,
 309                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 310   # Todo: access via ->[1] ok? Better: search first item column and use this
 311   $self->add_columns($self->_item_column,
 312                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 313   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 314
 315   $self->add_cvar_raw_data_columns();
 316
 317   $self->add_items_to_order();
 318   $self->handle_prices_and_taxes();
 319 }
 320
 321 sub handle_order {
 322   my ($self, $entry) = @_;
 323
 324   my $object = $entry->{object};
 325
 326   my $vc_obj;
 327   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_gln customer_id)) {
 328     $self->check_vc($entry, 'customer_id');
 329     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 330   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_gln vendor_id)) {
 331     $self->check_vc($entry, 'vendor_id');
 332     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 333   } else {
 334     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 335   }
 336
 337   $self->check_contact($entry);
 338   $self->check_language($entry);
 339   $self->check_payment($entry);
 340   $self->check_delivery_term($entry);
 341   $self->check_department($entry);
 342   $self->check_project($entry, global => 1);
 343   $self->check_ct_shipto($entry);
 344   $self->check_taxzone($entry);
 345   $self->check_currency($entry, take_default => 0);
 346
 347   if ($vc_obj) {
 348     # copy from customer if not given
 349     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 350       $object->$_($vc_obj->$_) unless $object->$_;
 351     }
 352     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 353   }
 354
 355   $self->handle_salesman($entry);
 356   $self->handle_employee($entry);
 357 }
 358
 359 sub check_language {
 360   my ($self, $entry) = @_;
 361
 362   my $object = $entry->{object};
 363
 364   # Check whether or not language ID is valid.
 365   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 366     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 367     return 0;
 368   }
 369
 370   # Map name to ID if given.
 371   if (!$object->language_id && $entry->{raw_data}->{language}) {
 372     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 373                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 374
 375     if (!$language) {
 376       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 377       return 0;
 378     }
 379
 380     $object->language_id($language->id);
 381   }
 382
 383   if ($object->language_id) {
 384     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 385   }
 386
 387   return 1;
 388 }
 389
 390 sub handle_item {
 391   my ($self, $entry, $order_entry) = @_;
 392
 393   return unless $order_entry;
 394
 395   my $object = $entry->{object};
 396
 397   return unless $self->check_part($entry);
 398
 399   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 400
 401   $self->handle_unit($entry);
 402
 403   # copy from part if not given
 404   $object->description($part_obj->description) unless $object->description;
 405   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 406   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 407
 408   # set to 0 if not given
 409   $object->ship(0)     unless $object->ship;
 410
 411   $self->check_project($entry, global => 0);
 412   $self->check_price_factor($entry);
 413   $self->check_pricegroup($entry);
 414
 415   $self->handle_sellprice($entry, $order_entry);
 416   $self->handle_discount($entry, $order_entry);
 417 }
 418
 419 sub handle_unit {
 420   my ($self, $entry) = @_;
 421
 422   my $object = $entry->{object};
 423
 424   # Set unit from part if not given.
 425   if (!$object->unit) {
 426     $object->unit($object->part->unit);
 427     return 1;
 428   }
 429
 430   # Check whether or not unit is valid.
 431   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 432     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 433     return 0;
 434   }
 435
 436   # Check whether unit is convertible to parts unit
 437   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 438     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 439     return 0;
 440   }
 441
 442   return 1;
 443 }
 444
 445 sub handle_sellprice {
 446   my ($self, $entry, $record_entry) = @_;
 447
 448   my $item   = $entry->{object};
 449   my $record = $record_entry->{object};
 450
 451   return if !$record->customervendor;
 452
 453   # If sellprice is given, set price source to pricegroup if given or to none.
 454   if (exists $entry->{raw_data}->{sellprice}) {
 455     my $price_source      = SL::PriceSource->new(record_item => $item, record => $record);
 456     my $price_source_spec = $item->pricegroup_id ? 'pricegroup' . '/' . $item->pricegroup_id : '';
 457     my $price             = $price_source->price_from_source($price_source_spec);
 458     $item->active_price_source($price->source);
 459
 460   } else {
 461     # Set sellprice the best price of price source
 462     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 463     my $price        = $price_source->best_price;
 464     if ($price) {
 465       $item->sellprice($price->price);
 466       $item->active_price_source($price->source);
 467     } else {
 468       $item->sellprice(0);
 469       $item->active_price_source($price_source->price_from_source('')->source);
 470     }
 471   }
 472 }
 473
 474 sub handle_discount {
 475   my ($self, $entry, $record_entry) = @_;
 476
 477   my $item   = $entry->{object};
 478   my $record = $record_entry->{object};
 479
 480   return if !$record->customervendor;
 481
 482   # If discount is given, set discount source to none.
 483   if (exists $entry->{raw_data}->{discount}) {
 484     $item->discount($item->discount/100.0)      if $item->discount;
 485     $item->discount(0)                      unless $item->discount;
 486
 487     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 488     my $discount     = $price_source->price_from_source('');
 489     $item->active_discount_source($discount->source);
 490
 491   } else {
 492     # Set discount the best discount of price source
 493     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 494     my $discount     = $price_source->best_discount;
 495     if ($discount) {
 496       $item->discount($discount->discount);
 497       $item->active_discount_source($discount->source);
 498     } else {
 499       $item->discount(0);
 500       $item->active_discount_source($price_source->discount_from_source('')->source);
 501     }
 502   }
 503 }
 504
 505 sub check_part {
 506   my ($self, $entry) = @_;
 507
 508   my $object = $entry->{object};
 509   my $is_ambiguous;
 510
 511   # Check whether or not part ID is valid.
 512   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 513     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 514     return 0;
 515   }
 516
 517   # Map number to ID if given.
 518   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 519     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 520     if (!$part) {
 521       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 522       return 0;
 523     }
 524
 525     $object->parts_id($part->id);
 526   }
 527
 528   # Map description to ID if given.
 529   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 530     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 531     if (!$part) {
 532       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 533       return 0;
 534     }
 535
 536     if ($self->part_counts_by->{description}->{ $entry->{raw_data}->{description} } > 1) {
 537       $is_ambiguous = 1;
 538     } else {
 539       $object->parts_id($part->id);
 540     }
 541   }
 542
 543   # Map ean to ID if given.
 544   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 545     my $part = $self->parts_by->{ean}->{ $entry->{raw_data}->{ean} };
 546     if (!$part) {
 547       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 548       return 0;
 549     }
 550
 551     if ($self->part_counts_by->{ean}->{ $entry->{raw_data}->{ean} } > 1) {
 552       $is_ambiguous = 1;
 553     } else {
 554       $object->parts_id($part->id);
 555     }
 556   }
 557
 558   if ($object->parts_id) {
 559     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 560   } else {
 561     if ($is_ambiguous) {
 562       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
 563     } else {
 564       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 565     }
 566     return 0;
 567   }
 568
 569   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 570     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 571     return 0;
 572   }
 573
 574   return 1;
 575 }
 576
 577 sub check_contact {
 578   my ($self, $entry) = @_;
 579
 580   my $object = $entry->{object};
 581
 582   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 583   return 0 unless $cp_cv_id;
 584
 585   # Check whether or not contact ID is valid.
 586   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 587     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 588     return 0;
 589   }
 590
 591   # Map name to ID if given.
 592   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 593     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 594     if (!$cp) {
 595       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 596       return 0;
 597     }
 598
 599     $object->cp_id($cp->cp_id);
 600   }
 601
 602   if ($object->cp_id) {
 603     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 604   }
 605
 606   return 1;
 607 }
 608
 609 sub check_ct_shipto {
 610   my ($self, $entry) = @_;
 611
 612   my $object = $entry->{object};
 613
 614   my $trans_id = $object->customer_id || $object->vendor_id;
 615   return 0 unless $trans_id;
 616
 617   # Check whether or not shipto ID is valid.
 618   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 619     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 620     return 0;
 621   }
 622
 623   return 1;
 624 }
 625
 626 sub check_price_factor {
 627   my ($self, $entry) = @_;
 628
 629   my $object = $entry->{object};
 630
 631   # Check whether or not price_factor ID is valid.
 632   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 633     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 634     return 0;
 635   }
 636
 637   # Map description to ID if given.
 638   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 639     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 640     if (!$price_factor) {
 641       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 642       return 0;
 643     }
 644
 645     $object->price_factor_id($price_factor->id);
 646   }
 647
 648   return 1;
 649 }
 650
 651 sub check_pricegroup {
 652   my ($self, $entry) = @_;
 653
 654   my $object = $entry->{object};
 655
 656   # Check whether or not pricegroup ID is valid.
 657   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 658     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 659     return 0;
 660   }
 661
 662   # Map pricegroup to ID if given.
 663   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 664     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 665     if (!$pricegroup) {
 666       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 667       return 0;
 668     }
 669
 670     $object->pricegroup_id($pricegroup->id);
 671   }
 672
 673   return 1;
 674 }
 675
 676 sub add_items_to_order {
 677   my ($self) = @_;
 678
 679   # add orderitems to order
 680   my $order_entry;
 681   my @orderitems;
 682   foreach my $entry (@{ $self->controller->data }) {
 683     # search first/next order
 684     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 685
 686       # next order entry: add collected orderitems to the previous one
 687       if (defined $order_entry) {
 688         $order_entry->{object}->orderitems(@orderitems);
 689         @orderitems = ();
 690       }
 691
 692       $order_entry = $entry;
 693
 694     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 695       # collect orderitems to add to order (if they have no errors)
 696       # ( add_orderitems does not work here if we want to call
 697       #   calculate_prices_and_taxes afterwards ...
 698       #   so collect orderitems and add them at once )
 699       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 700     }
 701   }
 702   # add last collected orderitems to last order
 703   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 704 }
 705
 706 sub handle_prices_and_taxes() {
 707   my ($self) = @_;
 708
 709   # calculate prices and taxes
 710   foreach my $entry (@{ $self->controller->data }) {
 711     next if @{ $entry->{errors} };
 712
 713     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 714
 715       $entry->{object}->calculate_prices_and_taxes;
 716
 717       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 718       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 719     }
 720   }
 721
 722   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 723   # And throw an error if the differences are too big.
 724   my @to_verify = ( { column      => 'amount',
 725                       raw_column  => 'verify_amount',
 726                       info_header => 'Calc. Amount',
 727                       info_method => 'calc_amount',
 728                       err_msg     => 'Amounts differ too much',
 729                     },
 730                     { column      => 'netamount',
 731                       raw_column  => 'verify_netamount',
 732                       info_header => 'Calc. Net amount',
 733                       info_method => 'calc_netamount',
 734                       err_msg     => 'Net amounts differ too much',
 735                     } );
 736
 737   foreach my $tv (@to_verify) {
 738     # Todo: access via ->[0] ok? Better: search first order column and use this
 739     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 740       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 741       $self->add_info_columns($self->_order_column,
 742                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 743     }
 744
 745     # check differences
 746     foreach my $entry (@{ $self->controller->data }) {
 747       next if @{ $entry->{errors} };
 748       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 749         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 750         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 751         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 752           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 753         }
 754       }
 755     }
 756   }
 757
 758 }
 759
 760 sub save_objects {
 761   my ($self, %params) = @_;
 762
 763   # Collect orders without errors to save.
 764   my $entries_to_save = [];
 765   foreach my $entry (@{ $self->controller->data }) {
 766     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 767     next if @{ $entry->{errors} };
 768
 769     push @{ $entries_to_save }, $entry;
 770   }
 771
 772   $self->SUPER::save_objects(data => $entries_to_save);
 773 }
 774
 775 sub _order_column {
 776   $_[0]->settings->{'order_column'}
 777 }
 778
 779 sub _item_column {
 780   $_[0]->settings->{'item_column'}
 781 }
 782
 783 1;