SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::PriceSource;
  23 use SL::TransNumber;
  24
  25 use parent qw(SL::Controller::CsvImport::BaseMulti);
  26
  27
  28 use Rose::Object::MakeMethods::Generic
  29 (
  30  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  31 );
  32
  33
  34 sub init_class {
  35   my ($self) = @_;
  36   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  37 }
  38
  39 sub set_profile_defaults {
  40   my ($self) = @_;
  41
  42   $self->controller->profile->_set_defaults(
  43                        order_column    => $::locale->text('Order'),
  44                        item_column     => $::locale->text('OrderItem'),
  45                        max_amount_diff => 0.02,
  46                       );
  47 };
  48
  49
  50 sub init_settings {
  51   my ($self) = @_;
  52
  53   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  54 }
  55
  56
  57 sub init_cvar_configs_by {
  58   my ($self) = @_;
  59
  60   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  61   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  62
  63   my $ccb;
  64   $ccb->{class}->{'SL::DB::Order'}          = [];
  65   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  66   $ccb->{row_ident}->{$self->_order_column} = [];
  67   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  68
  69   return $ccb;
  70 }
  71
  72
  73 sub init_profile {
  74   my ($self) = @_;
  75
  76   my $profile = $self->SUPER::init_profile;
  77
  78   # SUPER::init_profile sets row_ident to the translated class name
  79   # overwrite it with the user specified settings
  80   foreach my $p (@{ $profile }) {
  81     if ($p->{class} eq 'SL::DB::Order') {
  82       $p->{row_ident} = $self->_order_column;
  83     }
  84     if ($p->{class} eq 'SL::DB::OrderItem') {
  85       $p->{row_ident} = $self->_item_column;
  86     }
  87   }
  88
  89   foreach my $p (@{ $profile }) {
  90     my $prof = $p->{profile};
  91     if ($p->{row_ident} eq $self->_order_column) {
  92       # no need to handle
  93       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  94     }
  95     if ($p->{row_ident} eq $self->_item_column) {
  96       # no need to handle
  97       delete @{$prof}{qw(trans_id)};
  98     }
  99   }
 100
 101   return $profile;
 102 }
 103
 104
 105 sub setup_displayable_columns {
 106   my ($self) = @_;
 107
 108   $self->SUPER::setup_displayable_columns;
 109
 110   $self->add_displayable_columns($self->_order_column,
 111                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 112                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 113                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 114                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 115                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 116                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 117                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 118                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 119                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 120                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 121                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 122                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 123                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 124                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 125                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 126                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 127                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 128                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 129                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 130                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 131                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 132                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 133                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 134                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 135                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 136                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 137                                  { name => 'customer_gln',            description => $::locale->text('Customer GLN')                          },
 138                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 139                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 140                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 141                                  { name => 'vendor_gln',              description => $::locale->text('Vendor GLN')                            },
 142                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 143                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 144                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 145                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 146                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 147                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 148                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 149                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 150                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 151                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 152                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 153                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 154                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 155                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 156                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 157                                 );
 158
 159   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 160
 161   $self->add_displayable_columns($self->_item_column,
 162                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 163                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 164                                  { name => 'description',     description => $::locale->text('Description')                },
 165                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 166                                  { name => 'ean',             description => $::locale->text('EAN')                        },
 167                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 168                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 169                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 170                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 171                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 172                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 173                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 174                                  { name => 'position',        description => $::locale->text('position')                   },
 175                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 176                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 177                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 178                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 179                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 180                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 181                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 182                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 183                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 184                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 185                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 186                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 187                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 188                                 );
 189 }
 190
 191
 192 sub init_languages_by {
 193   my ($self) = @_;
 194
 195   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 196 }
 197
 198 sub init_all_parts {
 199   my ($self) = @_;
 200
 201   return SL::DB::Manager::Part->get_all;
 202 }
 203
 204 sub init_parts_by {
 205   my ($self) = @_;
 206
 207   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 208 }
 209
 210 sub init_part_counts_by {
 211   my ($self) = @_;
 212
 213   my $part_counts_by;
 214
 215   $part_counts_by->{ean}->        {$_->ean}++         for @{ $self->all_parts };
 216   $part_counts_by->{description}->{$_->description}++ for @{ $self->all_parts };
 217
 218   return $part_counts_by;
 219 }
 220
 221 sub init_contacts_by {
 222   my ($self) = @_;
 223
 224   my $all_contacts = SL::DB::Manager::Contact->get_all;
 225
 226   my $cby;
 227   # by customer/vendor id  _and_  contact person id
 228   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 229   # by customer/vendor id  _and_  contact person name
 230   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 231
 232   return $cby;
 233 }
 234
 235 sub init_ct_shiptos_by {
 236   my ($self) = @_;
 237
 238   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 239
 240   my $sby;
 241   # by trans_id  _and_  shipto_id
 242   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 243
 244   return $sby;
 245 }
 246
 247 sub init_price_factors_by {
 248   my ($self) = @_;
 249
 250   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 251   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 252 }
 253
 254 sub init_pricegroups_by {
 255   my ($self) = @_;
 256
 257   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 258   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 259 }
 260
 261 sub init_units_by {
 262   my ($self) = @_;
 263
 264   my $all_units = SL::DB::Manager::Unit->get_all;
 265   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 266 }
 267
 268 sub check_objects {
 269   my ($self) = @_;
 270
 271   $self->controller->track_progress(phase => 'building data', progress => 0);
 272
 273   my $i = 0;
 274   my $num_data = scalar @{ $self->controller->data };
 275   my $order_entry;
 276   foreach my $entry (@{ $self->controller->data }) {
 277     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 278
 279     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 280
 281     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 282       $self->handle_order($entry);
 283       $order_entry = $entry;
 284     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 285       $self->handle_item($entry, $order_entry);
 286     } else {
 287       $order_entry = undef;
 288     }
 289
 290     $self->handle_cvars($entry, sub_module => 'orderitems');
 291
 292   } continue {
 293     $i++;
 294   }
 295
 296   $self->add_info_columns($self->_order_column,
 297                           { header => $::locale->text('Data type'), method => 'datatype' });
 298   $self->add_info_columns($self->_item_column,
 299                           { header => $::locale->text('Data type'), method => 'datatype' });
 300
 301   $self->add_info_columns($self->_order_column,
 302                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 303   # Todo: access via ->[0] ok? Better: search first order column and use this
 304   $self->add_columns($self->_order_column,
 305                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 306   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 307   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 308
 309   $self->add_info_columns($self->_item_column,
 310                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 311   # Todo: access via ->[1] ok? Better: search first item column and use this
 312   $self->add_columns($self->_item_column,
 313                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 314   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 315
 316   $self->add_cvar_raw_data_columns();
 317
 318   $self->add_items_to_order();
 319   $self->handle_prices_and_taxes();
 320 }
 321
 322 sub handle_order {
 323   my ($self, $entry) = @_;
 324
 325   my $object = $entry->{object};
 326
 327   my $vc_obj;
 328   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_gln customer_id)) {
 329     $self->check_vc($entry, 'customer_id');
 330     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 331   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_gln vendor_id)) {
 332     $self->check_vc($entry, 'vendor_id');
 333     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 334   } else {
 335     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 336   }
 337
 338   $self->check_contact($entry);
 339   $self->check_language($entry);
 340   $self->check_payment($entry);
 341   $self->check_delivery_term($entry);
 342   $self->check_department($entry);
 343   $self->check_project($entry, global => 1);
 344   $self->check_ct_shipto($entry);
 345   $self->check_taxzone($entry);
 346   $self->check_currency($entry, take_default => 0);
 347
 348   if ($vc_obj) {
 349     # copy from customer if not given
 350     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 351       $object->$_($vc_obj->$_) unless $object->$_;
 352     }
 353     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 354   }
 355
 356   $self->handle_salesman($entry);
 357   $self->handle_employee($entry);
 358 }
 359
 360 sub check_language {
 361   my ($self, $entry) = @_;
 362
 363   my $object = $entry->{object};
 364
 365   # Check whether or not language ID is valid.
 366   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 367     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 368     return 0;
 369   }
 370
 371   # Map name to ID if given.
 372   if (!$object->language_id && $entry->{raw_data}->{language}) {
 373     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 374                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 375
 376     if (!$language) {
 377       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 378       return 0;
 379     }
 380
 381     $object->language_id($language->id);
 382   }
 383
 384   if ($object->language_id) {
 385     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 386   }
 387
 388   return 1;
 389 }
 390
 391 sub handle_item {
 392   my ($self, $entry, $order_entry) = @_;
 393
 394   return unless $order_entry;
 395
 396   my $object = $entry->{object};
 397
 398   return unless $self->check_part($entry);
 399
 400   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 401
 402   $self->handle_unit($entry);
 403
 404   # copy from part if not given
 405   $object->description($part_obj->description) unless $object->description;
 406   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 407   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 408
 409   # set to 0 if not given
 410   $object->ship(0)     unless $object->ship;
 411
 412   $self->check_project($entry, global => 0);
 413   $self->check_price_factor($entry);
 414   $self->check_pricegroup($entry);
 415
 416   $self->handle_sellprice($entry, $order_entry);
 417   $self->handle_discount($entry, $order_entry);
 418 }
 419
 420 sub handle_unit {
 421   my ($self, $entry) = @_;
 422
 423   my $object = $entry->{object};
 424
 425   # Set unit from part if not given.
 426   if (!$object->unit) {
 427     $object->unit($object->part->unit);
 428     return 1;
 429   }
 430
 431   # Check whether or not unit is valid.
 432   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 433     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 434     return 0;
 435   }
 436
 437   # Check whether unit is convertible to parts unit
 438   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 439     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 440     return 0;
 441   }
 442
 443   return 1;
 444 }
 445
 446 sub handle_sellprice {
 447   my ($self, $entry, $record_entry) = @_;
 448
 449   my $item   = $entry->{object};
 450   my $record = $record_entry->{object};
 451
 452   return if !$record->customervendor;
 453
 454   # If sellprice is given, set price source to pricegroup if given or to none.
 455   if (exists $entry->{raw_data}->{sellprice}) {
 456     my $price_source      = SL::PriceSource->new(record_item => $item, record => $record);
 457     my $price_source_spec = $item->pricegroup_id ? 'pricegroup' . '/' . $item->pricegroup_id : '';
 458     my $price             = $price_source->price_from_source($price_source_spec);
 459     $item->active_price_source($price->source);
 460
 461   } else {
 462     # Set sellprice the best price of price source
 463     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 464     my $price        = $price_source->best_price;
 465     if ($price) {
 466       $item->sellprice($price->price);
 467       $item->active_price_source($price->source);
 468     } else {
 469       $item->sellprice(0);
 470       $item->active_price_source($price_source->price_from_source('')->source);
 471     }
 472   }
 473 }
 474
 475 sub handle_discount {
 476   my ($self, $entry, $record_entry) = @_;
 477
 478   my $item   = $entry->{object};
 479   my $record = $record_entry->{object};
 480
 481   return if !$record->customervendor;
 482
 483   # If discount is given, set discount source to none.
 484   if (exists $entry->{raw_data}->{discount}) {
 485     $item->discount($item->discount/100.0)      if $item->discount;
 486     $item->discount(0)                      unless $item->discount;
 487
 488     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 489     my $discount     = $price_source->price_from_source('');
 490     $item->active_discount_source($discount->source);
 491
 492   } else {
 493     # Set discount the best discount of price source
 494     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 495     my $discount     = $price_source->best_discount;
 496     if ($discount) {
 497       $item->discount($discount->discount);
 498       $item->active_discount_source($discount->source);
 499     } else {
 500       $item->discount(0);
 501       $item->active_discount_source($price_source->discount_from_source('')->source);
 502     }
 503   }
 504 }
 505
 506 sub check_part {
 507   my ($self, $entry) = @_;
 508
 509   my $object = $entry->{object};
 510   my $is_ambiguous;
 511
 512   # Check whether or not part ID is valid.
 513   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 514     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 515     return 0;
 516   }
 517
 518   # Map number to ID if given.
 519   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 520     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 521     if (!$part) {
 522       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 523       return 0;
 524     }
 525
 526     $object->parts_id($part->id);
 527   }
 528
 529   # Map description to ID if given.
 530   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 531     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 532     if (!$part) {
 533       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 534       return 0;
 535     }
 536
 537     if ($self->part_counts_by->{description}->{ $entry->{raw_data}->{description} } > 1) {
 538       $is_ambiguous = 1;
 539     } else {
 540       $object->parts_id($part->id);
 541     }
 542   }
 543
 544   # Map ean to ID if given.
 545   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 546     my $part = $self->parts_by->{ean}->{ $entry->{raw_data}->{ean} };
 547     if (!$part) {
 548       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 549       return 0;
 550     }
 551
 552     if ($self->part_counts_by->{ean}->{ $entry->{raw_data}->{ean} } > 1) {
 553       $is_ambiguous = 1;
 554     } else {
 555       $object->parts_id($part->id);
 556     }
 557   }
 558
 559   if ($object->parts_id) {
 560     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 561   } else {
 562     if ($is_ambiguous) {
 563       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
 564     } else {
 565       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 566     }
 567     return 0;
 568   }
 569
 570   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 571     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 572     return 0;
 573   }
 574
 575   return 1;
 576 }
 577
 578 sub check_contact {
 579   my ($self, $entry) = @_;
 580
 581   my $object = $entry->{object};
 582
 583   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 584   return 0 unless $cp_cv_id;
 585
 586   # Check whether or not contact ID is valid.
 587   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 588     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 589     return 0;
 590   }
 591
 592   # Map name to ID if given.
 593   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 594     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 595     if (!$cp) {
 596       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 597       return 0;
 598     }
 599
 600     $object->cp_id($cp->cp_id);
 601   }
 602
 603   if ($object->cp_id) {
 604     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 605   }
 606
 607   return 1;
 608 }
 609
 610 sub check_ct_shipto {
 611   my ($self, $entry) = @_;
 612
 613   my $object = $entry->{object};
 614
 615   my $trans_id = $object->customer_id || $object->vendor_id;
 616   return 0 unless $trans_id;
 617
 618   # Check whether or not shipto ID is valid.
 619   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 620     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 621     return 0;
 622   }
 623
 624   return 1;
 625 }
 626
 627 sub check_price_factor {
 628   my ($self, $entry) = @_;
 629
 630   my $object = $entry->{object};
 631
 632   # Check whether or not price_factor ID is valid.
 633   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 634     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 635     return 0;
 636   }
 637
 638   # Map description to ID if given.
 639   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 640     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 641     if (!$price_factor) {
 642       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 643       return 0;
 644     }
 645
 646     $object->price_factor_id($price_factor->id);
 647   }
 648
 649   return 1;
 650 }
 651
 652 sub check_pricegroup {
 653   my ($self, $entry) = @_;
 654
 655   my $object = $entry->{object};
 656
 657   # Check whether or not pricegroup ID is valid.
 658   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 659     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 660     return 0;
 661   }
 662
 663   # Map pricegroup to ID if given.
 664   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 665     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 666     if (!$pricegroup) {
 667       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 668       return 0;
 669     }
 670
 671     $object->pricegroup_id($pricegroup->id);
 672   }
 673
 674   return 1;
 675 }
 676
 677 sub add_items_to_order {
 678   my ($self) = @_;
 679
 680   # add orderitems to order
 681   my $order_entry;
 682   my @orderitems;
 683   foreach my $entry (@{ $self->controller->data }) {
 684     # search first/next order
 685     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 686
 687       # next order entry: add collected orderitems to the previous one
 688       if (defined $order_entry) {
 689         $order_entry->{object}->orderitems(@orderitems);
 690         @orderitems = ();
 691       }
 692
 693       $order_entry = $entry;
 694
 695     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 696       # collect orderitems to add to order (if they have no errors)
 697       # ( add_orderitems does not work here if we want to call
 698       #   calculate_prices_and_taxes afterwards ...
 699       #   so collect orderitems and add them at once )
 700       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 701     }
 702   }
 703   # add last collected orderitems to last order
 704   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 705 }
 706
 707 sub handle_prices_and_taxes() {
 708   my ($self) = @_;
 709
 710   # calculate prices and taxes
 711   foreach my $entry (@{ $self->controller->data }) {
 712     next if @{ $entry->{errors} };
 713
 714     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 715
 716       $entry->{object}->calculate_prices_and_taxes;
 717
 718       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 719       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 720     }
 721   }
 722
 723   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 724   # And throw an error if the differences are too big.
 725   my @to_verify = ( { column      => 'amount',
 726                       raw_column  => 'verify_amount',
 727                       info_header => 'Calc. Amount',
 728                       info_method => 'calc_amount',
 729                       err_msg     => 'Amounts differ too much',
 730                     },
 731                     { column      => 'netamount',
 732                       raw_column  => 'verify_netamount',
 733                       info_header => 'Calc. Net amount',
 734                       info_method => 'calc_netamount',
 735                       err_msg     => 'Net amounts differ too much',
 736                     } );
 737
 738   foreach my $tv (@to_verify) {
 739     # Todo: access via ->[0] ok? Better: search first order column and use this
 740     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 741       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 742       $self->add_info_columns($self->_order_column,
 743                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 744     }
 745
 746     # check differences
 747     foreach my $entry (@{ $self->controller->data }) {
 748       next if @{ $entry->{errors} };
 749       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 750         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 751         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 752         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 753           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 754         }
 755       }
 756     }
 757   }
 758
 759 }
 760
 761 sub save_objects {
 762   my ($self, %params) = @_;
 763
 764   # Collect orders without errors to save.
 765   my $entries_to_save = [];
 766   foreach my $entry (@{ $self->controller->data }) {
 767     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 768     next if @{ $entry->{errors} };
 769
 770     push @{ $entries_to_save }, $entry;
 771   }
 772
 773   $self->SUPER::save_objects(data => $entries_to_save);
 774 }
 775
 776 sub _order_column {
 777   $_[0]->settings->{'order_column'}
 778 }
 779
 780 sub _item_column {
 781   $_[0]->settings->{'item_column'}
 782 }
 783
 784 1;