SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Pricegroup;
  18 use SL::DB::Project;
  19 use SL::DB::Shipto;
  20 use SL::DB::TaxZone;
  21 use SL::DB::Unit;
  22 use SL::TransNumber;
  23
  24 use parent qw(SL::Controller::CsvImport::BaseMulti);
  25
  26
  27 use Rose::Object::MakeMethods::Generic
  28 (
  29  'scalar --get_set_init' => [ qw(settings languages_by parts_by contacts_by ct_shiptos_by price_factors_by pricegroups_by units_by) ],
  30 );
  31
  32
  33 sub init_class {
  34   my ($self) = @_;
  35   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  36 }
  37
  38 sub set_profile_defaults {
  39   my ($self) = @_;
  40
  41   $self->controller->profile->_set_defaults(
  42                        order_column    => $::locale->text('Order'),
  43                        item_column     => $::locale->text('OrderItem'),
  44                        max_amount_diff => 0.02,
  45                       );
  46 };
  47
  48
  49 sub init_settings {
  50   my ($self) = @_;
  51
  52   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  53 }
  54
  55
  56 sub init_cvar_configs_by {
  57   my ($self) = @_;
  58
  59   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  60   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  61
  62   my $ccb;
  63   $ccb->{class}->{'SL::DB::Order'}          = [];
  64   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  65   $ccb->{row_ident}->{$self->_order_column} = [];
  66   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  67
  68   return $ccb;
  69 }
  70
  71
  72 sub init_profile {
  73   my ($self) = @_;
  74
  75   my $profile = $self->SUPER::init_profile;
  76
  77   # SUPER::init_profile sets row_ident to the translated class name
  78   # overwrite it with the user specified settings
  79   foreach my $p (@{ $profile }) {
  80     if ($p->{class} eq 'SL::DB::Order') {
  81       $p->{row_ident} = $self->_order_column;
  82     }
  83     if ($p->{class} eq 'SL::DB::OrderItem') {
  84       $p->{row_ident} = $self->_item_column;
  85     }
  86   }
  87
  88   foreach my $p (@{ $profile }) {
  89     my $prof = $p->{profile};
  90     if ($p->{row_ident} eq $self->_order_column) {
  91       # no need to handle
  92       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  93     }
  94     if ($p->{row_ident} eq $self->_item_column) {
  95       # no need to handle
  96       delete @{$prof}{qw(trans_id)};
  97     }
  98   }
  99
 100   return $profile;
 101 }
 102
 103
 104 sub setup_displayable_columns {
 105   my ($self) = @_;
 106
 107   $self->SUPER::setup_displayable_columns;
 108
 109   $self->add_displayable_columns($self->_order_column,
 110                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 111                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 112                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 113                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 114                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 115                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 116                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 117                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 118                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 119                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 120                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 121                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 122                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 123                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 124                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 125                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 126                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 127                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 128                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 129                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 130                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 131                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 132                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 133                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 134                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 135                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 136                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 137                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 138                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 139                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 140                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 141                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 142                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 143                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 144                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 145                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 146                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 147                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 148                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 149                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 150                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 151                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 152                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 153                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 154                                 );
 155
 156   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 157
 158   $self->add_displayable_columns($self->_item_column,
 159                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 160                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 161                                  { name => 'description',     description => $::locale->text('Description')                },
 162                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 163                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 164                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 165                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 166                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 167                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 168                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 169                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 170                                  { name => 'position',        description => $::locale->text('position')                   },
 171                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 172                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 173                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 174                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 175                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 176                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 177                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 178                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 179                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 180                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 181                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 182                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 183                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 184                                 );
 185 }
 186
 187
 188 sub init_languages_by {
 189   my ($self) = @_;
 190
 191   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 192 }
 193
 194 sub init_parts_by {
 195   my ($self) = @_;
 196
 197   my $all_parts = SL::DB::Manager::Part->get_all;
 198   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_parts } } ) } qw(id partnumber ean description) };
 199 }
 200
 201 sub init_contacts_by {
 202   my ($self) = @_;
 203
 204   my $all_contacts = SL::DB::Manager::Contact->get_all;
 205
 206   my $cby;
 207   # by customer/vendor id  _and_  contact person id
 208   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 209   # by customer/vendor id  _and_  contact person name
 210   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 211
 212   return $cby;
 213 }
 214
 215 sub init_ct_shiptos_by {
 216   my ($self) = @_;
 217
 218   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 219
 220   my $sby;
 221   # by trans_id  _and_  shipto_id
 222   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 223
 224   return $sby;
 225 }
 226
 227 sub init_price_factors_by {
 228   my ($self) = @_;
 229
 230   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 231   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 232 }
 233
 234 sub init_pricegroups_by {
 235   my ($self) = @_;
 236
 237   my $all_pricegroups = SL::DB::Manager::Pricegroup->get_all;
 238   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_pricegroups } } ) } qw(id pricegroup) };
 239 }
 240
 241 sub init_units_by {
 242   my ($self) = @_;
 243
 244   my $all_units = SL::DB::Manager::Unit->get_all;
 245   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 246 }
 247
 248 sub check_objects {
 249   my ($self) = @_;
 250
 251   $self->controller->track_progress(phase => 'building data', progress => 0);
 252
 253   my $i = 0;
 254   my $num_data = scalar @{ $self->controller->data };
 255   foreach my $entry (@{ $self->controller->data }) {
 256     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 257
 258     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 259       $self->handle_order($entry);
 260     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 261       $self->handle_item($entry);
 262     }
 263     $self->handle_cvars($entry, sub_module => 'orderitems');
 264
 265   } continue {
 266     $i++;
 267   }
 268
 269   $self->add_info_columns($self->_order_column,
 270                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 271   # Todo: access via ->[0] ok? Better: search first order column and use this
 272   $self->add_columns($self->_order_column,
 273                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 274   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 275   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 276
 277   $self->add_info_columns($self->_item_column,
 278                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 279   # Todo: access via ->[1] ok? Better: search first item column and use this
 280   $self->add_columns($self->_item_column,
 281                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 282   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 283
 284   $self->add_cvar_raw_data_columns();
 285
 286   $self->add_items_to_order();
 287   $self->handle_prices_and_taxes();
 288
 289
 290   # If order has errors set error for orderitems as well
 291   my $order_entry;
 292   foreach my $entry (@{ $self->controller->data }) {
 293     # Search first order
 294     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 295       $order_entry = $entry;
 296     } elsif ( defined $order_entry
 297               && $entry->{raw_data}->{datatype} eq $self->_item_column
 298               && scalar @{ $order_entry->{errors} } > 0 ) {
 299       push @{ $entry->{errors} }, $::locale->text('Error: Invalid order for this order item');
 300     }
 301   }
 302
 303 }
 304
 305 sub handle_order {
 306   my ($self, $entry) = @_;
 307
 308   my $object = $entry->{object};
 309
 310   my $vc_obj;
 311   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 312     $self->check_vc($entry, 'customer_id');
 313     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 314   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 315     $self->check_vc($entry, 'vendor_id');
 316     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 317   } else {
 318     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 319   }
 320
 321   $self->check_contact($entry);
 322   $self->check_language($entry);
 323   $self->check_payment($entry);
 324   $self->check_delivery_term($entry);
 325   $self->check_department($entry);
 326   $self->check_project($entry, global => 1);
 327   $self->check_ct_shipto($entry);
 328   $self->check_taxzone($entry);
 329   $self->check_currency($entry, take_default => 0);
 330
 331   if ($vc_obj) {
 332     # copy from customer if not given
 333     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 334       $object->$_($vc_obj->$_) unless $object->$_;
 335     }
 336   }
 337
 338   $self->handle_salesman($entry);
 339   $self->handle_employee($entry);
 340 }
 341
 342 sub check_language {
 343   my ($self, $entry) = @_;
 344
 345   my $object = $entry->{object};
 346
 347   # Check whether or not language ID is valid.
 348   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 349     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 350     return 0;
 351   }
 352
 353   # Map name to ID if given.
 354   if (!$object->language_id && $entry->{raw_data}->{language}) {
 355     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 356                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 357
 358     if (!$language) {
 359       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 360       return 0;
 361     }
 362
 363     $object->language_id($language->id);
 364   }
 365
 366   if ($object->language_id) {
 367     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 368   }
 369
 370   return 1;
 371 }
 372
 373 sub handle_item {
 374   my ($self, $entry) = @_;
 375
 376   my $object = $entry->{object};
 377   return unless $self->check_part($entry);
 378
 379   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 380
 381   $self->handle_unit($entry);
 382   $self->handle_sellprice($entry);
 383
 384   # copy from part if not given
 385   $object->description($part_obj->description) unless $object->description;
 386   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 387   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 388
 389   # set to 0 if not given
 390   $object->discount(0) unless $object->discount;
 391   $object->ship(0)     unless $object->ship;
 392
 393   $self->check_project($entry, global => 0);
 394   $self->check_price_factor($entry);
 395   $self->check_pricegroup($entry);
 396 }
 397
 398 sub handle_unit {
 399   my ($self, $entry) = @_;
 400
 401   my $object = $entry->{object};
 402
 403   # Set unit from part if not given.
 404   if (!$object->unit) {
 405     $object->unit($object->part->unit);
 406     return 1;
 407   }
 408
 409   # Check whether or not unit is valid.
 410   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 411     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 412     return 0;
 413   }
 414
 415   # Check whether unit is convertible to parts unit
 416   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 417     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 418     return 0;
 419   }
 420
 421   return 1;
 422 }
 423
 424 sub handle_sellprice {
 425   my ($self, $entry) = @_;
 426
 427   my $object = $entry->{object};
 428
 429   # Set sellprice from part if not given. Convert with respect to unit.
 430   if (!defined $object->sellprice) {
 431     my $sellprice = $object->part->sellprice;
 432
 433     if ($object->unit ne $object->part->unit) {
 434       $sellprice = $object->unit_obj->convert_to($sellprice, $object->part->unit_obj);
 435     }
 436     $object->sellprice($sellprice);
 437   }
 438 }
 439
 440 sub check_part {
 441   my ($self, $entry) = @_;
 442
 443   my $object = $entry->{object};
 444
 445   # Check whether or not part ID is valid.
 446   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 447     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 448     return 0;
 449   }
 450
 451   # Map number to ID if given.
 452   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 453     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 454     if (!$part) {
 455       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 456       return 0;
 457     }
 458
 459     $object->parts_id($part->id);
 460   }
 461
 462   # Map description to ID if given.
 463   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 464     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 465     if (!$part) {
 466       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 467       return 0;
 468     }
 469
 470     $object->parts_id($part->id);
 471   }
 472
 473   if ($object->parts_id) {
 474     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 475   } else {
 476     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 477     return 0;
 478   }
 479
 480   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 481     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 482     return 0;
 483   }
 484
 485   return 1;
 486 }
 487
 488 sub check_contact {
 489   my ($self, $entry) = @_;
 490
 491   my $object = $entry->{object};
 492
 493   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 494   return 0 unless $cp_cv_id;
 495
 496   # Check whether or not contact ID is valid.
 497   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 498     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 499     return 0;
 500   }
 501
 502   # Map name to ID if given.
 503   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 504     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 505     if (!$cp) {
 506       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 507       return 0;
 508     }
 509
 510     $object->cp_id($cp->cp_id);
 511   }
 512
 513   if ($object->cp_id) {
 514     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 515   }
 516
 517   return 1;
 518 }
 519
 520 sub check_ct_shipto {
 521   my ($self, $entry) = @_;
 522
 523   my $object = $entry->{object};
 524
 525   my $trans_id = $object->customer_id || $object->vendor_id;
 526   return 0 unless $trans_id;
 527
 528   # Check whether or not shipto ID is valid.
 529   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 530     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 531     return 0;
 532   }
 533
 534   return 1;
 535 }
 536
 537 sub check_price_factor {
 538   my ($self, $entry) = @_;
 539
 540   my $object = $entry->{object};
 541
 542   # Check whether or not price_factor ID is valid.
 543   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 544     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 545     return 0;
 546   }
 547
 548   # Map description to ID if given.
 549   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 550     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 551     if (!$price_factor) {
 552       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 553       return 0;
 554     }
 555
 556     $object->price_factor_id($price_factor->id);
 557   }
 558
 559   return 1;
 560 }
 561
 562 sub check_pricegroup {
 563   my ($self, $entry) = @_;
 564
 565   my $object = $entry->{object};
 566
 567   # Check whether or not pricegroup ID is valid.
 568   if ($object->pricegroup_id && !$self->pricegroups_by->{id}->{ $object->pricegroup_id }) {
 569     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 570     return 0;
 571   }
 572
 573   # Map pricegroup to ID if given.
 574   if (!$object->pricegroup_id && $entry->{raw_data}->{pricegroup}) {
 575     my $pricegroup = $self->pricegroups_by->{pricegroup}->{ $entry->{raw_data}->{pricegroup} };
 576     if (!$pricegroup) {
 577       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price group');
 578       return 0;
 579     }
 580
 581     $object->pricegroup_id($pricegroup->id);
 582   }
 583
 584   return 1;
 585 }
 586
 587 sub add_items_to_order {
 588   my ($self) = @_;
 589
 590   # add orderitems to order
 591   my $order_entry;
 592   my @orderitems;
 593   foreach my $entry (@{ $self->controller->data }) {
 594     # search first/next order
 595     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 596
 597       # next order entry: add collected orderitems to the previous one
 598       if (defined $order_entry) {
 599         $order_entry->{object}->orderitems(@orderitems);
 600         @orderitems = ();
 601       }
 602
 603       $order_entry = $entry;
 604
 605     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 606       # collect orderitems to add to order (if they have no errors)
 607       # ( add_orderitems does not work here if we want to call
 608       #   calculate_prices_and_taxes afterwards ...
 609       #   so collect orderitems and add them at once )
 610       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 611     }
 612   }
 613   # add last collected orderitems to last order
 614   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 615 }
 616
 617 sub handle_prices_and_taxes() {
 618   my ($self) = @_;
 619
 620   # calculate prices and taxes
 621   foreach my $entry (@{ $self->controller->data }) {
 622     next if @{ $entry->{errors} };
 623
 624     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 625
 626       $entry->{object}->calculate_prices_and_taxes;
 627
 628       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 629       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 630     }
 631   }
 632
 633   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 634   # And throw an error if the differences are too big.
 635   my @to_verify = ( { column      => 'amount',
 636                       raw_column  => 'verify_amount',
 637                       info_header => 'Calc. Amount',
 638                       info_method => 'calc_amount',
 639                       err_msg     => 'Amounts differ too much',
 640                     },
 641                     { column      => 'netamount',
 642                       raw_column  => 'verify_netamount',
 643                       info_header => 'Calc. Net amount',
 644                       info_method => 'calc_netamount',
 645                       err_msg     => 'Net amounts differ too much',
 646                     } );
 647
 648   foreach my $tv (@to_verify) {
 649     # Todo: access via ->[0] ok? Better: search first order column and use this
 650     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 651       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 652       $self->add_info_columns($self->_order_column,
 653                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 654     }
 655
 656     # check differences
 657     foreach my $entry (@{ $self->controller->data }) {
 658       next if @{ $entry->{errors} };
 659       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 660         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 661         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 662         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 663           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 664         }
 665       }
 666     }
 667   }
 668
 669 }
 670
 671 sub save_objects {
 672   my ($self, %params) = @_;
 673
 674   # set order number and collect to save
 675   my $objects_to_save = [];
 676   foreach my $entry (@{ $self->controller->data }) {
 677     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 678     next if @{ $entry->{errors} };
 679
 680     push @{ $objects_to_save }, $entry;
 681   }
 682
 683   $self->SUPER::save_objects(data => $objects_to_save);
 684 }
 685
 686 sub _order_column {
 687   $_[0]->settings->{'order_column'}
 688 }
 689
 690 sub _item_column {
 691   $_[0]->settings->{'item_column'}
 692 }
 693
 694 1;