SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::TransNumber;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 137                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 138                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 139                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 140                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 141                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 142                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 143                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 144                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 145                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 146                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 147                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 148                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 149                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 150                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 151                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 152                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 153                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 154                                 );
 155
 156   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 157
 158   $self->add_displayable_columns($self->_item_column,
 159                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 160                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 161                                  { name => 'description',     description => $::locale->text('Description')                },
 162                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 163                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 164                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 165                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 166                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 167                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 168                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 169                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 170                                  { name => 'position',        description => $::locale->text('position')                   },
 171                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 172                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 173                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 174                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 175                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 176                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 177                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 178                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 179                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 180                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 181                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 182                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 183                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 184                                 );
 185 }
 186
 187
 188 sub init_languages_by {
 189   my ($self) = @_;
 190
 191   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 192 }
 193
 194 sub init_parts_by {
 195   my ($self) = @_;
 196
 197   my $all_parts = SL::DB::Manager::Part->get_all;
 198   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 199 }
 200
 201 sub init_contacts_by {
 202   my ($self) = @_;
 203
 204   my $all_contacts = SL::DB::Manager::Contact->get_all;
 205
 206   my $cby;
 207   # by customer/vendor id  _and_  contact person id
 208   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 209   # by customer/vendor id  _and_  contact person name
 210   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 211
 212   return $cby;
 213 }
 214
 215 sub init_ct_shiptos_by {
 216   my ($self) = @_;
 217
 218   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 219
 220   my $sby;
 221   # by trans_id  _and_  shipto_id
 222   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 223
 224   return $sby;
 225 }
 226
 227 sub init_price_factors_by {
 228   my ($self) = @_;
 229
 230   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 231   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 232 }
 233
 234 sub init_pricegroups_by {
 235   my ($self) = @_;
 236
 237   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 238   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 239 }
 240
 241 sub init_units_by {
 242   my ($self) = @_;
 243
 244   my $all_units = SL::DB::Manager::Unit->get_all;
 245   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 246 }
 247
 248 sub check_objects {
 249   my ($self) = @_;
 250
 251   $self->controller->track_progress(phase => 'building data', progress => 0);
 252
 253   my $i = 0;
 254   my $num_data = scalar @{ $self->controller->data };
 255   foreach my $entry (@{ $self->controller->data }) {
 256     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 257
 258     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 259       $self->handle_order($entry);
 260     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 261       $self->handle_item($entry);
 262     }
 263     $self->handle_cvars($entry, sub_module => 'orderitems');
 264
 265   } continue {
 266     $i++;
 267   }
 268
 269   $self->add_info_columns($self->_order_column,
 270                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 271   # Todo: access via ->[0] ok? Better: search first order column and use this
 272   $self->add_columns($self->_order_column,
 273                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 274   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 275   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 276
 277   $self->add_info_columns($self->_item_column,
 278                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 279   # Todo: access via ->[1] ok? Better: search first item column and use this
 280   $self->add_columns($self->_item_column,
 281                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 282   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 283
 284   $self->add_cvar_raw_data_columns();
 285
 286   $self->add_items_to_order();
 287   $self->handle_prices_and_taxes();
 288 }
 289
 290 sub handle_order {
 291   my ($self, $entry) = @_;
 292
 293   my $object = $entry->{object};
 294
 295   my $vc_obj;
 296   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 297     $self->check_vc($entry, 'customer_id');
 298     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 299   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 300     $self->check_vc($entry, 'vendor_id');
 301     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 302   } else {
 303     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 304   }
 305
 306   $self->check_contact($entry);
 307   $self->check_language($entry);
 308   $self->check_payment($entry);
 309   $self->check_delivery_term($entry);
 310   $self->check_department($entry);
 311   $self->check_project($entry, global => 1);
 312   $self->check_ct_shipto($entry);
 313   $self->check_taxzone($entry);
 314   $self->check_currency($entry, take_default => 0);
 315
 316   if ($vc_obj) {
 317     # copy from customer if not given
 318     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 319       $object->$_($vc_obj->$_) unless $object->$_;
 320     }
 321   }
 322
 323   $self->handle_salesman($entry);
 324   $self->handle_employee($entry);
 325 }
 326
 327 sub check_language {
 328   my ($self, $entry) = @_;
 329
 330   my $object = $entry->{object};
 331
 332   # Check whether or not language ID is valid.
 333   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 334     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 335     return 0;
 336   }
 337
 338   # Map name to ID if given.
 339   if (!$object->language_id && $entry->{raw_data}->{language}) {
 340     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 341                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 342
 343     if (!$language) {
 344       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 345       return 0;
 346     }
 347
 348     $object->language_id($language->id);
 349   }
 350
 351   if ($object->language_id) {
 352     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 353   }
 354
 355   return 1;
 356 }
 357
 358 sub handle_item {
 359   my ($self, $entry) = @_;
 360
 361   my $object = $entry->{object};
 362   return unless $self->check_part($entry);
 363
 364   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 365
 366   $self->handle_unit($entry);
 367   $self->handle_sellprice($entry);
 368
 369   # copy from part if not given
 370   $object->description($part_obj->description) unless $object->description;
 371   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 372   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 373
 374   # set to 0 if not given
 375   $object->discount(0) unless $object->discount;
 376   $object->ship(0)     unless $object->ship;
 377
 378   $self->check_project($entry, global => 0);
 379   $self->check_price_factor($entry);
 380   $self->check_pricegroup($entry);
 381 }
 382
 383 sub handle_unit {
 384   my ($self, $entry) = @_;
 385
 386   my $object = $entry->{object};
 387
 388   # Set unit from part if not given.
 389   if (!$object->unit) {
 390     $object->unit($object->part->unit);
 391     return 1;
 392   }
 393
 394   # Check whether or not unit is valid.
 395   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 396     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 397     return 0;
 398   }
 399
 400   # Check whether unit is convertible to parts unit
 401   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 402     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 403     return 0;
 404   }
 405
 406   return 1;
 407 }
 408
 409 sub handle_sellprice {
 410   my ($self, $entry) = @_;
 411
 412   my $object = $entry->{object};
 413
 414   # Set sellprice from part if not given. Convert with respect to unit.
 415   if (!defined $object->sellprice) {
 416     my $sellprice = $object->part->sellprice;
 417
 418     if ($object->unit ne $object->part->unit) {
 419       $sellprice = $object->unit_obj->convert_to($sellprice, $object->part->unit_obj);
 420     }
 421     $object->sellprice($sellprice);
 422   }
 423 }
 424
 425 sub check_part {
 426   my ($self, $entry) = @_;
 427
 428   my $object = $entry->{object};
 429
 430   # Check whether or not part ID is valid.
 431   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 432     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 433     return 0;
 434   }
 435
 436   # Map number to ID if given.
 437   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 438     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 439     if (!$part) {
 440       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 441       return 0;
 442     }
 443
 444     $object->parts_id($part->id);
 445   }
 446
 447   # Map description to ID if given.
 448   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 449     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 450     if (!$part) {
 451       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 452       return 0;
 453     }
 454
 455     $object->parts_id($part->id);
 456   }
 457
 458   if ($object->parts_id) {
 459     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 460   } else {
 461     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 462     return 0;
 463   }
 464
 465   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 466     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 467     return 0;
 468   }
 469
 470   return 1;
 471 }
 472
 473 sub check_contact {
 474   my ($self, $entry) = @_;
 475
 476   my $object = $entry->{object};
 477
 478   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 479   return 0 unless $cp_cv_id;
 480
 481   # Check whether or not contact ID is valid.
 482   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 483     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 484     return 0;
 485   }
 486
 487   # Map name to ID if given.
 488   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 489     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 490     if (!$cp) {
 491       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 492       return 0;
 493     }
 494
 495     $object->cp_id($cp->cp_id);
 496   }
 497
 498   if ($object->cp_id) {
 499     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 500   }
 501
 502   return 1;
 503 }
 504
 505 sub check_ct_shipto {
 506   my ($self, $entry) = @_;
 507
 508   my $object = $entry->{object};
 509
 510   my $trans_id = $object->customer_id || $object->vendor_id;
 511   return 0 unless $trans_id;
 512
 513   # Check whether or not shipto ID is valid.
 514   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 515     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 516     return 0;
 517   }
 518
 519   return 1;
 520 }
 521
 522 sub check_price_factor {
 523   my ($self, $entry) = @_;
 524
 525   my $object = $entry->{object};
 526
 527   # Check whether or not price_factor ID is valid.
 528   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 529     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 530     return 0;
 531   }
 532
 533   # Map description to ID if given.
 534   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 535     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 536     if (!$price_factor) {
 537       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 538       return 0;
 539     }
 540
 541     $object->price_factor_id($price_factor->id);
 542   }
 543
 544   return 1;
 545 }
 546
 547 sub check_pricegroup {
 548   my ($self, $entry) = @_;
 549
 550   my $object = $entry->{object};
 551
 552   # Check whether or not pricegroup ID is valid.
 553   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 554     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 555     return 0;
 556   }
 557
 558   # Map pricegroup to ID if given.
 559   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 560     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 561     if (!$pricegroup) {
 562       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 563       return 0;
 564     }
 565
 566     $object->pricegroup_id($pricegroup->id);
 567   }
 568
 569   return 1;
 570 }
 571
 572 sub add_items_to_order {
 573   my ($self) = @_;
 574
 575   # add orderitems to order
 576   my $order_entry;
 577   my @orderitems;
 578   foreach my $entry (@{ $self->controller->data }) {
 579     # search first/next order
 580     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 581
 582       # next order entry: add collected orderitems to the previous one
 583       if (defined $order_entry) {
 584         $order_entry->{object}->orderitems(@orderitems);
 585         @orderitems = ();
 586       }
 587
 588       $order_entry = $entry;
 589
 590     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 591       # collect orderitems to add to order (if they have no errors)
 592       # ( add_orderitems does not work here if we want to call
 593       #   calculate_prices_and_taxes afterwards ...
 594       #   so collect orderitems and add them at once )
 595       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 596     }
 597   }
 598   # add last collected orderitems to last order
 599   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 600 }
 601
 602 sub handle_prices_and_taxes() {
 603   my ($self) = @_;
 604
 605   # calculate prices and taxes
 606   foreach my $entry (@{ $self->controller->data }) {
 607     next if @{ $entry->{errors} };
 608
 609     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 610
 611       $entry->{object}->calculate_prices_and_taxes;
 612
 613       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 614       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 615     }
 616   }
 617
 618   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 619   # And throw an error if the differences are too big.
 620   my @to_verify = ( { column      => 'amount',
 621                       raw_column  => 'verify_amount',
 622                       info_header => 'Calc. Amount',
 623                       info_method => 'calc_amount',
 624                       err_msg     => 'Amounts differ too much',
 625                     },
 626                     { column      => 'netamount',
 627                       raw_column  => 'verify_netamount',
 628                       info_header => 'Calc. Net amount',
 629                       info_method => 'calc_netamount',
 630                       err_msg     => 'Net amounts differ too much',
 631                     } );
 632
 633   foreach my $tv (@to_verify) {
 634     # Todo: access via ->[0] ok? Better: search first order column and use this
 635     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 636       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 637       $self->add_info_columns($self->_order_column,
 638                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 639     }
 640
 641     # check differences
 642     foreach my $entry (@{ $self->controller->data }) {
 643       next if @{ $entry->{errors} };
 644       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 645         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 646         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 647         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 648           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 649         }
 650       }
 651     }
 652   }
 653
 654 }
 655
 656 sub save_objects {
 657   my ($self, %params) = @_;
 658
 659   # set order number and collect to save
 660   my $objects_to_save = [];
 661   foreach my $entry (@{ $self->controller->data }) {
 662     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 663     next if @{ $entry->{errors} };
 664
 665     push @{ $objects_to_save }, $entry;
 666   }
 667
 668   $self->SUPER::save_objects(data => $objects_to_save);
 669 }
 670
 671 sub _order_column {
 672   $_[0]->settings->{'order_column'}
 673 }
 674
 675 sub _item_column {
 676   $_[0]->settings->{'item_column'}
 677 }
 678
 679 1;